Дан файл, содержащий текст. Получить в другом файле тот же текст, записанный заглавными буквами

program Project1;
 
{Задача:
Дан файл с текстом. Получить в другом файле тот же текст, записанный заглавными буквами.}
 
{Перевод букв строки в верхний регистр. Для кодовой страницы CP866 (OEM, DOS).}
function UpCase866(const aStr : String) : String;
var
  S : String;
  i : Integer;
begin
  S := aStr;
  for i := 1 to Length(S) do
    if S[i] in [#$A0..#$AF] then {Буквы ['а'..'п'].}
      S[i] := Chr(Ord(S[i]) - 32)
    else if s[i] in [#$E0..#$EF] then {Буквы ['р'..'я'].}
      S[i] := Chr(Ord(S[i]) - 80)
    else if S[i] = #$F1 then {Буква 'ё'.}
      S[i] := #$F0
    else
      S[i] := UpCase(S[i]);
  UpCase866 := S;
end;
 
const
  Fn1 = 'file1.txt'; {Имя входного файла.}
  Fn2 = 'file2.txt'; {Имя выходного файла.}
var
  F1, F2 : Text;
  S : String;
begin
  repeat
    Writeln('Входной файл: ', Fn1, ', выходной файл: ', Fn2);
 
    Assign(F1, Fn1); {Связываем файловую переменную с именем файла.}
    Reset(F1); {Открываем текстовый файл для чтения.}
    Assign(F2, Fn2); {Связываем файловую переменную с именем файла.}
    Rewrite(F2); {Создаём текстовый файл и открываем его для записи.}
    while not Eof(F1) do {Если конец файла F1 не достигнут, то продолжаем.}
    begin
      Read(F1, S); {Читаем сроку из файла F1.}
      Write(F2, UpCase866(S)); {Преобразуем буквы строки к верхнему регистру и записываем её в файл F2.}
      if Eoln(F1) and not Eof(F1) then {Точный учёт переноса строк в конце файла.}
      begin
        Readln(F1);
        Writeln(F2);
      end;
    end;
    Close(F1); {Закрываем входной файл.}
    Close(F2); {Закрываем выходной файл.}
 
    Writeln('Содержимое файла ', Fn2, ' сформировано.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.