Пишем DLL на FASM'e - FASM - Ответ 12999257

format   PE gui dll                 ; собираем DLL-модуль
include 'win32ax.inc'               ; макросы для укороченных директив
include 'encoding/win1251.inc'      ; подключим кирилицу
;---------
.data
mes0    db  'Библиотека Dll удачно поключена!',0      ; мессага-флаг, что DLL робит
wName   db  'Тест внешнего модуля',0                  ;  ..обзовём окно.
 
;---------
.code
start:                    ; точка входа!
       mov     eax,1      ; возвращаем TRUE
       ret                ;  ..в родитель LdrLoadDLL()
 
; Теперь наша либа зарегана, и мы можем вставлять всякие процедуры.
; Пока только одна.., которая просто покажет окно.
proc   Hello
       invoke  MessageBox,0,mes0,wName,0   ; даём о себе знать!
       ret                                 ; на выход.
endp                                       ; конец процедуры 'Hello'
 
.end start                ; макрос автоматом вставит секцию импорта.
 
; А вот секцию экспорта нужно вбить на клаве,
; и перечислить в ней весь экспорт, чтобы EXE смог их импортировать
;---------
section '.edata' export data readable      ;
export  'myDll.dll',\                      ; имя нашей библиотеки
         Hello, 'Hello'                    ; тут перечисляем имена всех процедур 
;---------
section '.reloc' fixups data discardable   ; разрешаем загрузчику перемещать базу DLL в памяти

format  PE gui                    ; собираем EXE
include 'win32ax.inc'
include 'encoding/win1251.inc'
entry   start
;---------
.data
mess0    db  'А это уже EXE приложение..',0
wName    db  'Проверка EXE!',0
 
;---------
.code
start:
        invoke  Hello             ; зовём внешнюю процедуру из нашей DLL
        nop
        invoke  MessageBox,0,mess0,wName,0     ; следом - сразу системную.
        invoke  ExitProcess,0                  ; на выход!
 
;---------
; Тут макрос '.end start' уже не поможет, т.к. в импорте есть самопальные библиотеки dll.
; Перечисляем их имена и импортируемые из них функции
;---------
section '.idata' import data readable
library  myLib,  'myDLL.dll',\                 ; прописываем нашу либу,
         kernel, 'kernel32.dll',\              ;   ..а так-же системные.
         user,   'user32.dll'                  ;     ^^^^
import   myLib,  Hello, 'Hello'                ; таблица IAT со-списком функций.
import   kernel, ExitProcess, 'ExitProcess'
import   user,   MessageBox, 'MessageBoxA'