Не получается вложить словарь в словарь

@ClearKbdBuf · Регистрация: 14.08.2016

Друзья, доброго времени суток!

Не могу понять, почему у меня не получается вложить словарь в словарь.

Visual Basic

    Set Header = CreateObject("Scripting.Dictionary")  
    Dim ColName As Variant
    Dim CNames As Variant
    Dim Ctr As Long
    Dim BufNames As Object
    Set BufNames = CreateObject("Scripting.Dictionary")
    CNames = Split(NamesOfColumns, "|||")
    Ctr = 0
    For Each ColName In CNames
        BufNames.Add ColName, Ctr
        Ctr = Ctr + 1
    Next
    Header.Add "NAMES", BufNames
    NumOfColumns = Ctr

В Watches почему-то пишет, что item "Names" в словаре Header содержит значение типа Variant/String. При этом BufHeader в порядке, все элементы отображаются нормально.
Может требуются какие-то дополнительные итерации, чтобы засунуть туда ссылку на объект?
Весь вечер мучаюсь, не могу понять в чем дело. Если кто знает в чем дело, подскажите, пожалуйста.

С уважением.

@kalbasiatka · 14.08.2016, 22:31

Visual Basic

Sub uuu()
    Dim x&
    Dim sd1 As Object, sd2 As Object
'--------------------------------------------
    Set sd1 = CreateObject("Scripting.Dictionary")
    Set sd2 = CreateObject("Scripting.Dictionary")
    
    For Each el In Array("a", "b", "c")
        x = x + 1
        sd1.Item(el) = x
    Next
 
    Set sd2.Item("NAMES") = sd1
    
    sd_keys = sd2.keys
    sd_items = sd2.Items
 
    sd_sub_dic_keys = sd2.Item("NAMES").keys
    sd_sub_dic_items = sd2.Item("NAMES").Items
    
End Sub
    
Sub ttt()
    Dim x&
    Dim sd As Object
'---------------------
    Set sd = CreateObject("Scripting.Dictionary")
    Set sd.Item("NAMES") = CreateObject("Scripting.Dictionary")
    
    For Each el In Array("a", "b", "c")
        x = x + 1
        sd.Item("NAMES").Item(el) = x
    Next
 
    sd_keys = sd.keys
    sd_items = sd.Items
 
    sd_sub_dic_keys = sd.Item("NAMES").keys
    sd_sub_dic_items = sd.Item("NAMES").Items
    
End Sub

@ClearKbdBuf · 15.08.2016, 09:57 **[ТС]**

Спасибо за Ваш отзыв!

Я попробовал сделать как Вы прописали:

Visual Basic

    
 
    Dim ColName As Variant
    Dim CNames As Variant
    Dim Ctr As Long
    Dim BufNames As Object
    
    Set Header = CreateObject("Scripting.Dictionary")
    Set BufNames = CreateObject("Scripting.Dictionary")
    CNames = Split(NamesOfColumns, "|||")
    Ctr = 0
    For Each ColName In CNames
        BufNames.Add ColName, Ctr
        Ctr = Ctr + 1
    Next
    NumOfColumns = Ctr
    Set Header.Item("NAMES") = BufNames

Ситуация не меняется. Я приложил скриншот с содержимым переменных для наглядности. такое ощущение, что баг в екселе. Однако, мне тяжело в это поверить, я все же думаю, что я где-то не так делаю.

~~Shersh~~ · 15.08.2016, 10:31

Сообщение от ClearKbdBuf

'~~Set Header.Item("NAMES") = BufNames~~

Visual Basic

1	Header.Add BufNames, 0

?

@ClearKbdBuf · 15.08.2016, 10:46 **[ТС]**

Друзья, спасибо Вам за ответы!

На самом деле все вкладывалось!

Вложенные объекты в Watches действительно отображаются как variant/string. Почему не знаю. Однако, воспринимается правильно. Вот скриншот с результатами выполнения процедуры uuu() из примера kalbasiatka.
На нем видно что sd2.item("NAMES") воспринимается как Variant/String. Однако, вызов sd2.item("NAMES").keys выдает массив.

Моя ошибка была в свойстве ColumNames класса VTable. Вот она:

Visual Basic

1
2
3

Public Property Get ColumnNames() As Object
     ColumnNames = Header.Item("NAMES")
End Property

Имея дело со ссылкой на объект, я забыл оператор SET

Исправил на

Visual Basic

1
2
3

Public Property Get ColumnNames() As Object
     Set ColumnNames = Header.Item("NAMES")
End Property

Все заработало.

Я благодарю всех пользователей, которые отозвались по моей проблеме!

Опции темы

Не получается вложить словарь в словарь

Решение