Готовые решения и полезные коды на Visual Basic .NET (Часть-2)

Imports System.Runtime.InteropServices
 
Public Class BlurMe
 
#Region "  pInvoke Helper"
    Private Class WinAPI
        Public Class Types
            <Flags>
            Public Enum DWMWINDOWATTRIBUTE
                DWMWA_USE_IMMERSIVE_DARK_MODE = 20
                DWMWA_SYSTEMBACKDROP_TYPE = 38
            End Enum
 
            Public Structure MARGINS
                Public cxLeftWidth As Integer
                Public cxRightWidth As Integer
                Public cyTopHeight As Integer
                Public cyBottomHeight As Integer
            End Structure
        End Class
 
        <DllImport("DwmApi.dll")>
        Public Shared Function DwmExtendFrameIntoClientArea(ByVal hwnd As IntPtr, ByRef pMarInset As Types.MARGINS) As Integer
        End Function
        <DllImport("dwmapi.dll")>
        Public Shared Function DwmSetWindowAttribute(ByVal hwnd As IntPtr, ByVal dwAttribute As Types.DWMWINDOWATTRIBUTE, ByRef pvAttribute As Integer, ByVal cbAttribute As Integer) As Integer
        End Function
        Public Shared Function ExtendFrame(ByVal hwnd As IntPtr, ByVal margins As Types.MARGINS) As Integer
            Return WinAPI.DwmExtendFrameIntoClientArea(hwnd, margins)
        End Function
 
        Public Shared Function SetWindowAttribute(ByVal hwnd As IntPtr, ByVal attribute As Types.DWMWINDOWATTRIBUTE, ByVal parameter As Integer) As Integer
            Return WinAPI.DwmSetWindowAttribute(hwnd, attribute, parameter, Marshal.SizeOf(Of Integer)())
        End Function
    End Class
#End Region
 
    Public Enum BlurType
        None
        Acrylic
        Mica
        Tabbed
    End Enum
 
    Public Enum Mode
        LightMode
        DarkMode
    End Enum
 
    Public Shared Sub SetBlurStyle(ByVal cntrl As Control, ByVal blurType As BlurType, ByVal designMode As Mode)
 
        Dim mgns As WinAPI.Types.MARGINS = Nothing
        With mgns
            .cxLeftWidth = 0
            .cxRightWidth = 0
            .cyTopHeight = cntrl.Height + 10000000
            .cyBottomHeight = 0
        End With
 
        WinAPI.DwmExtendFrameIntoClientArea(cntrl.Handle, mgns)
 
        cntrl.BackColor = Color.Black
 
        Select Case blurType
            Case BlurType.None
                WinAPI.SetWindowAttribute(cntrl.Handle, WinAPI.Types.DWMWINDOWATTRIBUTE.DWMWA_SYSTEMBACKDROP_TYPE, 1)
            Case BlurType.Mica
                WinAPI.SetWindowAttribute(cntrl.Handle, WinAPI.Types.DWMWINDOWATTRIBUTE.DWMWA_SYSTEMBACKDROP_TYPE, 2)
            Case BlurType.Acrylic
                WinAPI.SetWindowAttribute(cntrl.Handle, WinAPI.Types.DWMWINDOWATTRIBUTE.DWMWA_SYSTEMBACKDROP_TYPE, 3)
            Case BlurType.Tabbed
                WinAPI.SetWindowAttribute(cntrl.Handle, WinAPI.Types.DWMWINDOWATTRIBUTE.DWMWA_SYSTEMBACKDROP_TYPE, 4)
        End Select
 
        Select Case designMode
            Case Mode.LightMode
                WinAPI.SetWindowAttribute(cntrl.Handle, WinAPI.Types.DWMWINDOWATTRIBUTE.DWMWA_USE_IMMERSIVE_DARK_MODE, 0)
            Case Mode.DarkMode
                WinAPI.SetWindowAttribute(cntrl.Handle, WinAPI.Types.DWMWINDOWATTRIBUTE.DWMWA_USE_IMMERSIVE_DARK_MODE, 1)
        End Select
 
        cntrl.Invalidate()
    End Sub
End Class