Как сцепить каждую ячейку столбца А с каждой ячейкой ст. B (все комбинации)

Const FIRST_ROW_NUM = 3 'Первая строка, с которой начинаются данные для построения декартова произведения.
Sub DecartMultiply(ByVal depth As Long, ByRef dimensions As Long, ByRef ubounds() As Long, ByRef indices() As Long, ByRef arr() As String, ByRef k As Long)
    Dim i As Long, j As Long
    If depth < dimensions - 1 Then
        For i = 0 To ubounds(depth)
            indices(depth) = i
            DecartMultiply depth + 1, dimensions, ubounds, indices, arr, k
        Next i
    Else
        For i = 0 To ubounds(depth)
            arr(k, dimensions - 1) = Cells(FIRST_ROW_NUM + i, dimensions).Value
            For j = dimensions - 2 To 0 Step -1
                arr(k, j) = Cells(FIRST_ROW_NUM + indices(j), j + 1).Value
            Next j
            k = k + 1
        Next i
    End If
End Sub
Sub CreateDecartMultiply()
    Dim i As Long, k As Long, n As Long, dimensions As Long, uboundMax As Long, outputRow As Long, lastRow As Long
    Dim ubounds() As Long, indices() As Long, arr() As String
    dimensions = Range(Cells(FIRST_ROW_NUM, 1), Cells(FIRST_ROW_NUM, 1).End(xlToRight)).Columns.Count
    ReDim ubounds(0 To dimensions - 1) As Long
    ReDim indices(0 To dimensions - 2) As Long
    n = 1
    For i = 0 To dimensions - 1
        If IsEmpty(Cells(FIRST_ROW_NUM + 1, i + 1)) Then ubounds(i) = 0 Else ubounds(i) = Cells(FIRST_ROW_NUM, i + 1).End(xlDown).Row - FIRST_ROW_NUM
        n = n * (ubounds(i) + 1)
        If ubounds(i) > uboundMax Then uboundMax = ubounds(i)
    Next i
    ReDim arr(0 To n - 1, 0 To dimensions - 1) As String
    DecartMultiply 0, dimensions, ubounds, indices, arr, k
    lastRow = ActiveSheet.UsedRange.Row + ActiveSheet.UsedRange.Rows.Count - 1
    outputRow = FIRST_ROW_NUM + uboundMax + 2
    If (outputRow <= lastRow) Then Range(Rows(outputRow), Rows(lastRow)).Delete
    Cells(outputRow, 1).Resize(n, dimensions).Value = arr
End Sub