Ассемблерная вставка: копирование содержимого массива типа char в n-раз больший массив

@_kaktus_ · Регистрация: 21.12.2013

Собственно задание: Написать программу, осуществляющую копирование содержимого массива типа char в n-раз больший массив, при этом каждый элемент массива должен повторяться n-раз, т. е., например, из массива 'a', 'b', 'c', при n=3, должен быть сформирован массив 'a', 'a', 'a', 'b', 'b', 'b', 'c', 'c', 'c' Ввод-вывод массивов осуществлять в виде строк. Основную часть программы заменить ассемблерной вставкой.
Вот код на паскале:

Кликните здесь для просмотра всего текста

Pascal

var
mas,mas2: string;
n,m,i,j,t: integer;
begin
t:=1;
writeln('Введите количество элементов: ');
 readln(m);
 writeln('Заполните массив из ',m,' элементов: ');
  for i:=1 to m do
   readln(mas[i]);
 writeln('n=');
  readln(n);
for i:=1 to m do
   for j:=1 to n do
    begin
      mas2[t]:=mas[i];
       t:=t+1;
    end;
    for i:=1 to m*n do
     write(mas2[i],' ');
   readln;
end.

Собственно вопрос как в ассемблерной вставке обратиться к элементам массива?

Assembler

 asm
   mov ax, i
    @M: mov bx, j
        @N:
            // как вот тут обратиться к элементу массива?
           inc bx
            cmp bx, n
           jnz @N
    inc ax
     cmp ax,m
    jnz @M
  end;

@_kaktus_ · 04.01.2017, 14:57 **[ТС]**

Pascal

var
mas: string;
MAS2:array[1..256]OF CHAR;
n,m: integer;
begin
   WRITE('Введите строку: ');
   READ(MAS);
   M:=LENGTH(MAS);
 writeln('n=');
  read(n);
    ASM
            //XOR EAX,EAX
            XOR EDX,EDX
            MOV ECX,1
        @1: MOV AL,BYTE PTR [MAS+ECX]
            MOV EBX,1
        @2: MOV BYTE PTR [MAS2+EDX],AL
            INC EDX
            INC BX
            CMP BX,N
            JLE @2
            INC CX
            CMP CX,M
            JLE @1
    END;
   for i:=1 to m*n do
     write(mas2[i]);
   readln;
   readln;
end.

@bormant · 05.01.2017, 12:06

Сильно сомневаюсь, что встроенный ассемблер 16-битного Turbo Pascal знает про расширенные регистры (edx, ecx, ebx).

Кроме того, не проще ли использовать строчные операции?

Pascal

var ms, md: String;
begin
  Write('Строка: '); ReadLn(ms);
  asm
    mov  dx,ds
    mov  es,dx
    lea  di,md
    lea  si,ms
    xor  ax,ax
    lodsb
    mov  cx,ax
    mov  ah,3
    mul  ah
    stosb
    jcxz @done
@1:
    lodsb
    stosb
    stosb
    stosb
    loop @1
@done:
    mov  ds,dx
  end;
  WriteLn(md);
end.

Добавлено через 2 минуты
или

Pascal

var ms, md: String;
begin
  Write('Строка: '); ReadLn(ms);
  asm
    mov  dx,ds
    mov  es,dx
    lea  di,md
    lea  si,ms
    xor  ax,ax
    lodsb
    mov  cx,ax
    mov  ah,3
    mul  ah
    stosb
    jcxz @done
@1:
    lodsb
    mov  bx,3
    xchg bx,cx
    rep  stosb
    xchg bx,cx
    loop @1
@done:
    mov  ds,dx
  end;
  WriteLn(md);
end.

Добавлено через 17 часов 48 минут
Кстати, последний mov ds,dx -- не нужен, поскольку ds в этом фрагменте не меняется. Нужен был бы внутри процедуры, пришлось бы указатель на источник грузить как lds si,ms, на приёмник как les di,md.

@Constantin Cat · 06.01.2017, 18:39

bormant,
правельнее было бы так:

Pascal

var
  a,b:string;
  c,d:integer;
begin
  write('enter string:');
  readln(a);
  write('enter count:');
  readln(d);
  b:='error :(';
  asm
    push es
    push ds
    pop  es
    lea  si,a
    lea  di,b
    xor  dx,dx
    xor  ax,ax
    lodsb
    mov  cx,d
    mul  cx
    or   ah,ah
    jnz  @@02
    mov  cx,ax
    stosb
@@01:
    lodsb
    push cx
    mov  cx,d
    rep  stosb
    pop  cx
    loop @@01
@@02:
    pop  es
  end;
  write('result:',b);
  readln;
end.

@bormant · 06.01.2017, 21:36

Constantin Cat,
не совсем. Про переменную величину N проглядел, виноват.
В остальном замечания следующие:
1) сохранять ES не требуется
2) пересылка через стек медленнее, чем через регистр,
3) строки в 255 символов, незачем умножать на 16-битное d,
4) d: Byte было б в самый раз, сл-но mov cl,d; mul cl -- свободны dx, bx, в них можно хранить множитель.

Итого в сухом остатке:

Pascal

var
  a, b: String;
  d: Byte;
begin
  Write('enter string: '); ReadLn(a);
  Write('enter count: '); ReadLn(d);
  b:='error :(';
  asm
    mov  dx,ds
    mov  es,dx
    lea  si,a
    lea  di,b
    xor  ax,ax
    lodsb
    mov  cl,d
    mul  cl
    or   ah,ah
    jnz  @2
    mov  cx,ax
    stosb
    xor  bx,bx
@1:
    lodsb
    xchg cx,bx
    mov  cl,d
    rep  stosb
    xchg cx,bx
    loop @1
@2:
  end;
  Write('result: ',b); ReadLn;
end.

@Constantin Cat · 06.01.2017, 23:33

Сообщение от bormant

сохранять ES не требуется

В именно этом коде нет, а вообще - да;

Сообщение от bormant

пересылка через стек медленнее, чем через регистр,

в учебных программах - это не имеет значения.

Сообщение от bormant

строки в 255 символов, незачем умножать на 16-битное d,

Да, но в вопросе было:

Сообщение от _kaktus_

массива типа char

Строка это только частный случай массива символов. Правильнее было бы получить длину строки(снова этот частный случай), выделить n-памать, скопировать и посимвольно вывести.

@bormant · 07.01.2017, 04:56

Constantin Cat,

При написании отдельных частей программы на языке ассемблера следует иметь в виду, что необходимо сохранить содержимое регистров ВР, SP, SS и DS. Если их необходимо изменить, то исходные значения следует запомнить, а затем восстановить. Остальные регистры можно безболезненно изменять.

ES в списке отсутствует, нет?

Про учебные задачи - отклоняется. В учебных задачах имеет значение не приобретать дурных привычек. В ассемблер пошли зачем, сэкономить такты? Вот и экономьте такты.

Про массив типа Char - отклоняется - 1) сохраняете однобайтную длину, 2) string часть условия.

Добавлено через 11 минут
Получение длины строки есть (xor ax,ax; lodsb), память под приемник выделена, ограниченв 255 байтами. Нормальные условия вполне. Проверку на выход за его пределы вы дописали.

@Constantin Cat 3405 / 1824 / 489 Регистрация: 28.02.2015 Сообщений: 3,699
	06.01.2017, 23:33	6
	Сообщение от bormant сохранять ES не требуется В именно этом коде нет, а вообще - да; Сообщение от bormant пересылка через стек медленнее, чем через регистр, в учебных программах - это не имеет значения. Сообщение от bormant строки в 255 символов, незачем умножать на 16-битное d, Да, но в вопросе было: Сообщение от _kaktus_ массива типа char Строка это только частный случай массива символов. Правильнее было бы получить длину строки(снова этот частный случай), выделить n-памать, скопировать и посимвольно вывести. 0

@bormant Модератор 7481 / 4353 / 2771 Регистрация: 22.11.2013 Сообщений: 12,480 Записей в блоге: 1
	07.01.2017, 04:56	7
	Constantin Cat, При написании отдельных частей программы на языке ассемблера следует иметь в виду, что необходимо сохранить содержимое регистров ВР, SP, SS и DS. Если их необходимо изменить, то исходные значения следует запомнить, а затем восстановить. Остальные регистры можно безболезненно изменять. ES в списке отсутствует, нет? Про учебные задачи - отклоняется. В учебных задачах имеет значение не приобретать дурных привычек. В ассемблер пошли зачем, сэкономить такты? Вот и экономьте такты. Про массив типа Char - отклоняется - 1) сохраняете однобайтную длину, 2) string часть условия. Добавлено через 11 минут Получение длины строки есть (xor ax,ax; lodsb), память под приемник выделена, ограниченв 255 байтами. Нормальные условия вполне. Проверку на выход за его пределы вы дописали. 0

Опции темы