Для каждого столбца матрицы найти наименьший элемент

Sub Procedure_1()
 
    'Создание матрицы. Матрица - это одна или несколько переменных,
    'имеющих одинаковое имя. Чтобы проще писать код, мысленно
    'матрицу можно сравнить с обычной таблицей, которая состоит из строк и столбцов.
    
    '1 To - используется, чтобы порядковый номер первого элемента матрицы
    'был один. По умолчанию порядковый номер первого элемента матрицы ноль,
    'что неудобно для написания кода.
    
    'Матрица, состоящая из 3-х строк и 4-х столбцов.
    
    'Double - означает, что в матрице могут быть только числа, при чём целые и дробные
    '(есть ещё текст).
    Dim Матрица(1 To 3, 1 To 4) As Double
 
    'Создаём различные переменные, которые понадобятся для выполнения задания.
    
    'Long - означает, что в переменной может быть только целое число
    '(есть ещё дробные числа).
    Dim i As Long, j As Long
    Dim СлЧисло As Double
    Dim min As Double
    Dim Счётчик As Long
    
    'For ... To ... Step ... Next - называется циклом и используется
    'для выполнения одного и того же действия заданное количество раз.
    
    'Заполняем матрицу вещественными числами.
    For i = 1 To 3 Step 1
        For j = 1 To 4 Step 1
            'Генерируем числа от -5 и меньше 5.
            
            'Пояснение:
            '(5 - (-5)) даёт 10.
            'Rnd генерирует число от 0 до 0,9.
            'В итоге будет получаться число от 0 (10*0) до 9 (10*0,9).
            'Будет получаться число: 9; 9,1; 9,2 и до 9,9. Числа 10 не будет получено.
            'Затем от полученого числа будет отниматься число 5.
            'В итоге будет получаться заданный диапазон чисел.
            
            СлЧисло = (5 - (-5)) * Rnd + (-5)
            
            'Откругляем число до двух знаков после запятой.
            'Скорее всего вам надо будет использовать другое средство
            'для округления, но я воспользуюсь этим.
            Матрица(i, j) = Format(СлЧисло, "0.00")
        Next j
    Next i
    
    'Для наглядности выводим полученную матрицу в Excel на активный лист.
    For i = 1 To 3 Step 1
        For j = 1 To 4 Step 1
            Cells(i, j).Value = Матрица(i, j)
        Next j
    Next i
    
 
'------------------------------------------------------------------------------------------------
    'Поиск наименьших элементов в каждом столбце.
    For i = 1 To 4 Step 1
        'Сначала за минимальный элемент берём самый первый элемент в столбце.
        'А затем остальные сравниваем с ним.
        min = Матрица(1, i)
        For j = 2 To 3 Step 1
            'If ... Then ... End If - используется для выбора действия.
        
            'Если текущий элемент в столбце меньше числа в переменной min,
            'то в переменную min помещаем это число.
            If Матрица(j, i) < min Then
                min = Матрица(j, i)
            End If
        Next j
        'Выводим результат по текущему столбцу в Excel.
        Cells(5, i).Value = min
    Next i
    
 
'------------------------------------------------------------------------------------------------
    'Поиск неотрицательных элементов в матрице.
    'Неотрицательные элементы - это нули и положительные числа.
    For i = 1 To 3 Step 1
        For j = 1 To 4 Step 1
            If Матрица(i, j) >= 0 Then
                Счётчик = Счётчик + 1
            End If
        Next j
    Next i
 
    'С помощью MsgBox выводим сообщение, в котором укажем результат.
    'Символ "&" используется для соединения нескольких фрагментов в одну строку.
    MsgBox "Неотрицательных элементов: " & Счётчик
    
End Sub

Private Sub CommandButton1_Click()
Dim s As Single, min(4) As Single, r As Integer
Cells.Clear
 
For j = 1 To 4
min(j) = 10
For i = 1 To 3
 
s = Rnd * 10 - 5
Cells(i + 1, j + 1) = Round(s, 2)
If min(j) > s Then
min(j) = s
End If
If s >= 0 Then
r = r + 1
End If
Next
Cells(i + 4, j + 1) = Round(min(j), 2)
Next
Cells(i + 3, 1) = "Наименьший элемент в столбце"
Cells(i + 3, j + 3) = "Количество неотрицательных элементов"
Cells(i + 4, j + 3) = r
End Sub

Sub www()
    Dim i&, cnt&, rand#
    Randomize
    For i = 1 To 1000000
        rand = Rnd
        If Round(rand * 10 - 5, 2) <> CDbl(Format(rand * 10 - 5, "0.00")) Then cnt = cnt + 1
    Next i
    Debug.Print cnt
End Sub

Sub www()
    Dim i&, j&, arr#(1 To 3, 1 To 4), minArr(1 To 1, 1 To 4), cnt&
    Randomize
    For j = 1 To 4
        For i = 1 To 3
            arr(i, j) = Int(Rnd * 1001 - 500) / 100
            If i = 1 Or minArr(1, j) > arr(i, j) Then minArr(1, j) = arr(i, j)
            If arr(i, j) >= 0 Then cnt = cnt + 1
    Next i, j
    Cells(1, 1).Resize(3, 4) = arr
    Cells(4, 1) = "Наименьший элемент в столбце:"
    Cells(5, 1).Resize(1, 4) = minArr
    Cells(6, 1) = "Кол-во неотрицательных элементов:"
    Cells(7, 1) = cnt
End Sub

Sub Procedure_1()
 
    Dim СлЧисло As Double
    Dim min As Double, max As Double
    Dim КолЗнаков As Long
    
    'Указываем данные, которые нужно получить.
    min = -5
    max = 5
    КолЗнаков = 2
    
    'Преобразуем данные.
    min = min * 10 ^ КолЗнаков
    max = max * 10 ^ КолЗнаков
    
    'Получение случайного числа.
    'Формулу генерации случайных целых чисел в заданном диапазоне можно посмотреть
    'в справке. Для этого нужно поставить курсор на Rnd и нажать клавишу F1.
    СлЧисло = (max - min + 1) * Rnd + min
    
    'Отбрасывание дробной части.
    СлЧисло = Int(СлЧисло)
    
    'Установка нужного количества знаков после запятой.
    СлЧисло = СлЧисло / 10 ^ КолЗнаков
 
End Sub