Программа для генерации звуковых сигналов - Assembler - Ответ 9216834

.model small
.data
.stack 256
.code
start:
    mov ax,0    ;Настраиваем сегментные регистры
    mov ds,ax
    mov ax,750
    call Sound
    mov bx,18
    call pause  
    call No_Sound
    mov bx,18*5
    call pause
    mov ax,1000
    call Sound
    mov bx,18*3
    call pause  
    call No_Sound
    mov ax,4c00h    ;закончить программу
    int 21h
 
pause:
    add bx,ds:[46ch];прибавить к времени паузв счетчик таймера
w1: cmp bx,ds:[46ch];сравнить время конца паузы с текущим временем
    jnz w1      ;пока не достигдли конца, продолжаем паузу
    ret 
    
;Подача звука через встроенный спикер
;ах - частота звука
Sound      proc     near
    push     ax        ;сохранить регистры
    push     bx
    push     dx
    mov      bx,ax     ;частота
    mov      ax,34DDh
    mov      dx,12h    ;(dx,ax)=1193181
    cmp      dx,bx     ;если bx < 18Гц, то выход
    jnb      Done      ;чтобы избежать переполнения
    div      bx        ;ax=(dx,ax)/bx
    mov      bx,ax     ;счетчик таймера
    in       al,61h    ;порт РВ
    or       al,3      ;установить биты 0-1
    out      61h,al
    mov      al,00001011b   ;управляющее слово таймера:
                        ;канал 2, режим 3, двоичное слово
    mov      dx,43h    ;вывод в регистр режима
    out      dx,al     ;устанавливаем режим работы таймера
    dec      dx    ;порт 2-го канала
    mov      al,bl     ;младший байт счетчика
    out      dx,al     ;записываем
    mov      al,bh     ;старший байт счетчика
    out      dx,al     ;записываем
Done:   pop      dx        ;восстановить регистры
    pop      bx
    pop      ax
    ret        ;выход из подпрограммы
Sound      endp
;Прекращение подачи звука через встроенный спикер
No_Sound   proc     near
    push    ax  ;сохраняем регистр
    in  al,61h  ;порт РВ
    and al,not 3;сброс битов 0-1
    out 61h,al  ;возвращаем значение в порт
    pop ax  ;восстанавливаем регистр
    ret     ;выход из подпрограммы
No_Sound   endp
 
end start