Построение графиков и считывание координат расположения курсора

   Imports System
                            Imports System.Windows.Forms
                            Imports System.Drawing
 
                            Class FunWithTheMouse
                            Inherits Form
 
                            ' Объявляем объекты, к которым будем обращаться из разных методов
                            Private pictureBox1 As PictureBox
                            Private label1 As Label
                            Private spotClicked As Point
 
                            ' Метод-конструктор нашего класса
                            Public  Sub New()
 
                            ' Задаем размеры окна
                            Me.Size = New Size(640, 480)
 
                            ' Загружаем фотографию в элемент PictureBox и добавляем его на форму
                            pictureBox1 = New PictureBox()
                            pictureBox1.Image = DirectCast(New Bitmap("../../images/foal.jpg"), Image)
                            pictureBox1.SizeMode = PictureBoxSizeMode.Normal
                            pictureBox1.Dock = DockStyle.Fill
                            Me.Controls.Add(pictureBox1)
 
                            ' Добавляем метку с инструкциями в нижнюю часть экрана
                            label1 = New Label()
                            label1.BackColor = Color.Wheat
                            label1.Dock = DockStyle.Bottom
                            label1.Text = "Drag rectangle with left mouse button (draw) or another " _
                            & "mouse button (lighten). To scribble, hold SHIFT and move mouse."
                            label1.TextAlign = ContentAlignment.MiddleCenter
                            Me.Controls.Add(label1)
 
                            ' Привязываем PictureBox к обработчикам событий мыши
                            AddHandler Me.pictureBox1.MouseDown, AddressOf MouseButtonIsDown
                            AddHandler Me.pictureBox1.MouseUp, AddressOf MouseButtonIsUp
                            AddHandler Me.pictureBox1.MouseMove, AddressOf TheMouseMoved
                            End Sub
 
                            ' Обработчик событий, срабатывающий при ПЕРЕМЕЩЕНИИ мыши
                            Public Sub TheMouseMoved(ByVal sender As Object, ByVal e As MouseEventArgs)
 
                            ' Если на клавиатуре нажата клавиша SHIFT
                            If (Control.ModifierKeys And Keys.Shift) = Keys.Shift Then
 
                            ' Подготовка области рисования на изображении
                            Dim g As System.Drawing.Graphics = Me.pictureBox1.CreateGraphics()
 
                            ' Используем желтое перо
                            Dim yellowPen As System.Drawing.Pen = _
                            New System.Drawing.Pen(Color.Yellow, 3)
 
                            ' Рисование окружности (эллипс, вписанный в квадрат)
                            ' Верхний левый угол квадрата имеет координаты X и Y текущего положения мыши
                            g.DrawEllipse(yellowPen, e.X, e.Y, 40, 40)
 
                            ' Очистка
                            g.Dispose()
                            End If
                            End Sub
 
                            ' Обработчик событий, срабатывающий при НАЖАТИИ кнопки мыши
                            Public Sub MouseButtonIsDown(ByVal sender As Object, ByVal e As MouseEventArgs)
 
                            ' Запоминаем точку, в которой произошло нажатие кнопки мыши. Когда
                            ' кнопка будет отпущена, нам понадобятся ее координаты
 
                            spotClicked.X = e.X ' горизонтальная координата
                            spotClicked.Y = e.Y ' вертикальная кордината
                            End Sub
 
                            ' Обработчик событий, срабатывающий при ОТЖАТИИ кнопки мыши
                            Public Sub MouseButtonIsUp(ByVal sender As Object, ByVal e As MouseEventArgs)
 
                            ' Пользователь отпустил кнопку мыши!
 
                            ' Создаем прямоугольник (пока он еще не виден), ограничивающий
                            ' область изображения, с которой пользователь будет работать
                            Dim r As Rectangle = New Rectangle()
 
                            ' Левый верхний угол соответствует точке, в которой была нажата кнопка мыши
                            ' Мы сохранили ее координаты с помощью описанного выше метода
                            r.X = spotClicked.X
                            r.Y = spotClicked.Y
 
                            ' Ширина и высота прямоугольника вычисляется
                            ' путем вычитания начальных координат мыши (в точке нажатия)
                            ' из текущих координат (в точке отжатия кнопки)
                            r.Width = e.X - spotClicked.X
                            r.Height = e.Y - spotClicked.Y
 
                            If e.Button = Windows.Forms.MouseButtons.Left Then
                            ' Если была нажата и отпущена левая кнопка мыши
                            ' рисуем видимый контур прямоугольника
 
                            ' Подготовка области рисования на изображении
                            Dim g As Graphics = Me.pictureBox1.CreateGraphics()
 
                            ' Рисуем красный контур прямоугольника
                            Dim redPen As Pen = New Pen(Color.Red, 2)
                            g.DrawRectangle(redPen, r)
                            Else
 
                            '  Если была нажата другая кнопка, вызываем более сложный
                            '  метод, подсвечивающий область изображения
                            ChangeLightness(r)
                            End If
                            End Sub
 
                            ' Метод, увеличивающий яркость выбранного участка изображения
                            ' путем увеличения яркости каждого пикселя этого участка
                            Public Sub ChangeLightness(ByVal rect As Rectangle)
 
                            Dim newRed As Integer, newGreen As Integer, newBlue As Integer
                            Dim pixel As Color
 
                            ' Копируем изображение, загруженное в PictureBox
                            Dim picture As System.Drawing.Bitmap = New Bitmap(Me.pictureBox1.Image)
 
                            ' Поскольку операция увеличения яркости может занять много времени,
                            ' необходимо предупредить об этом пользователя, если выбран большой участок
                            If (rect.Width > 150) OrElse (rect.Height > 150) Then
                            Dim result As DialogResult = MessageBox.Show( _
                            "The area you selected is large and may take " _
                            & " a long time to lighten", _
                            "Warning", _
                            MessageBoxButtons.OKCancel)
 
                            ' При нажатии кнопки Cancel (Отмена) выходим из метода
                            ' и возвращаемся к месту его вызова
                            If result = Windows.Forms.DialogResult.Cancel Then
                            Return
                            End If
                            End If
 
                            ' Перебираем последовательно все пиксели данного участка
                            ' и удваиваем значение яркости компонент RGB пикселей
 
                            ' Перебор по горизонтали слева направо ...
                            For x As Integer = rect.X To rect.X + rect.Width - 1
 
                            ' и по вертикали сверху вниз ...
                            For y As Integer = rect.Y To (rect.Y + rect.Height) - 1
 
                            ' Считываем текущий пиксель
                            pixel = picture.GetPixel(x, y)
 
                            ' Увеличиваем яркость цветовых компонент пикселя
                            newRed = Convert.ToInt32(Math.Round(pixel.R * 2, 0))
                            If newRed > 255 Then
                            newRed = 255
                            End If
                            newGreen = Convert.ToInt32(Math.Round(pixel.G * 2, 0))
                            If newGreen > 255 Then
                            newGreen = 255
                            End If
                            newBlue = Convert.ToInt32(Math.Round(pixel.B * 2, 0))
                            If newBlue > 255 Then
                            newBlue = 255
                            End If
 
                            ' Присваиваем пикселю новые цветовые значения
                            picture.SetPixel(x, y, _
                            Color.FromArgb(Convert.ToByte(newRed), _
                            Convert.ToByte(newGreen), _
                            Convert.ToByte(newBlue)))
                            Next
                            Next
 
                            ' Помещаем измененную копию изображения в PictureBox
                            ' чтобы изменения отобразились на экране
                            Me.pictureBox1.Image = picture
                            End Sub
 
                            Shared Sub Main()
                            ' Создаем экземпляр класса формы
                            Application.Run(New FunWithTheMouse())
                            End Sub
 
                            End Class

    Private Sub Form1_MouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Me.MouseClick
        Me.Text = e.Location.ToString
    End Sub

Private Sub PictureBox1_MouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Me.MouseClick
    Me.Text = e.Location.ToString
End Sub

 Private Sub PictureBox1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles PictureBox1.Click
        TextBox3.Text = TextBox1.Text
        TextBox4.Text = TextBox2.Text
    End Sub
 
    Private Sub PictureBox1_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseMove
        TextBox1.Text = MousePosition.X
        TextBox2.Text = MousePosition.Y
    End Sub

    Private Sub PictureBox1_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseMove
        TextBox1.Text = e.Location.X
        TextBox2.Text = e.Location.Y
    End Sub