Упорядочить диапазон элементов массива

@yarok1996 · Регистрация: 18.10.2015

Студворк — интернет-сервис помощи студентам

Не компилируется!
Помогите что не так в програме, Не могу сделать условие чтобы сортировало только числа кратные 5
Составить программу, по которой:
1) заполнить массив A (40) случайным образом целыми числами с диапазона [100, 999];
2) вывести элементы массива на экран в строку;
3) упорядочить диапазон элементов массива при следующих условиях:
Диапазон элементов массива:
Первый :8
Последний:38
Метод упорядочения: выбором
Свойства элементов массива: кратные 5

Pascal

const MaxN = 38;
type TElement = real; TMas = array[8..MaxN] of TElement;
var A : TMas; Nmin, i,N, j : Integer; T :TElement;
 begin
  N:=40;
  randomize;
   for i:=1 to N do begin
   a[i]:=100+Random(900);end;
 WriteLn('До сортировки:');
for i := 1 to N do Write(a[i],' '); WriteLn;
for i := n downto 2 do
for j := 1 to i-1 do
if a[j] > a[j+1]
then begin T := a[j]; a[j] := a[j+1]; a[j+1] := T;
end;
WriteLn('отсортирован:');
for i:=1 to N do
if a[i] mod 5=10 then begin
 write(a[i]);
 end;
   readln;
 end.

ФедосеевПавел · 15.11.2015, 18:47

1.

Сообщение от yarok1996

1) заполнить массив A (40) случайным образом целыми числами с диапазона [100, 999];

Pascal

1 2	type TElement = integer;

2.

Сообщение от yarok1996

Свойства элементов массива: кратные 5

Pascal

1	if a[i] mod 5=0 then begin

Добавлено через 11 минут
Сортировать нужно не так.
1. Просматриваешь массив от 8 до 38. Ищешь первый элемент кратный 5.
2. Просматриваешь массив от индекса первого кратного 5 элемента до 38. Ищешь самый маленький из кратных 5.
3. Обмениваешь его с первым найденным.
4. Повторяешь пункты 1-3 но не от 8 индекса, а от первого найденного.

Добавлено через 1 час 9 минут

Pascal

program test;
 
const
  NMax = 40;
  NSortMin = 8;
  NSortMax = 38;
type
  TElement = integer;
  TMas = array[1..NMax] of TElement;
var
  A: TMas;
  i, j, Indx: integer;
  tmp: TElement;
begin
  randomize;
  for i := 1 to NMax do
  begin
    a[i] := 100 + Random(900);
  end;
  WriteLn('До сортировки:');
  for i := 1 to NMax do
    Write(a[i], ' ');
  WriteLn;
  for i := 1 to NMax do
    if (a[i] mod 5 = 0) and (i >= NSortMin) and (i <= NSortMax) then
      Write('*** ')
    else
      Write('    ');
  writeln;
  for i := NSortMin to NSortMax do
  begin
    if a[i] mod 5 <> 0 then
      continue;
    Indx := i;
    for j := i + 1 to NSortMax do
    begin
      if (a[j] mod 5 = 0) and (a[j] < a[Indx]) then
        Indx := j;
    end;
    tmp  := a[i];
    a[i] := a[Indx];
    a[Indx] := tmp;
  end;
  WriteLn('отсортирован:');
  for i := 1 to NMax do
    Write(a[i], ' ');writeln;
  for i := 1 to NMax do
    if (a[i] mod 5 = 0) and (i >= NSortMin) and (i <= NSortMax) then
      Write('*** ')
    else
      Write('    ');
  writeln;
  readln;
end.

Опции темы