Мониторинг изменений текстового файла - Delphi - Ответ 6388315

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Timer1: TTimer;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
    FFileName : String;    //Имя файла, за которым ведётся наблюдение.
    FTimeLast : TDateTime; //Дата и время последнего изменения файла.
    procedure MonStart(const aFileName : String); //Запуск монитора.
    procedure MonStop; //Останов монитора.
    procedure MonScan; //Проверка - изменился ли файл.
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
//Останов монитора.
procedure TForm1.MonStop;
begin
  Timer1.Enabled := False;
  Memo1.Lines.Add(FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', Now) + '. Монитор остановлен.')
end;
 
//Запуск монитора.
procedure TForm1.MonStart(const aFileName : String);
begin
  //Если монитор работает, то останавливаем его.
  if Timer1.Enabled then
     MonStop;
  //Проверяем, существует ли файл.
  if not FileExists(aFileName) then
  begin
    Memo1.Lines.Add(FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', Now)
      + '. Файл не найден! Действие отменено.');
    Exit;
  end;
 
  //Запускаем монитор.
  FFileName := aFileName;
  FTimeLast := FileDateToDateTime(FileAge(FFileName));
  Memo1.Lines.Add(FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', Now) + '. Монитор запущен.');
  Memo1.Lines.Add('Файл: ' + FFileName);
  Memo1.Lines.Add('Время последнего изменения файла: '
    + FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', FTimeLast));
  Timer1.Enabled := True;
end;
 
//Проверка - изменён ли файл.
procedure TForm1.MonScan;
var
  TimeCur : TDateTime;
begin
  //Проверяем, существует ли файл.
  if not FileExists(FFileName) then
  begin
    Memo1.Lines.Add(FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', Now) + '. Файл не найден!');
    MonStop;
  end;
  //Текущее временя последнего изменения файла.
  TimeCur := FileDateToDateTime(FileAge(FFileName));
  //Если текущее время изменения отличается от предыдущего, значит файл изменён.
  if FTimeLast <> TimeCur then
  begin
    FTimeLast := TimeCur;
    Memo1.Lines.Add(FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', Now) + '. Файл изменён.');
    Memo1.Lines.Add('    Время последнего изменения файла: '
      + FormatDateTime('dd.mm.yyyy"-"hh:nn:ss:zzz', FTimeLast));
  end;
end;
 
//Таймер: отслеживаение изменений файла.
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  MonScan;
end;
 
//Кнопка: запуск монитора.
procedure TForm1.Button1Click(Sender: TObject);
begin
  MonStart(ExtractFilePath(ParamStr(0)) + 'file.txt');
end;
 
//Кнопка: останов монитора.
procedure TForm1.Button2Click(Sender: TObject);
begin
  MonStop;
end;
 
//Перед закрытием формы.
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;
  MonStop;
end;
 
end.