Динамическое создание формы с CommandButton в несколько столбцов

'Module1
Sub StartExample()
    Dim Result As String
    Result = UserForm1.ShowExt
    MsgBox "Выбрано : " & """" & Result & """"
End Sub

'Class ResultReference
Private sValue As String
Public Event Change()
Public Property Get Value() As String
    Value = sValue
End Property
Public Property Let Value(ByVal Text As String)
    sValue = Text
    RaiseEvent Change
End Property
 
'Class EventOfControls
Public WithEvents ButtonEv As MSForms.CommandButton
Public ResultRef As ResultReference
Private Sub ButtonEv_Click()
    ResultRef.Value = ButtonEv.Caption
End Sub

Private Const SM_CXVSCROLL = 2
Private Declare Function GetSystemMetrics Lib "user32.dll" (ByVal nIndex As Long) As Long
Private DiffWidth As Single     'разница между шириной формы и шириной формы предназначенной для использования (минус, возможно, границы окна)
Private DiffHeight As Single    'разница между высотой формы и высотой формы предназначенной для использования (минус заголовок и, возможно, границы окна)
Private OffsetWidth As Single   'отступ от края формы по ширине
Private OffsetHeight As Single  'отступ от края формы по высоте
Private ButtonHeight As Single  'высота кнопки
Private MaxWidth As Single      'максимальная ширина формы
Private MaxHeight As Single     'максимальная высота формы
Private Buttons As Collection   'хранилище классов с кнопками и обработчиками событий
Private WithEvents Result As ResultReference 'сюда класс EventOfControls будет передавать имя нажатой кнопки
 
Public Function ShowExt() As String
    Me.Show
    ShowExt = Result.Value
    Unload Me
End Function
 
Private Sub Result_Change()
    Dim I As Integer
    For I = Buttons.Count To 1 Step -1
        Me.Controls.Remove Buttons(I).ButtonEv.Name
        Buttons.Remove I
    Next
    Me.Hide
End Sub
 
Private Sub UserForm_Initialize()
    Dim I As Integer
    Set Buttons = New Collection
    Set Result = New ResultReference
    'Set Buttons = New Collection
    Me.ScrollBars = fmScrollBarsNone
    DiffWidth = Me.Width - Me.InsideWidth
    DiffHeight = Me.Height - Me.InsideHeight
    OffsetHeight = 0.75 * 12
    OffsetWidth = 0.75 * 12
    MaxWidth = 0.75 * 640 - OffsetWidth * 2 - DiffWidth
    MaxHeight = 0.75 * 480 - OffsetHeight * 2 - DiffHeight
    ButtonHeight = 0.75 * 24
    ComboBox1.Style = fmStyleDropDownList
    'настройка размеров и положения combobox
    ComboBox1.Left = 0 + OffsetWidth
    ComboBox1.Top = 0 + OffsetHeight
    ComboBox1.Width = 0.75 * 160
    ComboBox1.Height = ButtonHeight
    'настройка начальных размеров формы
    Me.Width = OffsetWidth + ComboBox1.Width + OffsetWidth + DiffWidth
    Me.Height = OffsetHeight + ComboBox1.Height + OffsetHeight + DiffHeight
    'заполнение combobox названиями групп
    For I = 1 To List1.UsedRange.Columns.Count
        ComboBox1.AddItem List1.UsedRange(1, I).Value
    Next
End Sub
 
Private Sub ComboBox1_Change()
    Dim I As Integer
    Dim X As Single
    Dim LastX As Single
    Dim Y As Single
    Dim Column As Integer
    Dim DataRowsCount As Integer
    Dim EOC As EventsOfControls
    
    ComboBox1.Enabled = False
    ComboBox1.Visible = False
    
    Column = ComboBox1.ListIndex + 1
    DataRowsCount = WorksheetFunction.CountA(List1.Columns(Column))
    X = OffsetWidth
    Y = OffsetHeight
    LastX = X
    For I = 2 To DataRowsCount
        Set EOC = New EventsOfControls
        Set EOC.ButtonEv = Me.Controls.Add("Forms.CommandButton.1", "CommandButton" & I)
        Set EOC.ResultRef = Result
        EOC.ButtonEv.Caption = List1.Cells(I, Column).Value
        EOC.ButtonEv.AutoSize = True
        EOC.ButtonEv.AutoSize = False
        EOC.ButtonEv.Height = ButtonHeight
        EOC.ButtonEv.Left = X
        EOC.ButtonEv.Top = Y
        Buttons.Add EOC
        X = X + EOC.ButtonEv.Width
        If X > MaxWidth Then
            X = OffsetWidth
            Y = Y + ButtonHeight
            EOC.ButtonEv.Left = X
            EOC.ButtonEv.Top = Y
        Else
            If LastX < X Then LastX = X
        End If
    Next
    Me.Width = LastX + OffsetWidth + DiffWidth
    If Y > MaxHeight Then
        Me.ScrollHeight = Y + ButtonHeight + OffsetHeight
        Y = Int(MaxHeight / ButtonHeight)
        Y = Y * ButtonHeight
        Me.Height = Y + OffsetHeight * 2 + DiffHeight
        Me.Width = Me.Width + 0.75 * GetSystemMetrics(SM_CXVSCROLL)
        Me.ScrollBars = fmScrollBarsVertical
    Else
        Me.Height = Y + ButtonHeight + OffsetHeight + DiffHeight
    End If
End Sub

    For I = 2 To DataRowsCount
        Set EOC = New EventsOfControls
        Set EOC.ButtonEv = Me.Controls.Add("Forms.CommandButton.1", "CommandButton" & I)
        Set EOC.ResultRef = Result
        EOC.ButtonEv.Caption = List1.Cells(I, Column).Value
        EOC.ButtonEv.AutoSize = True
        EOC.ButtonEv.AutoSize = False
        EOC.ButtonEv.Height = ButtonHeight
        Buttons.Add EOC
        If X + EOC.ButtonEv.Width > MaxWidth Then
            X = OffsetWidth
            Y = Y + ButtonHeight
        End If
        EOC.ButtonEv.Left = X
        EOC.ButtonEv.Top = Y
        X = X + EOC.ButtonEv.Width
        If LastX < X Then LastX = X
    Next