Найдите в предложении все слова, в которых встречаются первые три буквы первого слова предложения.

program Project1;
 
const
  //Разделители слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  S : String;
  D1, Dx : set of Char;
  i, j, k, Cnt, Len, LenW : Integer;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    Writeln('Перечень слов, в которых присутствуют первые три буквы первого слова:');
    Len := Length(S);
    LenW := 0; //Длина очередного слова.
    D1 := []; //Множество, состоящее из первых трёх букв первого слова.
    Dx := []; //Множество букв в очередном обработанном слове.
    j := 0;
    Cnt := 0;
    for i := 1 to Len do begin
      if S[i] in D then Continue; //Пропускаем разделители.
      Inc(LenW); //Учитываем текущий символ в длине слова.
      Dx := Dx + [S[i]]; //Добавляем в множество очередной символ.
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        Inc(j); //Порядковый номер слова.
        if j = 1 then begin //Если это первое слово.
          if LenW < 3 then Writeln('Внимание! В первом слове меньше 3-х букв.'
            + ' Будут учитываться все имеющиеся буквы первого слова.');
          //Во множество D1 записываем не более 3-х первых букв первого слова.
          k := 1;
          while (k <= 3) and (k <= LenW) do begin
            D1 := D1 + [ S[i - LenW + k] ];
            Inc(k);
          end;
        end else if D1 - Dx = [] then begin //Распечатываем слово и его порядковый номер.
          Inc(Cnt);
          if Cnt > 1 then Write('; ');
          Write(j, ': "', Copy(S, i - LenW + 1, LenW), '"');
        end;
        LenW := 0;
        Dx := [];
      end;
    end;
    Writeln;
 
    if Cnt = 0 then
      Writeln('Нет ни одного слова, в котором присутствовали бы первые 3 буквы первого слова.');
 
    Writeln('Повторить - Enter, выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.