Построить график функции, на этом же графике построить графики первой и второй производных функции

uses graph;
const
x1=-4;{начало и конец графиков в реальных значениях}
x2=4;
function F1(x:real):real;
begin
F1:=5*x*x*x*x/12+2*x*x*x/3-9*x*x/2;
end;
function F2(x:real):real;
begin
F2:=5*x*x*x/3+2*x*x-9*x;
end;
function F3(x:real):real;
begin
F3:=5*x*x+4*x-9;
end;
function Bisec(a,b,e:real):real;
var c:real;
begin
repeat
 c:=(a+b)/2;
 if F2(a)*F2(c)<=0 then b:=c
 else a:=c;
until b-a<e;
Bisec:=(a+b)/2;
end;
var a,b,mx,my,x,dx,y1,y2,y3,y4:real;
    x0,y0,grD,px,py,grM,i,k:integer;
    s,s1:string;
begin
grD:=detect;
initgraph(grD,grM,'');
x0:=getmaxX div 2;{начало координат в центре экрана}
y0:=getmaxY div 2;
{коэффициенты по осям для перевода реальных координат в экранные}
mx:=600/(x2-x1);{длина в пикселах по оси Х/реальная длина}
my:=(y0-20)/F1(x2);{длина оси по У/(макс}
SetBkColor(15); {цвет фона}
setlinestyle(0,0,1);{сплошная линия}
SetColor(1);{цвет линий осей}
line(0,y0,getmaxX,y0); {ось Х}
line(x0,getmaxy,x0,0); {ось У}
for i:=1 to round(F1(x2)/10)+1 do   {максимальное количество засечек в одну сторону}
   begin
    line(x0-3,y0-round(i*my*10),x0+3,y0-round(i*my*10));{засечки на оси У}
    line(x0-3,y0+round(i*my*10),x0+3,y0+round(i*my*10));
    line(x0+round(i*mx),y0+3,x0+round(i*mx),Y0-3); {засечки на оси Х}
    line(x0-round(i*mx),y0+3,x0-round(i*mx),Y0-3);
    str(i*10,s);
    {подпись оси У}
    outtextXY(x0-20,y0-round(i*my*10),s);{соответственно засечкам}
    outtextXY(x0-25,y0+round(i*my*10),'-'+s);
    {подпись оси Х}
    str(i,s);
    outtextXY(x0+round(i*mx),y0+10,s);
    outtextXY(x0-round(i*mx),y0+10,'-'+s);
  end;
{центр}
outtextXY(x0+5,y0+10,'0');
{подписи концов осей}
outtextXY(getmaxX-10,y0-10,'X');
outtextXY(x0+10,10, 'Y');
dx:=0.001;
{график}
x:=x1;
while x<=x2 do
 begin
  px:=x0+round(x*mx); {изменение по оси Х}
  y1:=F1(x); {график в реальных координатах}
  py:=y0-round(y1*my);{в экранных}
  putpixel(px,py,4);
  y2:=F2(x); {график в реальных координатах}
  py:=y0-round(y2*my);{в экранных}
  putpixel(px,py,2);
  y3:=F3(x); {график в реальных координатах}
  py:=y0-round(y3*my);{в экранных}
  putpixel(px,py,9);
  x:=x+dx; {наращиваем х}
 end;
{корни, интервалы выделены графически в Экселе}
setcolor(2);
setlinestyle(0,0,3);
circle(x0+round(Bisec(-3.5,-2.5,0.001)*mx),y0,2);
circle(x0+round(Bisec(-1,1,0.001)*mx),y0,2);
circle(x0+round(Bisec(1,2,0.001)*mx),y0,2);
outtextXY(35,y0+140,'Korni pervoj proizvodnoj');
str(Bisec(-3.5,-2.5,0.001):6:3,s);
outtextXY(50,y0+160,'x1='+s);
str(Bisec(-1,1,0.001):6:3,s);
outtextXY(50,y0+180,'x2='+s);
str(Bisec(1,2,0.001):6:3,s);
outtextXY(50,y0+200,'x3='+s);
{заголовок}
setcolor(4);
settextstyle(0,0,1);
outtextXY(5,30,'Grafik functii F =5x^4/12+2x^3/3-9x^2/2');
setcolor(2);
outtextXY(5,50,'Grafik functii F'+#39+'=5x^3/3+2x^2-9x)');
setcolor(9);
outtextXY(5,70,'Grafik functii F"=5x^2+4x-9');
readln
end.