Напечатать в алфавитном порядке все глухие согласные буквы, которые не входят хотя бы в одно слово.

program Project1;
 
//Возвращает заглавную версию буквы для кодовой страницы CP866.
function UpCase866(const aChar : Char) : Char;
begin
  case aChar of
    #$A0..#$AF : UpCase866 := Char( Ord(aChar) - $20 ); //Буквы: а..п.
    #$E0..#$EF : UpCase866 := Char( Ord(aChar) - $50 ); //Буквы: р..я.
    #$F1 : UpCase866 := #$F0; //Буква ё.
  else
    UpCase866 := UpCase(aChar); //Все другие символы.
  end;
end;
 
const
  //Множество разделителей слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
  //Множество глухих согласных букв.
  Da = ['К', 'П', 'С', 'Т', 'Ф', 'Х', 'Ц', 'Ч', 'Ш', 'Щ'];
var
  S : String;
  Ch : Char;
  i, Len : Integer;
  DTmp, DRes : set of Char;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    Len := Length(S);
    DTmp := [];
    DRes := [];
    for i := 1 to Len do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Формируем множество глухих согласных букв, которые
      //присутствуют в текущем слове.
      Ch := UpCase866(S[i]);
      if Ch in Da then DTmp := DTmp + [Ch];
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        //Добавляем в результирующее множество те глухие согласные
        //буквы, которые не присутствуют в текущем слове.
        DRes := DRes + (Da - DTmp);
        //Обнуление временного множества.
        DTmp := [];
      end;
    end;
 
    Writeln('Перечень глухих согласных букв, которые не присутствуют');
    Writeln('хотябы в одном слове:');
    i := 0;
    for Ch := #0 to #255 do begin
      if not (Ch in DRes) then Continue;
      Inc(i);
      if i > 1 then Write(', ');
      Write(Ch);
    end;
    Writeln;
    Writeln;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.