В заданном предложении поменять местами самое длинное и самое короткое слова

program Project1;
 
type
  //Сведения о координатах слова.
  TWInfo = record
    Start, Len : Integer;
  end;
 
const
  //Множество разделителей слов.
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
var
  S, Sw : String;
  i, Pos1, Len, LenW : Integer;
  W, W1, W2 : TWInfo;
begin
  repeat
    Writeln('Задайте текст:');
    Readln(S);
    Len := Length(S);
 
    Pos1 := 0;
    //Начальное задание координат самого короткого слова.
    W1.Start := 0;
    W1.Len := Len;
    //Начальное задание координат самого длинного слова.
    W2.Start := 0;
    W2.Len := 0;
    for i := 1 to Len do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Отслеживаем начало слова.
      if (i = 1) or (S[i - 1] in D) then Pos1 := i;
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        LenW := i - Pos1 + 1;
        if LenW < W1.Len then begin
          W1.Len := LenW;
          W1.Start := Pos1;
        end;
        if LenW > W2.Len then begin
          W2.Len := LenW;
          W2.Start := Pos1;
        end;
      end;
    end;
 
    //Меняем слова местами.
    if (W1.Start > 0) and (W2.Start > 0) then begin
      //Меняем данные так, чтобы в записи W1 было то слово,
      //которое расположено левее, а в W2 - то, которое правее.
      if W1.Start > W2.Start then begin
        W := W1;
        W1 := W2;
        W2 := W;
      end;
 
      //Запоминаем правое слово.
      Sw := Copy(S, W2.Start, W2.Len);
      //Удаляем правое слово.
      Delete(S, W2.Start, W2.Len);
      //На место правого слова вставляем левое слово.
      Insert(Copy(S, W1.Start, W1.Len), S, W2.Start);
      //Удаляем левое слово.
      Delete(S, W1.Start, W1.Len);
      //На место левого слова записываем правое слово.
      Insert(Sw, S, W1.Start);
      //Вывод результатов.
      Writeln('Изменённый текст:');
      Writeln(S);
    end else begin
      Writeln('Недостаточно слов в заданном тексте.');
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.