Как можно перевести этот код с паскаля в с++? - C++ - Ответ 9032624

program razbienie_mnozhestwa(input,output);
var i,j,k,n:byte;wper:array[1..255]of boolean;
sled,pred,blok:array[1..255]of byte;
procedure write_razbienie; {процедура, выписывающая разбиение на экран}
var
 i,j:byte;
begin
 j:=1; {номер первого блока}
 repeat
  write('( ');
  for i:=j to n do if blok[i]=j then write(i, ' '); {если число і из блока j, то пишем это число}
  j:=sled[j]; {следующий по номеру блок}
  write(')');
 until j=0; 
 WRITELN
end;
begin
 write('input n:');
 readln(n); {вводим количество элементов множества}
 for i:=1 to n do begin {строим разбиение {{1, …, n}}}
  blok[i]:=1;
  wper[i]:=true
 end;
 sled[1]:=0;
 write_razbienie; {выписать разбиение}
 j:=n; {активный элемент}
 while j>1 do begin {задача цикла – перемещение «активного» элемента j в соседний блок – в предыдущий или последующий (в последнем случае может возникнуть необходимость создания нового блока вида {j}, а затем определение активного элемента во вновь образованном разбиении}
  k:=blok[j]; {процесс переноса активного элемента; k – номер активного блока}
  if wper[j] then begin {j движется вперёд}
   if sled[k]=0 then begin {k – последний блок}
    sled[k]:=j; {j – одноэлементный блок}
    pred[j]:=k;
    sled[j]:=0
   end;
   if sled[k]>j then begin {j образует новый блок}
    pred[j]:=k; {все блоки справа от блока с номером k содержат элементы, большие j. Отсюда следует, что j образует новый одноэлементный блок}
    sled[j]:=sled[k];
    pred[sled[j]]:=j;
    sled[k]:=j
   end;
   blok[j]:=sled[k] {переносим наш элемент в активный блок с номером k}
  end
  else begin {j движется назад}
   blok[j]:=pred[k]; {помещаем j в предыдущий блок}
   if k=j then if sled[k]=0 then sled[pred[k]]:=0 else begin
    sled[pred[k]]:=sled[k];
    pred[sled[k]]:=pred[k]
   end
  end;
  write_razbienie;
  j:=n;
  while(j>1)and
   ((wper[j]and(blok[j]=j))or(not wper[j]and(blok[j]=1))) do begin
   wper[j]:=not wper[j];
   dec(j)
  end
 end
end.