Упражнение про IO (игра в кости) - Haskell - Ответ 4912438

import System.Random
 
import Control.Monad.Identity
import Control.Monad.Writer
import Control.Monad.State
import Control.Monad.Reader
 
import Text.Printf
 
data Player = Player { score :: Int, name :: String }
 
mkPlayer :: String -> Player
mkPlayer name = Player { score = 0, name = name }
 
data GameState = GameState { currTurn :: Player, prevTurn :: Player, rolls :: [Int], turn :: Int }
 
mkGameState :: String -> String -> [Int] -> GameState
mkGameState p1 p2 rs = GameState { currTurn  = mkPlayer p1
                                 , prevTurn  = mkPlayer p2
                                 , rolls     = rs
                                 , turn      = 1
                                 }
 
type Game = ReaderT Int (StateT GameState (WriterT [String] Identity)) ()
 
execGame :: GameState -> Int -> [String]
execGame state threshold = runIdentity (execWriterT (execStateT (runReaderT game threshold) state))
 
nextTurn :: GameState -> GameState
nextTurn state = state { currTurn = prevTurn state
                       , prevTurn = currTurn' { score = newScore }
                       , rolls    = tail (rolls state)
                       , turn     = turn state + 1
                       }
    where currTurn' = currTurn state
          newScore  = score currTurn' + head (rolls state)
 
game :: Game
game = do
  threshold <- ask
  turn <- gets turn
  curr <- gets currTurn
  prev <- gets prevTurn
  tell [printf "Turn %d. %s - %d, %s - %d." turn (name curr) (score curr) (name prev) (score prev)]
  if score prev > threshold
  then tell [printf "%s wins with score %d." (name prev) (score prev)]
  else do
    modify nextTurn
    game
 
diceRoll :: Int -> Int
diceRoll x = 1 + x `mod` 6
 
main :: IO ()
main = do
  stdGen <- newStdGen
  mapM_ putStrLn $ execGame (mkGameState "John" "Peter" (map diceRoll (randoms stdGen))) 99