Спецификация драйвера - Delphi - Ответ 7452200

uses
  StrUtils, Printers;
 
function GetDocSize : Integer; stdcall;
  external 'driver.dll' name 'GetDocSize';
 
function GetDocImage(Buf : PChar; var Critical : Boolean) : Boolean;
  stdcall; external 'driver.dll' name 'GetDocImage';
 
procedure TForm1.Button1Click(Sender: TObject);
var
  PCh : PChar;
  S : String;
  Size : Integer;
  FPrn : TextFile;
  Critical : Boolean;
begin
  //Запрос размера образа. Будем считать, что размер получаем с учётом терминального нуля.
  Size := GetDocSize;
  if Size = 0 then
  begin
    MessageBox(Handle, 'Нет документов для печати.',
      'Отмена', MB_OK + MB_ICONEXCLAMATION + MB_APPLMODAL);
    Exit;
  end;
 
  //Выделение памяти для нуль-терминальной строки. Size - с учётом терминального нуля.
  PCh := StrAlloc(Size);
  try
    //Запрос содержания образа. Без действий с Critical.
    if not GetDocImage(PCh, Critical) then
    begin
      MessageBox(Handle, 'GetDocImage(). Не удалось получить текст. Действие отменено.',
        'Ошибка!', MB_OK + MB_ICONERROR + MB_APPLMODAL);
      Exit; //При этом перед выходом из метода управление перейдёт в раздел finally - end.
    end;
    S := PCh;
  finally
    //Освобождение памяти, выделенной ранее для нуль-терминальной строки.
    StrDispose(PCh);
  end;
 
  //Печать на принтере в текстовом режиме.
  Printer.BeginDoc;
  try
    AssignPrn(FPrn);
    Rewrite(FPrn);
    try
      Write(FPrn, S);
    finally
      CloseFile(FPrn);
    end;
  finally
    Printer.EndDoc;
  end;
end;