Однонаправленные кольцевые списки - Delphi - Ответ 3032589

type
  //Основоные данные.
  TData = Integer;
  //Тип указателя на элемент списка.
  TPElem = ^TElem;
  //Тип элемента списка.
  TElem = record
    Data : TData;
    PNext : TPElem;
  end;
  //Для кольцевого списка не будем заводить отдельный тип.
  //Кольцевой список будет представлен указателем типа PList : TPElem.
  //Этот указатель указывает на последний элемент списка.
  //Соответственно, указателем на первый элемент списка является: PList^.PNext.
 
//Добавление элемента в конец однонаправленного кольцевого списка.
procedure AddL(var aPList, aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  if aPList = nil then
    //Единственный элемент указывает сам на себя.
    aPElem^.PNext := aPElem
  else begin
    //Добавляем новый элемент после последнего в списке.
    aPElem^.PNext := aPList^.PNext;
    aPList^.PNext := aPElem;
  end;
  //Указатель списка переводим на добавленный элемент. - Теперь он является
  //последним в списке.
  aPList := aPElem;
end;
 
//Удаление однонаправленного кольцевого списка из памяти и инициализация.
procedure ListFree(var aPList : TPElem);
var
  PLast, PDel : TPElem;
begin
  if aPList = nil then Exit;
 
  PLast := aPList;
  repeat
    PDel := aPList;
    aPList := aPList^.PNext;
    Dispose(PDel);
  until aPList = PLast;
  aPList := nil;
end;
 
//Распечатка однонаправленного списка aN раз.
function ListToStr(const aPList : TPElem; const aN : Word) : String;
var
  PElem : TPElem;
  i, Cnt : Integer;
begin
  if aPList = nil then begin
    Result := 'Список пуст.';
    Exit;
  end;
 
  Result := '';
  //Указатель на первый элемент списка.
  PElem := aPList^.PNext;
  i := 0;
  Cnt := 0; //Счётчик пройденных колец.
  while Cnt < aN do begin
    Inc(i);
    if i > 1 then Result := Result + ', ';
    Result := Result + IntToStr(PElem^.Data);
    if PElem = aPList then Inc(Cnt); //Счётчик колец.
    PElem := PElem^.PNext;
  end;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  PList, PElem : TPElem;
  i : Integer;
  S : String;
begin
  //Начальная инициализация списка. Такую инициализацию можно выполнять
  //только в отношении пустого списка. Иначе, будут утечки памяти.
  PList := nil;
 
  //Создаём кольцевой список путём добавления элементов в его конец.
  for i := 0 to Memo1.Lines.Count - 1 do begin
    S := Memo1.Lines[i];
    if S = '' then Continue; //Пропуск пустых строк.
    New(PElem);
    PElem^.Data := StrToInt(S);
    AddL(PList, PElem);
  end;
 
  //Распечатка списка.
  Memo2.Lines.Add('--------------------------------------------------');
  Memo2.Lines.Add('Создан список:');
  Memo2.Lines.Add(ListToStr(PList, 1));
 
  //Распечатка списка.
  Memo2.Lines.Add('Для демонстрации обхода кольцевого списка распечатаем его 3 раза:');
  Memo2.Lines.Add(ListToStr(PList, 3));
 
  //Удаление списка из памяти.
  ListFree(PList);
  Memo2.Lines.Add('Список удалён из памяти.');
end;