Из двух стеков с целыми числами создать новый стек из элементов первого стека, которых нет во втором - PascalABC.NET - Ответ 11962854

//6.    Из двух стеков с целыми числами создать новый стек из элементов первого стека, которых нет во втором стеке.
Program aaa;
uses crt;
type
  elementPointer = ^stackElement;
  stackElement = record
    value: integer;
    nextElement: elementPointer;
  end;
  
 
procedure push(var stackTop: elementPointer; element: integer);// Добавляет элемент в начало стека
var
  newElementPointer: elementPointer;
begin
  new(newElementPointer);
  newElementPointer^.value := element;
  newElementPointer^.nextElement := stackTop;
  stackTop := newElementPointer;
end;
 
 
function pop(var stackTop: elementPointer): integer;//Удаляет элемент из стека
begin
  Result := stackTop^.value;
  stackTop := stackTop^.nextElement;
end;  
 
 
procedure printElements(stackTop: elementPointer);// Вывод элементов стека
var
  previousElementPointer: elementPointer;
begin
  if stackTop = nil then
    WriteLn('Stack is empty')
  else
    begin
      previousElementPointer := stackTop;
      while(previousElementPointer <> nil) do
        begin
          write(previousElementPointer^.value, ' ');
          previousElementPointer := previousElementPointer^.nextElement;
      end;
  end;
  WriteLn();
end;
 
 
procedure fillStack(var stackTop: elementPointer);// Заполнение стека элементами
var
  stackSize,
  element: integer;
begin
  stackTop := nil;
  WriteLn('Размер стека: ');
  ReadLn(stackSize);
  for var i := 1 to stackSize do begin
    write('Введите значения: ');
    ReadLn(element);
    push(stackTop, element);
  end;
end;
 
 
function isContained(stack: elementPointer; const pointerToFind: elementPointer): boolean;//Проверяет, является ли элемент, содержащийся в стеке
var
  currentPointer: elementPointer;
begin
  currentPointer := stack;
  Result := false;
  while (currentPointer <> nil) do
    begin
      if currentPointer^.value = pointerToFind^.value then
        begin
          Result := true;
          break;
        end  
      else
        begin
          currentPointer := currentPointer^.nextElement;
        end  
    end;
end;
 
 
function filterStack(const firstStack, secondStack: elementPointer): elementPointer;// Фильтрует первый стек на основе значений во втором стеке
var
  currentPointer,
  filteredStack: elementPointer;
begin
  filteredStack := nil;
  currentPointer := firstStack;
  while (currentPointer <> nil) do
    begin
      if not isContained(secondStack, currentPointer) then
        begin
          push(filteredStack, currentPointer^.value);
        end;
      currentPointer := currentPointer^.nextElement;
    end;
  Result := filteredStack;
end;
 
 
var
  oneStack,
  twoStack,
  filteredStack: elementPointer;
begin
  fillStack(oneStack);
  fillStack(twoStack);
  printElements(oneStack);
  printElements(twoStack);
  
  filteredStack := filterStack(oneStack, twoStack);
  printElements(filteredStack);
end.