Вычислить факториал введенного числа n! (0<n<1001) и вывести результат - Assembler - Ответ 9964518

.586p
.model flat
.code
include windows.inc
includelib user32.lib
extrn _imp__MessageBoxA@16:dword
n equ 73
 
start:  mov edi,offset result+len;edi - указатель на последний байт результата
    mov esi,n
    mov dword ptr [edi-4],esi
    sub edi,8
    mov ebp,1
    dec esi
@1: mov ecx,ebp
    xor ebx,ebx
@@: mov eax,dword ptr [edi+4*ecx]
    mul esi
    add eax,ebx
    adc edx,0
    mov ebx,edx
    mov dword ptr [edi+4*ecx],eax
    loop @b;.untilcxz
    je @2;  .if !ZERO?
    mov dword ptr [edi],edx
    cmp dword ptr [edi+4*ebp],0
    je @f
    inc ebp
@@: sub edi,4
@2: dec esi
    jne @1;.until ZERO?
; big-endian --> litle-endian
    mov edi,offset result
    mov cl,len/4;длина результата в двордах
@@: mov eax,[edi]
    bswap eax
    stosd
    loop @b
; перевожу hex->dec
    mov esi,offset terminator-1;
@3: mov cl,len;длина в байтах значения делимого
    mov edi,offset result
    xor eax,eax
@@: mov al,[edi];делимое
    div ten
    stosb
    loop @b
    or [esi],ah;остаток
    dec esi
    cmp dword ptr [edi-4],0;cmp result+36,0
    jne @3
    cmp dword ptr [edi-8],0;cmp result+32,0
    jne @3
    cmp dword ptr [edi-12],0;cmp result+32,0
    jne @3
; вывожу на экран
    inc esi
    push MB_OK + MB_ICONASTERISK
    push offset mesbox_title   
    push esi;offset mesbox_text с поправкой на ведущие нули
    push 0
    call _imp__MessageBoxA@16
    ret;выходим из программы
result  db 44 dup (0)
len = $-result
ten db 10
mesbox_text db 112 dup ('0')
terminator db 0
mesbox_title db 'Факториал',0
end start