Написать функцию, которая использует исходный список L и создает два новых списка L1 и L2. L1 содержит нечетные числа, а L2 – четные

program Project1;
 
type
  //Типы для описания списка.
 
  //Тип данных - определяет данные, которые будет содержать каждый элемент списка.
  TData = Integer;
  //Тип, описывающий элемент списка.
  TPElem = ^TElem;
  TElem = record
    Data : TData;
    PNext : TPElem;
  end;
  //Тип, описывающий список.
  TList = record
    PFirst : TPElem;
    PLast : TPElem;
  end;
 
//Процедуры для работы со списком.
 
//Удаление всего списка из памяти и инициализация.
procedure ListFree(var aList : TList);
var
  PNext, PDel : TPElem;
begin
  if aList.PFirst = nil then Exit;
 
  PNext := aList.PFirst;
  while PNext <> nil do begin
    PDel := PNext;
    PNext := PNext^.PNext;
    Dispose(PDel);
  end;
 
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
//Добавление элемента в конец списка.
procedure AddL(var aList : TList; const aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  aPElem^.PNext := nil;
  if aList.PFirst = nil then begin
    aList.PFirst := aPElem;
    aList.PLast := aPElem;
  end else begin
    aList.PLast^.PNext := aPElem;
    aList.PLast := aPElem;
  end;
end;
 
var
  List1, List2, List3 : TList;
  PElem, PNew : TPElem;
  S : String;
begin
  List1.PFirst := nil;
  List1.PLast := nil;
  List2.PFirst := nil;
  List2.PLast := nil;
  List3.PFirst := nil;
  List3.PLast := nil;
 
  repeat
    Writeln('Задайте список целых чисел через пробел');
    Writeln('и нажмите Enter:');
    repeat
      New(PElem);
      Read(PElem^.Data);
      AddL(List1, PElem);
    until Eoln(Input);
    Readln;
 
    //Распечатка элементов списка.
    Writeln('Составлен динамический список. Элементы списка:');
    PElem := List1.PFirst;
    while PElem <> nil do begin
      if PElem <> List1.PFirst then Write(', ');
      Write(PElem^.Data);
      PElem := PElem^.PNext;
    end;
    Writeln;
 
    //Составление списков чётных и нечётных чисел.
    PElem := List1.PFirst;
    while PElem <> nil do begin
      New(PNew);
      PNew^.Data := PElem^.Data;
      if PElem^.Data mod 2 = 0 then
        AddL(List2, PNew)
      else
        AddL(List3, PNew)
      ;
      PElem := PElem^.PNext;
    end;
 
    //Распечатка составленных списков.
 
    Writeln('Список чётных чисел:');
    PElem := List2.PFirst;
    while PElem <> nil do begin
      if PElem <> List2.PFirst then Write(', ');
      Write(PElem^.Data);
      PElem := PElem^.PNext;
    end;
    Writeln;
 
    Writeln('Список нечётных чисел:');
    PElem := List3.PFirst;
    while PElem <> nil do begin
      if PElem <> List3.PFirst then Write(', ');
      Write(PElem^.Data);
      PElem := PElem^.PNext;
    end;
    Writeln;
 
    //Удаление списокв из памяти.
    ListFree(List1);
    ListFree(List2);
    ListFree(List3);
    Writeln('Списки удалены из памяти.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.