Дана символьная строка. Вывести на экран те символы которые встречаются в строке более 3х раз - Pascal - Ответ 1716580

program Project1;
 
var
  S, sCnt, sCode : String;
  Ch : Char;
  i, Len : Integer;
  //Это тоже самое что и: ArrStat : array[#0..#255] of Integer;
  ArrStat : array[Char] of Integer;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    //Обнуляем элементы массива статистики.
    for Ch := #0 to #255 do ArrStat[Ch] := 0;
 
    //Собираем статистику.
    Len := Length(S);
    for i := 1 to Len do Inc(ArrStat[S[i]]);
 
    //Показываем результат.
    Writeln('Символы, которые присутствуют более трёх раз:');
    S := '';
    i := 0;
    for Ch := #0 to #255 do begin
      //Пропускаем те символы, которые встречаются не более трёх раз.
      if ArrStat[Ch] <= 3 then Continue;
      if S <> '' then S := S + #9;
      Str(ArrStat[Ch], sCnt);
      if Ch <= #32 then begin
        Str(Ord(Ch), sCode);
        S := S + '#' + sCode + '(' + sCnt + ')';
      end else begin
        S := S + Ch + '(' + sCnt + ')';
      end;
      //Распечатку формируем в виде таблицы, которая имеет 7 столбцов.
      Inc(i);
      if i mod 7 = 0 then begin
        Writeln(S);
        S := '';
      end;
    end;
    if S <> '' then Writeln(S);
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.