Команда сопроцессора - fy12x - Assembler - Ответ 12285643

ФедосеевПавел · 06.04.2018, 22:56

Не по теме:

Marihuana, вы как не для себя спрашиваете - чтобы проверить ваш код нужно сделать минимальную тестовую программу, вставить ваш фрагмент, выловить ошибки компиляции и затем приступить к отладке. Как думаете - много желающих?

Добавлено через 5 часов 11 минут
Смотрите, все ваши вычисления с целочисленными результатами, отсюда и ошибки округлений.
Без ввода X.
Если нужен ввод - посмотрите в соседних темах подраздела - там есть применение библиотечных функций

Assembler

.686
.model flat, stdcall
option casemap :none
 
        include \masm32\include\windows.inc
 
        include \masm32\include\user32.inc
        include \masm32\include\kernel32.inc
        include \masm32\include\masm32.inc
 
        includelib \masm32\lib\user32.lib
        includelib \masm32\lib\kernel32.lib
        includelib \masm32\lib\masm32.lib
.data
        promptUserInputNumber       DB 10, 13, 'Please enter your number: ', 0
        promptUserInputOperator     DB 'Please enter your operator: ', 0
        aszPressEnter   db      0Dh, 0Ah, 0Dh, 0Ah, "Press ENTER to exit", 0
        sum_string      db      10, 13, "Result of your equation is %d", 0
    X       dq  1.0
    a       dq  3.4
.data?
        hConsoleOutput  HANDLE  ?
        hConsoleInput   HANDLE  ?
        Buffer          db      1024 dup(?)
        BufLen          dd      ?
        Result          dq      ?
 
.code
 
main    proc
 
        ; получение описателей ввода и вывода консоли
        invoke  GetStdHandle,   STD_INPUT_HANDLE
        mov     hConsoleInput,  eax
 
        invoke  GetStdHandle,   STD_OUTPUT_HANDLE
        mov     hConsoleOutput, eax
 
        invoke  ClearScreen
 
    finit               ;обнуляем стэк
    ;sin(x)/sqrt(x)
    fld [X]
    fld st(0)
    fsin
    fxch    st(1)
    fsqrt
    fdivp   st(1),  st(0)
    ;((sin(3.4x))^2)/x^2
    fld [X]
    fld st(0)
    fmul    [a]
    fsin
    fmul    st(0),  st(0)
    fxch    st(1)
    fmul    st(0),  st(0)
    fdivp   st(1),  st(0)
    ;
    faddp   st(1),  st(0)
    fsqrt
    ;x+(Pi/2)*exp(-abs(3.4))
    fld [X]
    fldpi           ;pi/2
    fld1
    fadd    st(0),  st(0)
    fdivp   st(1),  st(0)
    fld [a]     ;-abs(3.4)
    fabs
    fchs
    ;вычисление exp(st(0))
        fldl2e                  ;st(0)=1/ln(2)=log2(e)
        fmulp   st(1),  st(0)   ;st(0)=x/ln(2)=x*log2(e)
        fld     st(0)
        frndint
        fsub    st(1), st(0)
        fxch    st(1)
        f2xm1           ;st(0)=2^(mantissa)-1
        fld1            ;st(0)=2^(mantissa)-1+1=2^(mantissa)
        faddp   st(1), st(0)
        fscale
        fstp    st(1)
    ;
    fmulp   st(1),  st(0)   ;(Pi/2)*exp(-abs(3.4))
    faddp   st(1),  st(0)   ;x+(Pi/2)*exp(-abs(3.4))
    fsqrt
 
    faddp   st(1),  st(0)
 
    fstp    [Result]
 
ResultShow:
        ;вывод результата
    invoke  FloatToStr2, [Result], ADDR Buffer
    invoke  StrLen, ADDR Buffer
    mov     [BufLen],   eax
    invoke  WriteConsole, hConsoleOutput, ADDR Buffer,\
        BufLen, ADDR BufLen, NULL
 
        ;ожидание нажатия ENTER
        invoke  WriteConsole, hConsoleOutput, ADDR aszPressEnter,\
                LENGTHOF aszPressEnter - 1, ADDR BufLen, NULL
        invoke  ReadConsole, hConsoleInput, ADDR Buffer,\
                LENGTHOF Buffer, ADDR BufLen, NULL
 
        invoke  ExitProcess, 0
main    endp
 
end     main

Добавлено через 2 минуты
А с отрицательными X будет ошибка, т.к. корень квадратный из отрицательного числа не определён на множестве действительных чисел.

Вернуться к обсуждению:
Команда сопроцессора - fy12x Assembler

Следующий ответ

Другие темы раздела
Assembler Вычисление выражения по формуле https://www.cyberforum.ru/ assembler-math/ thread2223395.html Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль.	Вычислить сумму ряда Assembler Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль. s_1=\sum_{i=1}^{N}(\cos\: {x})^i
Assembler Вычисление выражения по формуле Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль. https://www.cyberforum.ru/ assembler-math/ thread2223390.html	Assembler Вычислить произведение ряда https://www.cyberforum.ru/ assembler-math/ thread2223389.html Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль.
Assembler Вычисление выражения по формуле с FPU Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль.	Assembler Вычислить произведение ряда, используя FPU https://www.cyberforum.ru/ assembler-math/ thread2222777.html Не могли бы вы помочь Исходные данные необходимо вводить с клавиатуры, результат выводить на консоль.
Assembler Вычислить сумму ряда Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль. https://www.cyberforum.ru/ assembler-math/ thread2221024.html	Вычисление выражения по формуле Assembler Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль.
Assembler Вычислить сумму ряда https://www.cyberforum.ru/ assembler-math/ thread2220465.html Входные данные необходимо вводить с клавиатуры; результат должен быть выведен на консоль.	Assembler Вычислите, используя FPU, следующее выражение Исходные данные необходимо вводить с клавиатуры, результат выводить на консоль. https://www.cyberforum.ru/ assembler-math/ thread2216454.html
Assembler Реализовать процедуру умножения квадратных матриц (SSE) Реализовать процедуру умножения квадратных матриц (размером кратным четырём) без использования специальных расширений и с использованием расширений SSE, сравнить время выполнения этих реализаций. Использовать операцию: aAx + y предполагается, что a,b– скаляры, x,y – векторы, A,B – матрицы	Assembler Emu8086 мат.формула .small Вычислить с учетом чисел с плавающей запятой следующее выражение: s1=\sum_{i=1}^{N}(tg\: x)^i Ввести информацию которую нужно ввести - с клавиатуры https://www.cyberforum.ru/ assembler-math/ thread2204920.html

	06.04.2018, 22:56

Команда сопроцессора - fy12x - Assembler - Ответ 12285643

Решение