Найти произведение тех элементов, значение которых меньше среднего арифметического элементов массива

Sub Procedure_1()
 
    'Создаём массив "W".
    'Long означает, что в массиве "W" могут быть только целые числа.
    Dim W() As Long
    
    'Создаём различные переменные.
    Dim M As Long
    Dim Sum As Long
    
    'Double означает, что в переменной могут быть
    'как целые, так и дробные числа.
    Dim dAverage As Double
    
    'Переменная "dProduct" будет сохранять результы умножения чисел.
    'В данном случае Double я выбрал, потому что Double позволяет сохранять
    'числа 15-значные, а Long - только 10-значные.
    'А при умножении чисел могут возникнуть очень большие числа.
    Dim dProduct As Double
    
    Dim i As Long
    
    'Т.к. массив будем выводить в Excel, чтобы
    'смотреть, что он из себя представляет, то очищаем
    'активный лист от предыдущих данных.
    ActiveSheet.UsedRange.Clear
    
    'С помощью "InputBox" помещаем в переменную "M"
    'число, которое будет означать - количество элементов в массиве "W".
    M = InputBox("Сколько элементов будет в массиве W?")
    
    'Разбиваем массив "W" на элементы, чтобы затем
    'в элементы поместить числа.
    '"1 To" - используется, чтобы порядковый номер первого элемента
    'в массиве был один, а не ноль (ноль по умолчанию), чтобы
    'было удобно писать код.
    ReDim W(1 To M)
    
    'Заполняем массив числами, чтобы было с чем работать.
    'Чтобы числа не выдумывать, можно создавать числа
    'с помощью "Rnd".
    'For ... To ... Step ... Next - называется циклом
    'и используется, чтобы делать одно и то же действие
    'несколько раз.
    For i = 1 To M Step 1
        'Генерирую случайные целые числа от 1 до 5.
        W(i) = Int((5 - 1 + 1) * Rnd) + 1
    Next i
    
    'Чтобы иметь представление, что у нас за массив,
    'выводим массив на активный лист Excel.
    For i = 1 To M Step 1
        Cells(i, "A").Value = W(i)
    Next i
    
    'Находим среднее арифметическое элементов массива.
    '1. Сначала находим сумму элементов.
    For i = 1 To M Step 1
        Sum = Sum + W(i)
    Next i
    '2. Затем находим среднее арифметическое.
    dAverage = Sum / M
    
    'Найти произведение тех элементов, значение которых меньше
    'среднего арифметического элементов массива.
    'Присваиваем переменной "dProduct" число 1, т.к.
    'в ней содержится ноль, а при умножении на ноль всегда будет ноль.
    dProduct = 1
    For i = 1 To M Step 1
        'If ... Then ... End If - используется для выбора действия.
        'Если элемент меньше среднего.
        If W(i) < dAverage Then
            dProduct = dProduct * W(i)
        End If
    Next i
    
    'С помощью "MsgBox" выводим на монитор результат.
    MsgBox "Результат: " & dProduct
    
End Sub