Создать новый массив, элементами которого являются суммы первой и последней цифры каждого числа старого массива

uses
    crt;
 
const
    Size=10;
 
 
type
    tArr=array [1..Size,1..Size] of integer;
 
 
procedure   genArray(var arr:tArr;var i,j:integer);
    const
        max=100;
    
    var
        i1,j1:integer;
    
    begin
        i:=1+random(10);
        j:=1+random(10);
        for i1:=1 to i do
            for j1:=1 to j do
                    arr[i1,j1]:=random(max)
    end;
 
 
procedure   printArray(var arr:tArr;var i,j:integer);
    var
    i1,j1:integer;
    
    begin
        for i1:=1 to i do begin
            for j1:=1 to j do
                    write(arr[i1,j1],' ');
                writeln;
        end;
    end;
 
 
procedure   genNewArr(var oldArr,newArr:tArr; var i,j:integer);
    var
        error,i1,j1:integer;
        firstdigit:integer;
        text:string;
    
    begin
        for i1:=1 to i do begin
            for j1:=1 to j do begin
                    str(oldArr[i1,j1],text);
                    val(text[1],firstdigit,error);
                    newArr[i1,j1]:=oldArr[i1,j1] mod 10+firstdigit;
                end;
        end;
    end;
 
 
var
    old,new:tArr;
    i,j:integer;
 
 
begin
    clrscr;
    randomize;
    GenArray(old,i,j);
    PrintArray(old,i,j);
    readln;
    genNewArr(old,new,i,j);
    PrintArray(new,i,j);
    readln;
end.

program _matrix;
 
const 
 
 ln         = 10;
 Col        = 10;
 
type
 
 TMatrix    = array [0..Ln,0..Col] of integer;
 
var
 
 Cur_Mtr    : TMatrix;
 Mod_Mtr    : TMatrix;
 i,j        : byte;
 
function RandomInt(X1,X2 : integer):integer;
{возвращает случайное целое из (X1;X2)}
var
 x,abs_max  : integer;
 sign       : 0..1;
begin
 if X1<X2 then
 begin
  if abs(x1) > abs(x2) 
   then abs_max:=abs(X1) 
   else abs_max:=abs(X2);   
  repeat 
   x:=Random(abs_max);
   sign:=random(2);
   if sign>0 then x:=-x;
  until (x > X1) and (x < X2);
          RandomInt:=x;     
 end 
 else     RandomInt:=0;
end;
 
procedure FillMatrix(var M : TMatrix;
                     rnd   : boolean; 
                     lmax  : byte;
                     Cmax  : byte;
                     lBord : integer;
                     rBord : integer);
{ процедура заполнения матрицы
 rnd   : true - случайные значения; false - вручную
 lmax  : количество строк матрицы
 Cmax  : количество столбцов матрицы
 lBord : диапазон значений
 rBord : элементов матрицы                              }
var     
 i,j        : byte;
 x          : integer;
begin
 M[0,0]:=lmax;
 M[0,1]:=Cmax;
 case rnd of 
    true  : begin
             for i:=1 to M[0,0] do
             for j:=1 to M[0,1] do
             M[i,j]:= RandomInt(lBord,rBord);
            end;
    false : begin
             for i:=1 to M[0,0] do
             for j:=1 to M[0,1] do
               begin
                repeat
                 writeln('range: ',lBord,'..',rBord);
                 write('[',i,',',j,']:> ');
                 readln(x)
                until (x>lBord) and (x<rBord);
                M[i,j]:=x;
               end;
            end;
 end;
end;
 
procedure PrintMatrix(const M : TMatrix);
{процедура выывода элементов матрицы на экран}
var
 i,j        : byte;
 begin
 writeln();
  for i:=1 to M[0,0] do begin
  for j:=1 to M[0,1] do write(M[i,j]:5,' ');
                        writeln()
                        end;
 writeln();                     
 end;
 
function GetSum(N : integer):byte;
{возвращает сумму последней и первой цифры N} 
var
 last,first : byte;
begin
 N:=Abs(N);
 last :=N mod 10;
 while  N div 10 <> 0 do N:= N div 10;
 first:=N mod 10;
 GetSum:=last+first;
end;
 
BEGIN
 
{ fill matrix }
 Randomize;
 FillMatrix(Cur_Mtr,true,5,5,-1000,1000);
 Write('Current matrix:');
 PrintMatrix(Cur_Mtr);
 
{ processing & output }
 Mod_Mtr[0,0]:=Cur_Mtr[0,0];
 Mod_Mtr[0,1]:=Cur_Mtr[0,1];
 for i:=1 to Cur_Mtr[0,0] do
 for j:=1 to Cur_Mtr[0,1] do 
 Mod_Mtr[i,j]:=GetSum(Cur_Mtr[i,j]);
 
 Write('result matrix:');
 PrintMatrix(mod_mtr);
 
END.