Вывести на экран сумму цифр десятичной записи числа - Assembler - Ответ 14091609

.model medium
 
.stack 200h
 
.data
        msgPrompt       db      'Enter a number (bin): ', '$'
        msgEntered      db      0Dh, 0Ah, 'Entered a number (dec): ', '$'
        msgResult       db      0Dh, 0Ah, 'Sum of digits: ', '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
.data?
        N               dw      ?       ;вводимое число
        Sum             dw      ?       ;сумма десятичных цифр введённого числа
.code
 
;макрос для упрощения вызова процедур с параметрами
invoke  macro   CallProc, Params
        IRP     P,      <Params>
                mov     ax,     P
                push    ax
        endm
        call    CallProc
endm
 
;ввод 16-разрядного числа с клавиатуры в двоичном формате
;на входе:
;  дальний адрес переменной для сохранения результата
InputBin16      proc    near
        ;стековый фрейм
        push    bp
        mov     bp,     sp
        ;вывод приглашения ко вводу
        mov     ah,     09h
        lea     dx,     [msgPrompt]
        int     21h
        ;ввод с фильтрацией символов
        xor     bx,     bx
        mov     cx,     16
        @@getc:
                mov     ah,     08h     ;ввод символа без эха
                int     21h
                mov     dl,     al
                cmp     al,     0Dh     ;если ENTER - завершить ввод
                je      @@break
                sub     al,     '0'     ;проверка корректности символа
                jb      @@getc
                cmp     al,     2
                jnc     @@getc
                shl     bx,     1       ;для корректного символа - преобразование в число
                or      bl,     al
                mov     ah,     02h     ;вывод введённого символа
                int     21h
        loop    @@getc
        @@break:
        ;сохранить введённое число по адресу, указанному в параметре процедуры
        les     di,     [bp+4]
        mov     [di],   bx
        ;удаление фрейма стека
        pop     bp
        ret     4
InputBin16      endp
 
;Вывод на экран целого 16 разрядного беззнакового числа
;на входе:
;  целое 16 разрядное беззнаковое число
ShowUInt16       proc   near
        ;стековый фрейм
        push    bp
        mov     bp,     sp
        ;вывод числа на экран
        mov     ax,     [bp+4]
        mov     bx,     10              ;делитель (основание системы счисления)
        mov     cx,     0               ;количество выводимых цифр
        @@div:
                xor     dx,     dx      ;делим (dx:ax) на bx
                div     bx
                add     dl,     '0'     ;преобразуем остаток деления в символ цифры
                push    dx              ;и сохраняем его в стеке
                inc     cx              ;увеличиваем счётчик цифр
                test    ax,     ax      ;в числе ещё есть цифры?
        jnz     @@div                   ;да - повторить цикл выделения цифры
        @@show:
                mov     ah,     02h     ;функция ah=02h int 21h - вывести символ из dl на экран
                pop     dx              ;извлекаем из стека очередную цифру
                int     21h             ;и выводим её на экран
        loop    @@show                  ;и так поступаем столько раз, сколько нашли цифр в числе (cx)        pop     bx
        ;удаление фрейма стека
        pop     bp
        ret
ShowUInt16       endp
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        ;ввод числа
        invoke  InputBin16,     <<seg N>, <offset N>>
        mov     ax,     [N]
        ;вычисление суммы цифр
        mov     ax,     [N]
        xor     bx,     bx
        mov     cx,     10
        @@repeat:
                xor     dx,     dx
                div     cx
                add     bx,     dx
                test    ax,     ax
        jnz     @@repeat
        mov     [Sum],  bx
        ;контрольный вывод введённого числа
        mov     ah,     09h
        lea     dx,     [msgEntered]
        int     21h
        invoke  ShowUInt16,     [N]
        ;вывод результата
        mov     ah,     09h
        lea     dx,     [msgResult]
        int     21h
        invoke  ShowUInt16,     [Sum]
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
 
        ;завершение программы
        mov     ax,     4C00h
        int     21h
main    endp
 
end     main