Нужно удалить пустые ячейки из выбронного столбца

Sub Макрос3()
'Не удаляет 2 и больше подряд пустых ячейки
Dim R As Range
Set R = Application.InputBox("Ввыделите верхнюю левую ячейку", _
"Ввыделяем диапазон", Selection.Address, , , , , 8)
    Range(R, R.Offset(100000, 0).End(xlUp)).Select
    For Each Cell In Selection
    If Cell.Value = 0 Then
    Cell.Delete
    End If
    Next Cell
End Sub

Sub Макрос3()
'Не удаляет 2 и больше подряд пустых ячейки
Dim R As Range
Set R = Application.InputBox("Ввыделите верхнюю левую ячейку", _
"Ввыделяем диапазон", Selection.Address, , , , , 8)
 
Range(R, Cells(Rows.Count, R.Column)).SpecialCells(xlCellTypeBlanks).Delete xlShiftUp
 
End Sub

Sub Макрос3()
    Dim i As Long, R As Range
    Set R = Application.InputBox("Выделите верхнюю левую ячейку диапазона", _
    "Выделяем диапазон", Selection.Address, , , , , 8)
    'Выделяем верхнюю левую ячейку выбранного пользователем диапазона,
    'так как нет гарантии, что он выберет только одну ячейку.
    Set R = R.Cells(1)
    'Если верхняя левая ячейка выбранного пользователем диапазона пуста,
    'то, скорее всего, пользователь ошибся. Прекращаем работу процедуры.
    If IsEmpty(R) Then
        Exit Sub
    Else 'Если же ошибки нет, то...
        'Выделяем диапазон от этой ячейки до последней заполненной ячейки
        'в столбце, содержащем эту ячейку.
        Set R = Range(R, Cells(Rows.Count, R.Column).End(xlUp))
        'Отключаем обновление экрана, чтобы удаление проходило быстрее.
        Application.ScreenUpdating = False
        'Идем от последней ячейки диапазона к первой и удаляем пустые ячейки.
        'R.Count - количество ячеек в диапазоне.
        'Step -1 - означает, что цикл идет в обратном порядке (от большего к
        'меньшему).
        For i = R.Count To 1 Step -1
            If IsEmpty(R.Cells(i)) Then R.Cells(i).Delete
        Next i
        'Включаем обновление экрана.
        Application.ScreenUpdating = True
        'Конец работы.
    End If
End Sub