В алфавитном порядке вывести все звонкие согласные, которые входят в каждое нечетное слово и не входят ни в одно четное слово

...........................................
 //Сортируем массив слов по возрастанию - т. е. в порядке возрастания
    //кодов символов, согласно действующей в данный момент кодировочной таблице.
    //Это означает, что слова будут отсортированы почти по алфавиту. - Не по
    //алфавиту будут отсортированы только те слова, которые содержат букву "Ё" или "ё".
    //Для кодовой страницы CP866 (DOS, OEM) коды букв "Ё" и "ё" больше кода буквы "я".
    //Для кодовой страницы CP1251 (Windows) коды букв "Ё" и "ё" меньше кода буквы "А".
 
    //Метод сортировки - пузырьковая сортировка.
    for i := LenA - 1 downto 1 do begin
     repeat
       IsExch := False;
       for j := 1 to i do begin
         if Arr[j] > Arr[j + 1] then begin
           SWord := Arr[j];
           Arr[j] := Arr[j + 1];
           Arr[j + 1] := sWord;
         end;
       end;
     until not IsExch;
    end;
...........................................

program Project1;
 
//Возвращает заглавную версию буквы для кодовой страницы CP866.
function UpCase866(const aChar : Char) : Char;
begin
  case aChar of
    #$A0..#$AF : UpCase866 := Char( Ord(aChar) - $20 ); //Буквы: а..п.
    #$E0..#$EF : UpCase866 := Char( Ord(aChar) - $50 ); //Буквы: р..я.
    #$F1 : UpCase866 := #$F0; (*Буква ё.*)
  else
    UpCase866 := UpCase(aChar); //Все другие символы.
  end;
end;
 
const
  //Множество разделителей слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
  //Множество звонких согласных букв.
  Da = ['Б', 'В', 'Г', 'Д', 'Ж', 'З', 'Л', 'М', 'Н', 'Р'];
var
  S : String;
  Ch : Char;
  i, j, Len : Integer;
  D1, D2, DTmp : set of Char;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    Len := Length(S);
    D1 := [];
    D2 := [];
    DTmp := [];
    j := 0;
    for i := 1 to Len do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Формируем множество звонких согласных букв, которые
      //присутствуют в текущем слове.
      Ch := UpCase866(S[i]);
      if Ch in Da then DTmp := DTmp + [Ch];
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        //Порядковый номер слова.
        Inc(j);
        if j mod 2 <> 0 then begin
          //На первом нечётном слове инициализируем множество D1.
          if j = 1 then D1 := DTmp;
          //Во множество D1 попадают только те звонкие согласные
          //буквы, которые присутствуют одновременно и в D1 и в DTmp.
          D1 := D1 * DTmp; //Если слово нечётное.
          //Если D1 стало пустым - нет смысла продолжать обработку.
          if D1 = [] then Break;
        end else
          D2 := D2 + DTmp //Если слово чётное.
        ;
        //Обнуляем временное множество.
        DTmp := [];
      end;
    end;
 
    //Результирующее множество: все найденные звонкие согласные буквы,
    //которые присутствуют в каждом нечётном слове, но не присутствуют
    //ни в одном чётном слове.
    DTmp := D1 - D2;
 
    //Распечатка результатов.
    if DTmp = [] then begin
      Writeln('Нет ни одной звонкой согласной буквы, которая бы');
      Writeln('присутствовала в каждом нечётном слове, но не присутствовала');
      Writeln('ни в одном чётном слове.');
    end else begin
      Writeln('Перечень звонких согласных букв, которые присутствуют');
      Writeln('в каждом нечётном слове, но не присутствуют');
      Writeln('ни в одном чётном слове:');
      i := 0;
      for Ch := #0 to #255 do begin
        if not (Ch in DTmp) then Continue;
        Inc(i);
        if i > 1 then Write(', ');
        Write(Ch);
      end;
      Writeln;
    end;
    Writeln;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

var
  S : String;
  Ch : Char;
  i, j, Len : Integer;
  D1, D2, DTmp : set of Char;