Определите процедуру для умножения матриц

@zhenyak73 · Регистрация: 16.12.2014

Студворк — интернет-сервис помощи студентам

Есть задание:
Даны натуральное n и (построчно) элементы квадратной вещественной матрицы А четвертого порядка. Вычислить n-ю степень этой матрицы (A1 = A; A2 = A*A; A3 = A2 * A и т.д.).
Указания:
1. Определите процедуру mult(a,b,c) для умножения матриц (a*b = c).
2. Для вычисления n-ой степени матрицы поступайте так же, как при вычислении в цикле n-ой степени числа, но вместо умножения чисел используйте процедуру mult.

Написала программу. НО не могу разобратся как правильно вызвать процедуру. Поскажите пожалуйста.

Pascal

Program L21;
uses crt;
 
var
AA: array [1..4, 1..4] of real;
BB: array [1..4, 1..4] of real;
 
    i,j,q,l: integer;
    n: integer;  {степень в какую надо возвести матрицу А}
    s: real;
 
{Процедура перемножения матрицы}
procedure mult (a, b, c); {написано от Фонаря, так как не знаю как}
begin
 for i:=1 to 4 do
   begin
      for j:=1to 4 do
        begin
          s:=0;
          for q:=1 to 4 do
            begin
              s:=s+AA[i,q]*AA[q,j];
            end;
          BB[i,j]:=s;
        end;
    end;
end;
 
begin
clrscr;
randomize;
write(Введите натуральное число n:');
readln (n);
 
for i:=1 to 4 do
    for j:=1to 4 do
        AA[i,j]:=random(5);
 
writeln;
 
for i:=1 to 4 do
    begin
      for j:=1to 4 do
        begin
          write (AA[i,j]:2:2, ' ' );
        end;
      writeln;
    end;
 
 for i:=1 to 4 do
   begin
      for j:=1to 4 do
        begin
          s:=0;
          for q:=1 to 4 do
            begin
              s:=s+AA[i,q]*AA[q,j];
            end;
          BB[i,j]:=s;
        end;
    end;
 
for i:=1 to n-1 do MULT (a,b,c);
 
writeln;
writeln (Матрица возведенная в степень: ', n);
writeln;
for i:=1 to 4 do
    begin
      for j:=1to 4 do
        begin
          write (BB[i,j]:2:2, ' ' );
        end;
      writeln;
    end;
 
 
readln;
end.

@Puporev · 16.12.2014, 15:10

Pascal

Program L21;
uses crt;
const k=4;
{Процедура перемножения матрицы}
type mtr=array [1..k, 1..k] of real;
procedure mult (a,b:mtr;var c:mtr);
var i,j,q:byte;
begin
for i:=1 to k do
for j:=1 to k do
 begin
  c[i,j]:=0;
  for q:=1 to k do
  c[i,j]:=c[i,j]+a[i,q]*b[q,j];
 end;
end;
var AA,BB,CC:mtr;
    i,j,n:byte;
begin
clrscr;
randomize;
repeat
write('Введите натуральное число от 2 до 7 n=');
readln(n);
until n in [2..7];
writeln('Исходная матрица А');
for i:=1 to k do
 begin
  for j:=1 to k do
   begin
    AA[i,j]:=5*random;
    write(AA[i,j]:5:2);
   end;
  writeln;
 end;
CC:=AA;
for i:=1 to n-1 do
 begin
  mult(CC,AA,BB);
  CC:=BB;
 end;
writeln ('Матрица возведенная в степень ',n);
for i:=1 to k do
 begin
  for j:=1 to k do
  write (BB[i,j]:12:2);
  writeln;
 end;
readln
end.

@zhenyak73 · 16.12.2014, 15:29 **[ТС]**

Спасибо, а я так через TYPE не хотела. Поясните пожалуйста:
1.

Сообщение от Puporev

procedure mult (a,b:mtr;var c:mtr);

почему по разному описаны a,b и c?
2.

Сообщение от Puporev

var AA,BB,CC:mtr;

это из-за условия или можно было бы использовать только АА.
3.

Сообщение от Puporev

CC:=AA;
for i:=1 to n-1 do
begin
mult(CC,AA,BB);
CC:=BB;

Тут воще паника. Почему, зачем???
Буду очень признательна, если просветите. (Не люблю процедуры

)

@Puporev · 16.12.2014, 15:35

Сообщение от zhenyak73

почему по разному описаны a,b и c?

описаны одинаково, слово var перед c означает что матрица с это выходной параметр, создается в процедуре

Сообщение от zhenyak73

это из-за условия или можно было бы использовать только АА.

нам при возведении в степень нужны 3 матрицы, как и написано в процедуре, а значит и 3 фактических параметра.

Pascal

CC:=AA;//запомнили матрицу А
for i:=1 to n-1 do
begin
mult(CC,AA,BB);//умножили С на исходную А, получили В
CC:=BB;//запомним ее, чтобы снова умножать

@zhenyak73 · 18.12.2014, 17:28 **[ТС]**

Огромное спасибо!

@zhenyak73 0 / 0 / 0 Регистрация: 16.12.2014 Сообщений: 10
	16.12.2014, 15:29 [ТС]	3
	Спасибо, а я так через TYPE не хотела. Поясните пожалуйста: 1. Сообщение от Puporev procedure mult (a,b:mtr;var c:mtr); почему по разному описаны a,b и c? 2. Сообщение от Puporev var AA,BB,CC:mtr; это из-за условия или можно было бы использовать только АА. 3. Сообщение от Puporev CC:=AA; for i:=1 to n-1 do begin mult(CC,AA,BB); CC:=BB; Тут воще паника. Почему, зачем??? Буду очень признательна, если просветите. (Не люблю процедуры ) 0

@zhenyak73 0 / 0 / 0 Регистрация: 16.12.2014 Сообщений: 10
	18.12.2014, 17:28 [ТС]	5
	Огромное спасибо! 0

Опции темы

Определите процедуру для умножения матриц

Решение