Если максимальный элемент списка отрицательный, то продублировать каждое его вхождение в список - Pascal - Ответ 6694433

type
  TElement=Integer;
 
  PNode=^TNode;
  TNode=record
    next: PNode;
    data: TElement;
  end;
 
function NewNode(n: TElement; aNext: PNode): PNode;
var p: PNode;
begin
  New(p);
  with p^ do begin
    next:=aNext; data:=n;
    NewNode:=p;
  end;
end;
 
procedure sPush(var lst: PNode; n: TElement);
begin
  lst:=NewNode(n,lst);
end;
 
function sPop(var lst: PNode): TElement;
var t: PNode;
begin
  if lst=nil then RunError(204);
  with lst^ do begin
   sPop:=data;
   t:=lst; lst:=next; Dispose(t);
  end;
end;
 
procedure sWrite(lst: PNode);
begin
  while lst<>nil do with lst^ do begin
    Write(' ',data); lst:=next;
  end;
end;
 
procedure sDuplicate(lst: PNode; n: TElement);
begin
  while lst<>nil do with lst^ do
    if data=n then begin
      next:=NewNode(n,next);
      lst:=next^.next;
    end else lst:=next;
end;
 
procedure sRemoveP(var lst: PNode);
var p: ^PNode; t: PNode;
begin
  p:=Addr(lst);
  while p^<>nil do if p^^.data>0 then sPop(p^) else p:=Addr(p^^.next);
end;
 
function sGetMax(lst: PNode): TElement;
var m: TElement;
begin
  if lst=nil then RunError(204);
  m:=lst^.data; lst:=lst^.next;
  while lst<>nil do with lst^ do begin
    if data>m then m:=data;
    lst:=next;
  end;
  sGetMax:=m;
end;
 
var
  st: PNode;
  e: TElement;
  i: Integer;
begin
  Randomize;
  for i:=1 to 10 do sPush(st,-1-Random(100){+50});
  sWrite(st); WriteLn;
  e:=sGetMax(st);
  if e<0 then sDuplicate(st,e) else sRemoveP(st);
  sWrite(st); WriteLn;
  while st<>nil do sPop(st);
end.