Найти номер первого отрицательного элемента массива

Sub FindFirstNegAndMaxElems()
    Dim i As Long, iNeg As Long, xMax As Double, arr(1 To 10) As Double, msg As String
    'Ввод значений массива.
    For i = 1 To 10
        arr(i) = Val(Replace(InputBox("Введите " & i & " элемент массива:", _
                "Ввод значений массива"), ",", "."))
    Next i
    'Определение номера первого отрицательного элемента.
    For i = 1 To 10
        If arr(i) < 0 Then
            iNeg = i    'Запоминаем номер первого отрицательного элемента.
            Exit For    'При нахождении отрицательного элемента выходим из цикла,
        End If          'т.к. нас интересует только первый отрицательный элемент.
    Next i
    'Нахождение максимального элемента в массиве.
    xMax = arr(1) 'Берем в качестве максимального первый элемент массива.
    For i = 2 To 10
        If arr(i) > xMax Then   'Если найден элемент, больший максимального, то...
            xMax = arr(i)       'Принимаем его за максимальный.
        End If
    Next i
    'Вывод массива и дополнительной информации.
    msg = "Введенный массив:" & vbCr & vbCr
    msg = msg & arr(1)
    For i = 2 To 10
        msg = msg & vbTab & arr(i)
    Next i
    If iNeg > 0 Then
        msg = msg & vbCr & vbCr & "Первый отрицательный элемент массива находится под номером " & iNeg & "."
    Else
        msg = msg & vbCr & vbCr & "Отрицательных элементов в массиве нет."
    End If
    msg = msg & vbCr & "Максимальный элемент массива равен " & xMax & "."
    MsgBox msg
End Sub

            If B(i) <= 0 Then .Font.ColorIndex = wdBlue

Sub FirstPosAndLastNeg_differ()
Const N = 5
    Dim i As Long, arr(1 To N) As Double, msg As String
    Dim iNeg As Long, iPos As Long 'индексы искомых элементов (равны пока 0)
    
    'Ввод значений массива (с преобразованием пропускаемых при вводе в 0).
    For i = 1 To N
        arr(i) = Val(Replace(InputBox("Введите " & i & "-й элемент массива:", _
                "Ввод значений массива"), ",", "."))
    Next i
    
    'Определение номера первого положительного элемента.
    For i = 1 To N
        If arr(i) > 0 Then
            iPos = i    'Запоминаем номер первого положительного элемента.
            Exit For    'При нахождении положительного элемента ВЫХОДИМ из цикла,
        End If          'т.к. нас интересует только первый положительный элемент.
    Next i
    
    'Определение номера последнего отрицательного элемента.
    For i = N To 1 Step -1
        If arr(i) < 0 Then
            iNeg = i    'Запоминаем номер последнего отрицательного элемента.
            Exit For    'При нахождении отрицательного элемента ВЫХОДИМ из цикла,
        End If          'т.к. нас интересует только последний отрицательный элемент.
    Next i
    
    'Вывод массива и дополнительной информации.
    msg = "Введенный массив:" & vbCr & vbCr
    msg = msg & arr(1)
    For i = 2 To N
        msg = msg & vbTab & arr(i)
    Next i
    
    If iPos > 0 Then
        msg = msg & vbCr & vbCr & "Первый положительный элемент массива находится под номером " & iPos & "."
    Else
        msg = msg & vbCr & vbCr & "Положительных элементов в массиве нет." & vbCr
    End If
    
    If iNeg > 0 Then
        msg = msg & vbCr & vbCr & "Последний отрицательный элемент массива находится под номером " & iNeg & "."
    Else
        msg = msg & vbCr & vbCr & "Отрицательных элементов в массиве нет." & vbCr
    End If
    
If iPos > 0 And iNeg > 0 Then   ' при наличии тех и других (иначе сообщать не о чем)
    msg = msg & vbCr & "Разность 1-го положительного и последнего отрицательного " & _
    "элемента равна " & arr(iPos) & " – (" & arr(iNeg) & ") = " & arr(iPos) - arr(iNeg) & "."
    MsgBox msg
End If
End Sub