Создание и корректировка файла, содержащего сведения о студентах.

uses crt;
const filename='student';
const n=4;
type student=record
             grp:word;
             nom:byte;
             fam:string[20];
             im:string[20];
             otc:string[20];
             god:word;
             ocn:array[1..n] of byte;
             end;
tfile=file of student;
var b:boolean;{переменная для фиксации существования файла}
{ввод данных}
procedure Vvod(var st:student);
var k,i:byte;
begin
with st do
 begin
  repeat
  write(' Номер группы (число из 4х цифр)): ');
  readln(grp);
  until (grp>999)and(grp<=9999);
  repeat
  write(' Номер в списке(число от 1 до 30): ');
  readln(nom);
  until nom in [1..30];
  write(' Фамилия: ');readln(fam);
  write(' Имя: ');readln(im);
  write(' Отчество: ');readln(otc);
  repeat
  write(' Год рождения(1985-1994): ');
  readln(god);
  until(god>=1985)and(god<=1994);
  writeln(' Оценки за сессию(2-5):');
  for k:=1 to n do
   begin
    repeat
    write('  оценка ',k,'  ');
    readln(ocn[k]);
    until ocn[k] in [2..5];
   end;
 end;
end;
{создание файла записей}
procedure WriteFile(var t:tfile);
var m,i,k:integer;
    st:student;
begin
rewrite(t);
write('Количество записей m=');
readln(m);
writeln('Введите данные о студентах:');
for i:=1 to m do
 begin
  writeln('Студент ',i);
  Vvod(st);
  write(t,st);
 end;
close(t);
b:=true;
write('Press Enter...');
readln
end;
{открытие файла для чтения и редактирования}
procedure OpenFile(var t:tfile);
begin
if not b then
 begin
  writeln('Файл еще не создан, вернитесь к пункту 1');
  write('Press Enter...');
  readln;
  exit;
 end
else reset(t);
end;
{добавление записи}
procedure AddFile(var t:tfile);
var st:student;
begin
OpenFile(t);
if not b then exit;
writeln('Введите данные о студенте:');
Vvod(st);
seek(t,filesize(t));
write(t,st);
close(t);
write('Press Enter...');
readln
end;
{удаление записи из файла}
procedure DelFile(var t:tfile);
var n,i:integer;
    st:student;
begin
write('Удалить запись № ');
readln(n);
OpenFile(t);
if not b then exit;
if (filesize(t)<n)or(n<0) then
 begin
  writeln('В файле нет такой записи');
  close(t);
  write('Press Enter...');
  readln;
  exit;
 end;
seek(t,n-1);
for i:=n-1 to filesize(t)-2 do
 begin
  seek(t,i+1);
  read(t,st);
  seek(t,i);
  write(t,st);
 end;
seek(t,filesize(t)-1);
truncate(t);
close(t);
write('Press Enter...');
readln
end;
{редактирование записи}
Procedure Redakt(var t:tfile);
var n:integer;
    st:student;
begin
write('Заменить запись № ');
readln(n);
OpenFile(t);
if not b then exit;
if (filesize(t)<n)or(n<0) then
 begin
  writeln('В файле нет такой записи');
  close(t);
  write('Press Enter...');
  readln;
  exit;
 end;
seek(t,n-1);
writeln('Введите новые данные о студенте:');
Vvod(st);
write(t,st);
close(t);
write('Press Enter...');
readln
end;
{создание текстового файла}
procedure TextFile(var t:tfile;var f:text);
var gr:word;
    s:string;
    st:student;
    k,i,j:byte;
begin
OpenFile(t);
if not b then exit;
write('Имя файла ');{для каждой группы свое имя файла}
readln(s);
s:=s+'.txt';
assign(f,s);
rewrite(f);
k:=0;
writeln('Введите номер группы для поиска');
readln(gr);
while not eof(t) do
 begin
  read(t,st);
  if st.grp=gr then
   begin
    k:=1;
    with st do
     begin
      write(f,grp,' ',nom,' ',fam,' ',im,' ',otc,' ',god);
      for j:=1 to n do
      write(f,' ',ocn[j]);
     end;
    writeln(f,'');
   end;
  end;
if k=0 then writeln(f,'Takogo nomera gruppy net!');
close(t);
close(f);
write('Press Enter...');
readln
end;
{чтение исходного файла}
procedure ReadFile(var t:tfile);
var st:student;
    i:byte;
begin
OpenFile(t);
if not b then exit;
writeln('Содержание исходного файла:');
writeln('-------------------------------------------------------------------');
writeln('|Группа|Номер|   Фамилия   |  Имя  |   Отчество  | Г. р. | Оценки |');
writeln('-------------------------------------------------------------------');
while not eof(t) do
 begin
  read(t,st);
  with st do
   begin
    gotoXY(1,whereY);write('|',grp:5);
    gotoXY(8,whereY);write('|',nom:4);
    gotoXY(14,whereY); write('| ',fam);
    gotoXY(28,whereY); write('| ',im);
    gotoXY(36,whereY); write('| ',otc);
    gotoXY(50,whereY); write('|',god:5);
    gotoXY(58,whereY); write('|');
    for i:=1 to n do
    write(' ',ocn[i]);
    gotoXY(67,whereY); writeln('|');
   end;
 end;
writeln('-------------------------------------------------------------------');
write('Press Enter...');
readln
end;
var st:student;
    g:tfile;
    f:text;
    c:char;
begin
clrscr;
assign(g,filename);
b:=false;
repeat
clrscr;
writeln('Выберите действие:');
writeln('1-создать новый файл');
writeln('2-добавить запись');
writeln('3-удалить запись');
writeln('4-редактировать запись');
writeln('5-прочитать файл');
writeln('6-создать текстовый файл');
writeln('другое-выход');
readln(c);
case c of
'1':WriteFile(g);
'2':AddFile(g);
'3':DelFile(g);
'4':Redakt(g);
'5':ReadFile(g);
'6':TextFile(g,f);
else exit;
end;
until not(c in ['1'..'6']);
end.

with st do

reset(f);
seek(f,filesize(f));
write(f,zap);

procedure AddFile(var t:tfile);
var st:student;
begin
OpenFile(t);
if not b then exit;
writeln('Введите данные о студенте:');
Vvod(st);
reset (f);
seek(f,filesize(f));
write(f,zap);
close(t);
write('Press Enter...');
readln

writeln('______________________________________________________________________');
 close(t);//вот это, закрыть файл после просмотра, и все работает
 write('Press Enter...');