Разработать программу, которая меняет местами первое слово со вторым, третье с четвертым и т. д.

program Project1;
 
const
  //Множество разделителей слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  S, Sw : String;
  i, Len, LenW, LenW1, CntW, P1, P2 : Integer;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    Len := Length(S);
 
    CntW := 0; //Счётчик слов.
    LenW := 0; //Длина очередного слова.
    LenW1 := 0; //Длина нечётного слова.
    P1 := 0; //Позиция начала нечётного слова.
    for i := 1 to Len do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Учитываем очередной знак в длине слова.
      Inc(LenW);
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        //Счётчик слов.
        Inc(CntW);
        //Если это чётное слово, то выполняем перестановку слов.
        if CntW mod 2 = 0 then begin
          P2 := i - LenW + 1; //Позиция начала чётного слова.
          Sw := Copy(S, P2, LenW); //Запоминаем чётное слово.
          Delete(S, P2, LenW); //Удаление чётного слова.
          Insert(Copy(S, P1, LenW1), S, P2); //На место чётного слова вставляем нечётное.
          Delete(S, P1, LenW1); //Удаление нечётного слова на его прежнем месте.
          Insert(Sw, S, P1); //На место нечётного слова вставляем чётное.
        //Если это нечётное слово, то запоминаем его координаты.
        end else begin
          P1 := i - LenW + 1;
          LenW1 := LenW;
        end;
        //Сброс длины очередного слова.
        LenW := 0;
      end;
    end;
 
    //Ответ.
    Writeln('Строка после обработки:');
    Writeln(S);
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.