Найти номер последней из ее строк, содержащих максимальное количество одинаковых элементов.

uses crt;
const
  n=6;  {Число строк}
  m=10; {Число столбцов}
type
  Vector=Array[1..m] of Integer; {Строка}
  Matrix=Array[1..n] of Vector;  {Массив строк (матрица)}
  Elm=Record  {Запись вхождения элемента в строку, value - значение, count - количество}
    value, count: Integer;
  end;
  {Функция возвращает максимальное число одинаковых элементов в строке}
  function MaxEq(var V: Vector): Integer;
  var
    E: Array[1..m] of Elm; {Массив вхождений элементов}
    i, j, k, max: Integer;
  begin
    k:=0; {Количество элементов в массиве Е}
    for i:=1 to m do
    begin
      j:=1;
      {Проверка на наличие элемента в массиве вхождений}
      while (j<=k) and (V[i]<>E[j].value) do Inc(j); 
      if j>k then {Если элемент не найден, добавляем его в массив вхождений}
      begin
        Inc(k);
        E[k].value:=V[i];
        E[k].count:=1;
      end
      else Inc(E[j].count); {Иначе увеличиваем счетчик соответствующего элемента}
    end;
    {Поис элемента с максимальным числом вхождений (ч.в.)}
    max:=1; {Индекс элемента с ч.в.}
    for i:=2 to k do
      if E[i].count>E[max].count then max:=i; {Если ч.в. очередного элемента > максимального, запоминаем его индекс}
    MaxEq:=E[max].count; {Возвращаем максимальное число вхождений}
  end;
 
var
  A: Matrix;
  i, j, v, vmax, imax: Integer;
begin
  ClrScr;
  Randomize;
  {Генерация массива}
  Writeln('Матрица');
  for i:=1 to n do
  begin
    for j:=1 to m do
    begin
      A[i,j]:=Random(11)-5;
      Write(A[i,j]:4);
     end;
     Writeln;
   end;
   {Поиск строки с максимальным числом одинаковых элементов} 
   vmax:=0; 
   imax:=0;
   for i:=1 to n do
   begin
     v:=MaxEq(A[i]);
     if v>=vmax then
     begin
       vmax:=v;
       imax:=i;
     end;
   end;
   Writeln('Номер посл. строки с макс. числом одинаковых элементов = ', imax);
   Readkey;
end.

const 
  n=7;
type
  Tmatrix=array[1..n,1..n] of integer;
var
  a:Tmatrix;
  i,j,f,k,max,imax:integer;
  z:boolean;
begin
  randomize;
  writeln('Ishodnaya matritsa:');
  for i:=1 to n do
    begin
      for j:=1 to n do
        begin
          a[i,j]:=random(3);
          write(a[i,j]:4);
        end;
      writeln;
    end;
  writeln;
  z:=false;
  for f:=1 to n do
    for j:=1 to n do
      begin
        k:=0;
        for i:=1 to n do
          if a[f,j]=a[f,i] then
            inc(k);
        if not z then
          begin
            z:=true;
            max:=k;
            imax:=f;
          end
        else if k>max then
          begin
            max:=k;
            imax:=f;
          end
        else if k=max then
          imax:=f;
      end;
  writeln('Poslednya stroka s max kol-vom odinakovyh elementov ',imax);
  readln;
end.