Дана строка, состоящая из слов, разделенных пробелами. Если встречаются слова из 2 букв то заменить их * - Delphi - Ответ 3643584

//С применением стандартных процедур.
procedure TForm1.Button1Click(Sender: TObject);
const
  D = [#9, #10, #13, #32]; //Множество разделителей.
var
  S : String;
  i, Len, LenW : Integer;
begin
  S := Memo1.Text;
  Len := Length(S);
  LenW := 0;
  for i := Len downto 1 do //Перебор символов строки справа-налево.
    if not (S[i] in D) then begin //Если символ не является разделителем.
      Inc(LenW); //Учитываем символ в длине слова.
      if (i = 1) or (S[i - 1] in D) then begin //Если найдено начало слова.
        if LenW = 2 then begin //Если длина слова оказалась равной 2.
          Delete(S, i, LenW - 1);
          S[i] := '*';
        end;
        LenW := 0;
      end;
    end;
 
  //Ответ.
  Memo2.Text := S;
end;

//Без применения стандартных процедур.
procedure TForm1.Button1Click(Sender: TObject);
const
  D = [#9, #10, #13, #32]; //Множество разделителей.
var
  S : String;
  i, j, Len, LenW : Integer;
begin
  S := Memo1.Text;
  Len := Length(S);
  LenW := 0;
  j := 0;
  for i := 1 to Len do begin //Перебор символов строки слева-направо.
    Inc(j);
    S[j] := S[i];
    if not (S[i] in D) then begin //Если символ не является разделителем.
      Inc(LenW); //Учитываем символ в длине слова.
      if (i = Len) or (S[i + 1] in D) then begin //Если найден конец слова.
        if LenW = 2 then begin
          Dec(j, LenW - 1);
          S[j] := '*';
        end;
        LenW := 0;
      end;
    end;
  end;
  //Новая длина строки.
  SetLength(S, j);
 
  //Ответ.
  Memo2.Text := S;
end;