Динамический кольцевой список. Вывести n раз. Ошибка не выдает 1-ый символ.

type
  TPElem=^TElem;
  TElem=record
  Data:Char;
  PNext:TPElem;
  end;
  TQ=record
  PFirst,PLast:TPElem;
  end;
 
procedure QAdd(var aQ:TQ; var aPElem:TPElem);
begin
  if aPElem=nil then Exit;
  aPElem^.PNext:=nil;
  if aQ.PFirst=nil then
    aQ.PFirst:=aPElem
  else
    aQ.PLast^.PNext:=aPElem;
  aQ.PLast:=aPElem;
end;
 
function QDel(var aQ:TQ; var aPElem:TPElem):Boolean;
begin
  QDel:=False;
  if aQ.PFirst=nil then Exit;
  aPElem:=aQ.PFirst;
  aQ.PFirst:=aPElem^.PNext;
  if aQ.PFirst=nil then aQ.PLast:=nil;
  QDel:=True;
end;
 
procedure QFree(var aQ:TQ);
var
  PDel:TPElem;
begin
  while QDel(aQ,PDel) do Dispose(PDel);
end;
 
procedure QPrint(var aQ:TQ);
var
  QQ:TQ;
  PElem:TPElem;
  i:Integer;
begin
  QQ.PFirst:=nil;
  QQ.PLast:=nil;
  i:=0;
  while QDel(aQ,PElem) do begin
    QAdd(QQ,PElem);
    Inc(i);
    if i>1 then Write(PElem^.Data);
  end;
  Writeln;
  while QDel(QQ,PElem) do QAdd(aQ,PElem);
end;
 
var
  QSp:TQ;
  PElem:TPElem;
  i,n:Integer;
  S:String;
begin
  QSp.PFirst:=nil;
  QSp.PLast:=nil;
  repeat
    Writeln('Введите текст:');
    Readln(S);
    for i:=1 to Length(S) do begin
    New(PElem);
        PElem^.Data:=S[i];
        QAdd(QSp,PElem);
    end;
    Writeln('Сколько раз повторить введенный текст: ');
    Readln(n);
    for i:=1 to n do begin
    QPrint(QSp);
      end;
    Writeln('Повтор - Enter. Выход - Esc.');
    Readln(S);
  until S <> '';
end.

 if i>0 then Write(PElem^.Data);

program Project1;
 
type
  //Кольцевой список.
 
  //Тип указателя на элемент списка.
  TPElem = ^TElem;
  //Тип элемента списка.
  TElem = record
    Data : Char;
    PNext : TPElem;
  end;
  //Для кольцевого списка не будем заводить отдельный тип.
  //Кольцевой список будет представлен указателем типа PList : TPElem.
  //Этот указатель указывает на последний элемент списка.
  //Соответственно, указателем на первый элемент списка является: PList^.PNext.
 
//Добавление элемента в конец однонаправленного кольцевого списка.
procedure AddL(var aPList, aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  if aPList = nil then
    aPElem^.PNext := aPElem //Единственный элемент указывает сам на себя.
  else begin
    //Добавляем новый элемент после последнего в списке.
    aPElem^.PNext := aPList^.PNext;
    aPList^.PNext := aPElem;
  end;
  //Указатель списка переводим на добавленный элемент. - Теперь он является
  //последним в списке.
  aPList := aPElem;
end;
 
//Удаление однонаправленного кольцевого списка из памяти и инициализация.
procedure ListFree(var aPList : TPElem);
var
  PLast, PDel : TPElem;
begin
  if aPList = nil then Exit;
 
  PLast := aPList;
  repeat
    PDel := aPList;
    aPList := aPList^.PNext;
    Dispose(PDel);
  until aPList = PLast;
  aPList := nil;
end;
 
//Распечатка кольцевого однонаправленного списка aN раз.
procedure ListPrint(const aPList : TPElem; const aN : Word);
var
  PElem : TPElem;
  i, Cnt : Integer;
begin
  if aPList = nil then begin
    Writeln('Список пуст.');
    Exit;
  end;
 
  PElem := aPList^.PNext; //Указатель на первый элемент списка.
  i := 0;
  Cnt := 0; //Счётчик пройденных колец.
  while Cnt < aN do begin
    Inc(i);
    if i > 1 then Write(', ');
    Write(PElem^.Data);
    if PElem = aPList then Inc(Cnt); //Подсчёт пройденных колец.
    PElem := PElem^.PNext;
  end;
  Writeln;
end;
 
var
  PList, PElem : TPElem;
  S : String;
  i : Integer;
  N : Word;
begin
  //Начальная инициализация списка.
  PList := nil;
 
  repeat
    Writeln('Задайте строку:');
    Readln(S);
    Writeln('Задайте количество распечаток:');
    Readln(N);
 
    //Создаём кольцевой список.
    for i := 1 to Length(S) do begin
      New(PElem);
      PElem^.Data := S[i];
      AddL(PList, PElem);
    end;
    //Распечатка.
    Writeln('Распечатка кольцевого списка N раз:');
    ListPrint(PList, N);
    //Удаление списка из памяти.
    ListFree(PList);
    Writeln('Список удалён из памяти. Работа завершена.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.