Перевод строки в число и обратно со знаком (+,-)

program Project1;
 
{$N+} {Подключаем математический сопроцессор. Это позволит использовать тип Extended.}
 
const
  {Соответствие между цифрой и числом.}
  D : String = '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ';
 
{Перевод представления числа aSNum, заданного в системе счисления
с основанием aBase - в число.}
function StrToNum(const aSNum : String; const aBase : Byte) : Extended;
var
  SNum, Sign : String;
  i, Len : Integer;
  Res, Weight : Extended;
begin
  Res := 0;
 
  SNum := UpperCase(aSNum); {Перевод символов в верхний регистр.}
  {Знак в представлении числа.}
  Len := Length(SNum);
  Sign := '+';
  if (SNum <> '') and (SNum[1] in ['+', '-']) then
  begin
    Sign := SNum[1];
    Delete(SNum, 1, 1); {Представление числа без знака.}
    Dec(Len); {Длина представления без знака.}
  end;
  {Перевод целой части.}
  i := 1;
  while (i <= Len) and not (SNum[i] in ['.', ',']) do
  begin
    Res := Res * aBase + Pos(SNum[i], D) - 1;
    Inc(i);
  end;
  {Перевод дробной части.}
  Weight := 1; {Начальный вес разряда.}
  Inc(i);
  while i <= Len do
  begin
    Weight := Weight / aBase; {Вес очередного разряда.}
    Res := Res + (Pos(SNum[i], D) - 1) * Weight;
    Inc(i);
  end;
  {Учитываем знак числа.}
  if Sign = '-' then
    Res := -Res;
  StrToNum := Res;
end;
 
{Представление числа aNum в системе счисления с основанием aBase и с точностью
aPrec знаков после запятой.}
function NumToStr(const aNum : Extended; const aBase, aPrec : Byte) : String;
var
  NInt : Longint;
  NFrac : Extended;
  i : Integer;
  Res : String;
begin
  {Значение целой части числа.}
  NInt := Trunc(Abs(aNum));
  {Представление целой части числа.}
  Res := '';
  repeat
    Res := D[NInt mod aBase + 1] + Res;
    NInt := NInt div aBase;
  until NInt = 0;
 
  {Значение дробной части числа.}
  NFrac := Frac(Abs(aNum));
  {Добавляем разделитель целой и дробной части.}
  if (NFrac <> 0) and (aPrec > 0) then
    Res := Res + '.';
  {Представление дробной части.}
  i := 0;
  while (NFrac <> 0) and (i < aPrec) do
  begin
    Inc(i);
    Res := Res + D[Trunc(NFrac * aBase) + 1];
    NFrac := Frac(NFrac * aBase);
  end;
 
  {Добавляем в представление знак.}
  if aNum < 0 then
    Res := '-' + Res;
  NumToStr := Res;
end;
 
{Перевод представления числа, заданного в системе счисления с основанием aBase1,
в представление с основанием aBase2 с точностью aPrec знаков после запятой
в целевом представлении.}
function c2c(const aSNum : String; const aBase1, aBase2, aPrec : Byte) : String;
var
  Num : Extended;
begin
  Num := StrToNum(aSNum, aBase1);
  c2c := NumToStr(Num, aBase2, aPrec);
end;
 
var
  Base1, Base2, Prec : Byte;
  S, SNum : String;
begin
  repeat
    Writeln('----------');
    Writeln('Задайте основание исходной системы счисления:');
    Readln(Base1);
    Writeln('Задайте представление числа в исходной системе счисления:');
    Readln(SNum);
    Writeln('Задайте основание целевой системы счисления:');
    Readln(Base2);
    Writeln('Задайте точность представления числа в целевой системы счисления:');
    Readln(Prec);
 
    Writeln('Представление числа в целевой системе счисления:');
    Writeln(c2c(SNum, Base1, Base2, Prec));
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.