Скрипт для удаления файлов и папок

@BKPB · Регистрация: 08.05.2015

Студворк — интернет-сервис помощи студентам

Собрал из кусков скрипт для удаления файлов и папок.
Но проблема такая, если все указанные в скрипте файлы присутствуют в системе то он отрабатывает нормально.
А если какого нибудь файла или папки нет, то скрипт выдаёт ошибку: файл не найден и окно висит пока не закроешь вручную.
Помогите подправить или написать новый, чтобы не было такой ошибки.
Вот мой скрипт:

Visual Basic
1
2
3
4
5
6
7
8
9
' Задержка 1 секунда
WScript.Sleep 1*1000
' Удаление файла
WScript.CreateObject("Scripting.FileSystemObject").DeleteFile "C:\Users\Администратор ПК\AppData\Local\Yandex\YandexBrowser\Application\17.11.1.990\service_update.exe", True
WScript.CreateObject("Scripting.FileSystemObject").DeleteFile "C:\Users\Администратор ПК\AppData\Local\Yandex\YandexBrowser\Application\17.11.1.990\yupdate-exec.exe", True
' Задержка 1 секунда
WScript.Sleep 1*1000
' Удаление папки
WScript.CreateObject("Scripting.FileSystemObject").DeleteFolder "C:\Users\Администратор ПК\AppData\Local\Yandex\YandexBrowser\Application\17.11.1.990\Installer", True

А если поможете написать скрипт или .cmd, чтобы сперва отработал инсталлятор браузера setup.exe, затем ещё один .exe (он просто заменяет файлы в папке с настройками) и затем удалились бы не нужные папки и файлы,
то я бы был безмерно вам благодарен.

FlasherX · 05.02.2018, 13:51

Сообщение от BKPB

а может можно как то после установки программы заменить файлы

В этом нет проблемы, если знать что на что менять.

Я бы вообще от этого браузера отказался, если честно.
Установщик создаёт папку в %LocalAppData% размером в 523 Мб, в реестр пишет кучу ненужностей, собирает сведения и следит за пользователем. Почитайте: 1, 2 и т. д. Ну, можно ещё лукоморье почитать, если не в тягость.

setup.exe создаётся в папке %Temp%\YB_31547.tmp. У вас так?
А версия в %LocalAppData%\Yandex\YandexBrowser\Appl ication не продукта (18.1.1.539), а сборки: 41.0.2272.3911.

@BKPB · 05.02.2018, 14:17 **[ТС]**

И ещё, я понимаю, что я уже обнаглел, но если можно сделайте ещё,
после установки программы удаление папок:
C:\Users\Администратор ПК\AppData\Roaming\Yandex - пустая папка
C:\ProgramData\Yandex - папка с service_update.log
C:\Users\Администратор ПК\AppData\LocalLow\Yandex - папка с yupdate-exec-yabrowser.log
Если можно вас как то поблагодарить скажите как.

Добавлено через 11 минут

Сообщение от FlasherX

В этом нет проблемы, если знать что на что менять.

Заменить файлы в папке Default, в C:\Users\Администратор ПК\AppData\Local\Yandex\YandexBrowser\Us er Data\Default
на мои.

Сообщение от FlasherX

Я бы вообще от этого браузера отказался, если честно.

Не могу, как пел Владимир Высоцкий "Может вам она, как лошадь, но а мне так в самый раз".

Сообщение от FlasherX

setup.exe создаётся в папке %Temp%\YB_31547.tmp. У вас так?

Сейчас после чистки пк в темр она вообще не создалась, а до этого было как на скрине просто номер
типа 0000_000

Сообщение от FlasherX

А версия в %LocalAppData%\Yandex\YandexBrowser\Appl ication не продукта (18.1.1.539), а сборки: 41.0.2272.3911.

Я специально пока делаю эту версию т.к в новой мне не нравиться менеджер паролей, новый переводчик выделенного текста и отображение дополнений на ТАБЛО.

Добавлено через 9 минут
И если так можно, сделать что то типа C:\Users\%UserName%\AppData\Local\Yandex\YandexBrowser\User Data\Default,
вдруг придётся поставить на пк с другой учёткой.

FlasherX · 05.02.2018, 15:40

Сообщение от BKPB

Заменить файлы в папке Default, в C:\Users\Администратор ПК\AppData\Local\Yandex\YandexBrowser\Us er Data\Default на мои.

И откуда их, собственно, брать? И есть ли там папки?

Сообщение от BKPB

Не могу

Нет, всё-таки загляните Лукоморье. ))

Сообщение от BKPB

И если так можно, сделать что то типа C:\Users\%UserName%\..

Это и так предусмотрено.

@BKPB · 05.02.2018, 15:59 **[ТС]**

Сообщение от FlasherX

Заменить файлы в папке Default, в C:\Users\Администратор ПК\AppData\Local\Yandex\YandexBrowser\Us er Data\Default на мои.
И откуда их, собственно, брать? И есть ли там папки?

Когда программа устанавливается в систему они конечно создаются,
ну а в инсталляторе их конечно нет. Когда программа установится,
запускается мой архив Settings.exe и извлекает точно такие же файлы только настроенные
в такую же папку с заменой файлов.
Path=C:\Users\%UserName%\AppData\Local\Y andex\YandexBrowser\User Data\Default
Silent=1
Overwrite=1
Так реализовано у меня.
Ну а если вы имеете в виду как прописать замену файлов в этой папке не используя Settings.exe,
то скажите как вы считаете сделать лучше так и сделаем, может их легче извлечь с заменой просто из папки
или можно запихать папку в browser.7z, но тогда нужно вычислить, в какую папку распаковывается архив
browser.7z и подхватить их от туда. Что то типа этого.

FlasherX · 05.02.2018, 17:05

BKPB, перепакуйте свои файлы в Default.zip и положите его рядом со скриптом:

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Set FSO = CreateObject("Scripting.FileSystemObject")
Default = FSO.GetParentFolderName(WSH.ScriptFullName) & "\Default.zip"
 
If Not FSO.FileExists(Default) Then _
MsgBox "Отсутствует Default.zip в папке скрипта!", 4144 : WSH.Quit
Path = FSO.GetSpecialFolder(2) & "\RarSFX"
For i = 2 To 0 Step -1
  If FSO.FileExists(Path & i & "\setup.exe") Then Path = Path & i : Exit For
Next
 
With CreateObject("WScript.Shell")
  .Run """" & Path & "\setup.exe""",, 1
  LocalAppData = .Environment("Process")("LocalAppData")
  ProgramData  = .Environment("Process")(ALLUSERSPROFILE")
  YPath = LocalAppData & "\Yandex\YandexBrowser\"
  YBApp = YPath & "Application\"
  For Each Pr In GetObject("winmgmts:\\.\root\cimv2")._
  ExecQuery("Select Status from Win32_Process WHERE ExecutablePath='" &_
  Replace(YBApp & "browser.exe", "\",  "\\") & "' Or ExecutablePath='"&_
  Replace(YBApp & "17.11.1.990\service_update.exe", "\",  "\\") & "'")
    Pr.Terminate
  Next
  With CreateObject("Shell.Application")
    If .CanStartStopService("YandexBrowserService") _
    Then .ServiceStop "YandexBrowserService", False
    .NameSpace(YPath & "User Data\Default").CopyHere Default & "*", 5268
  End With
  .CurrentDirectory = YBApp & "17.11.1.990"
End With
 
For Each N In Split("service_update.exe yupdate-exec.exe Installer\browser.7z")
  If FSO.FileExists(N) Then FSO.DeleteFile N, 1
Next
For Each F in Array(FSO.SpecialFolders(5), ProgramData, LocalAppData & "Low")
  If FSO.FolderExists(F & "\Yandex") Then FSO.DeleteFolder F & "\Yandex", 1
Next

@BKPB · 05.02.2018, 17:21 **[ТС]**

Здесь убрал кавычки и сработало,
Добавлено через 3 минуты
Сценарий:
C:\UsersW7D~l\AppData\Local\Temp\RarSFX0 \Setup.vbs
Строка: 14
Символ: 59
Ошибка: Незавершенная строковая константа
Код: 800А0409
Источник: Ошибка компиляции Microsoft VBScript

FlasherX · 05.02.2018, 17:29

Сообщение от BKPB

Здесь убрал кавычки и сработало,

Как раз убирать кавычки нельзя. В 14 строке добавьте одну перед второй открывающей скобкой. Случайность. Без тестов пишу всё же.

Сообщение от BKPB

а вот здесь как

Может, последняя строка не скопировалась? В коде ошибки вроде нет.

@BKPB · 05.02.2018, 17:30 **[ТС]**

А вот здесь, что то не так
Сценарий:
C:\UsersW7D~l\AppData\Local\Temp\RarSFX0 \Setup.vbs
Строка: 34
Символ: 1
Ошибка: Объект не поддерживает это свойство или метод:
TSO.SpecialFolders'
Код: 800А01В6
Источник: Ошибка выполнения Microsoft VBScript

Добавлено через 47 секунд

Сообщение от FlasherX

Может, последняя строка не скопировалась? В коде ошибки вроде нет.

Да с копировалось не верно

И почему то в папку с настройками распаковались не сами файлы, а сам архив Default.zip

FlasherX · 05.02.2018, 17:39

Сообщение от BKPB

TSO.SpecialFolders'

Там явно нет буквы T спереди. )

Сообщение от BKPB

И почему то в папку с настройками распаковались не сами файлы, а сам архив Default.zip

Т. е.? Содержимое архива должно распаковаться.

@BKPB · 05.02.2018, 17:42 **[ТС]**

Сообщение от FlasherX

Т. е.? Содержимое архива должно распаковаться.

ДА.

FlasherX · 05.02.2018, 17:45

А, всё, понял.

Исправленный вариант:

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Set FSO = CreateObject("Scripting.FileSystemObject")
Default = FSO.GetParentFolderName(WSH.ScriptFullName) & "\Default.zip"
 
If Not FSO.FileExists(Default) Then _
MsgBox "Отсутствует Default.zip в папке скрипта!", 4144 : WSH.Quit
Path = FSO.GetSpecialFolder(2) & "\RarSFX"
For i = 2 To 0 Step -1
  If FSO.FileExists(Path & i & "\setup.exe") Then Path = Path & i : Exit For
Next
 
With CreateObject("WScript.Shell")
  .Run """" & Path & "\setup.exe""",, 1
  AppData = .SpecialFolders(5)
  LocalAppData = .Environment("Process")("LocalAppData")
  ProgramData  = .Environment("Process")("ALLUSERSPROFILE")
  YPath = LocalAppData & "\Yandex\YandexBrowser\"
  YBApp = YPath & "Application\"
  For Each Pr In GetObject("winmgmts:\\.\root\cimv2")._
  ExecQuery("Select Status from Win32_Process WHERE ExecutablePath='" &_
  Replace(YBApp & "browser.exe", "\",  "\\") & "' Or ExecutablePath='"&_
  Replace(YBApp & "17.11.1.990\service_update.exe", "\",  "\\") & "'")
    Pr.Terminate
  Next
  With CreateObject("Shell.Application")
    If .CanStartStopService("YandexBrowserService") _
    Then .ServiceStop "YandexBrowserService", False
    .NameSpace(YPath & "User Data\Default").CopyHere Default & "\*", 5268
  End With
  .CurrentDirectory = YBApp & "17.11.1.990"
End With
 
For Each N In Split("service_update.exe yupdate-exec.exe Installer\browser.7z")
  If FSO.FileExists(N) Then FSO.DeleteFile N, 1
Next
For Each F in Array(AppData, ProgramData, LocalAppData & "Low")
  If FSO.FolderExists(F & "\Yandex") Then FSO.DeleteFolder F & "\Yandex", 1
Next

@BKPB · 05.02.2018, 17:46 **[ТС]**

Там вообще
TSO.SpecialFolders нет, а только
FSO.SpecialFolders

FlasherX · 05.02.2018, 17:48

Я сам понятия не имею, зачем вы F исправили на Т.

@BKPB · 05.02.2018, 18:03 **[ТС]**

Сейчас вот что происходит:
http://i3.imageban.ru/out/2018... aa61f6.png

Всё видно и каждый файл запрашивает подтверждения,
может лучше копировать не файлы, а как у меня было папку целиком, но как это скрыть и разрешить замену
в WinRar то там есть такие настройки.

Добавлено через 4 минуты
Я на Т ничего не менял, это ва написали

Сообщение от FlasherX

Там явно нет буквы T спереди.

Добавлено через 9 минут

Сообщение от BKPB

Всё видно и каждый файл запрашивает подтверждения,
может лучше копировать не файлы, а как у меня было папку целиком

Идея, а может лучше и быстрее будет, удалить эту папку из папки с установленной программой и закинуть туда подобную с моими файлами.

FlasherX · 05.02.2018, 18:03

А теперь?:

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Set FSO = CreateObject("Scripting.FileSystemObject")
Default = FSO.GetParentFolderName(WSH.ScriptFullName) & "\Default.zip"
 
If Not FSO.FileExists(Default) Then _
MsgBox "Отсутствует Default.zip в папке скрипта!", 4144 : WSH.Quit
Path = FSO.GetSpecialFolder(2) & "\RarSFX"
For i = 2 To 0 Step -1
  If FSO.FileExists(Path & i & "\setup.exe") Then Path = Path & i : Exit For
Next
 
With CreateObject("WScript.Shell")
  .Run """" & Path & "\setup.exe""",, 1
  AppData = .SpecialFolders(5)
  LocalAppData = .Environment("Process")("LocalAppData")
  ProgramData  = .Environment("Process")("ALLUSERSPROFILE")
  YPath = LocalAppData & "\Yandex\YandexBrowser\"
  YBApp = YPath & "Application\"
  For Each Pr In GetObject("winmgmts:\\.\root\cimv2")._
  ExecQuery("Select Status from Win32_Process WHERE ExecutablePath='" &_
  Replace(YBApp & "browser.exe", "\",  "\\") & "' Or ExecutablePath='"&_
  Replace(YBApp & "17.11.1.990\service_update.exe", "\",  "\\") & "'")
    Pr.Terminate
  Next
  With CreateObject("Shell.Application")
    If .CanStartStopService("YandexBrowserService") _
    Then .ServiceStop "YandexBrowserService", False
    Set Items = .NameSpace(Default).Items
    .NameSpace(YPath & "User Data\Default").CopyHere Items, 5268
  End With
  .CurrentDirectory = YBApp & "17.11.1.990"
End With
 
For Each N In Split("service_update.exe yupdate-exec.exe Installer\browser.7z")
  If FSO.FileExists(N) Then FSO.DeleteFile N, 1
Next
For Each F in Array(AppData, ProgramData, LocalAppData & "Low")
  If FSO.FolderExists(F & "\Yandex") Then FSO.DeleteFolder F & "\Yandex", 1
Next

Сообщение от BKPB

Я на Т ничего не менял, это ва написали

Ну, конечно. Я выделил ваш текст из поста и нажал Цитировать. ))

@BKPB · 05.02.2018, 18:11 **[ТС]**

Сообщение от FlasherX

Ну, конечно. Я выделил ваш текст из поста и нажал Цитировать. ))

Я понял в чём дело, я копирую текст ошибок программой ScreenshotReader, и она так иногда загоняет.

FlasherX · 05.02.2018, 18:15

BKPB
Зачем же делать такую глупость, когда есть Ctrl+C?

Про результат лучше напишите.

@BKPB · 05.02.2018, 18:22 **[ТС]**

Ну вроде всё отлично, но вот только видать из за распаковки файлов Default.zip установка стала по дольше,
но это не беда, просто в процессе установки не понятно установилась она уже или нет так как по времени дольше.
Нельзя например, папку заменять не упаковывая её в .zip.
Или я не пойму почему стало дольше, наверное что файла заменяются по одному или что я Default.zip сжал по максимуму.

FlasherX · 05.02.2018, 18:26

Вы там про применение на другой машине писали. Папку носить лучше, чем архив?

@BKPB · 05.02.2018, 18:31 **[ТС]**

Сообщение от FlasherX

Вы там про применение на другой машине писали. Папку носить лучше, чем архив?

Нет конечно я носить буду в виде инсталлятора, я имел в виду что внутри инсталлятора заменить Default.zip на папку.

Новые блоги и статьи Все статьи Все блоги /
Доктрина интенционального знания - Доктрина для портала "Срез". Hrethgir 25.07.2026 Может найдётся кто захочет оценить доктрину. . . Написания правил участия для меня роскошь, требующая лимита времени, поэтому все сообщения не прошедшие модерацию будут видны только участникам портала,. . .	сукцессия 44. Решил подать на припринт в межународные сервисы препринтов. Но нужно одобрение от ученых anaschu 25.07.2026 Английский вариант. Пока кто то не одобрит мою личность, мне не получиться это опубликовать на препринте. Но заявку на публикацию статьи я сегодня подам.	сукцессия 43. Вторая научная статья за месяц- прайминг и гатгил anaschu 25.07.2026 две стороны одной монеты	Более приземисто - Эстафету хвоста в .cdl (деревья эстафеты в сад). Hrethgir 24.07.2026 В будущем, после написания блока инверсии обхода дерева (эстафеты хвоста), я планирую вернуться к нашему прошлому разговору о том, обладают ли знания целеполаганием. Тогда я пришел к выводу, что. . .
Вот представьте что вам дали бессмертие. kumehtar 24.07.2026 Вот представьте что вам дали бессмертие, ничего более не меняя. Вообще ничего, только бессмертие в нынешнем виде. Рады были бы? Что бы вы тут делали всё это время? Никакой пенсии. Никакого нового. . .	сукцессия 41 anaschu 24.07.2026 Численная верификация бифуркации в агентной модели лесной сукцессии: от одного параметра к ансамблю Автор: пользователь @Shumilov_AS \| Раздел: Прикладная математика / Численные методы Кратко. . .	сукцессия 40. Ансамблевая кластерная параметризаци, часть 1. anaschu 24.07.2026 Пр# Сопровождение научной статьи ИИ-ассистентом: подготовка публикации и калибровка агентно-ориентированной модели сукцессии микоризных систем Полевые заметки о двухнедельной совместной работе. . .	Теория всего 12. ВГК на планете в стратегической игре "терра" anaschu 21.07.2026 ### Главные семантические изменения и дешифровка новой физики 1. `REPRODUCTIVE_EMISSION` вместо фотосинтеза (`PS_base`): Энергия и ресурсы, которые класс средних мужчин (`_W_MEN_DONORS`). . .

@BKPB 0 / 0 / 0 Регистрация: 08.05.2015 Сообщений: 269
	05.02.2018, 17:21 [ТС]
	Здесь убрал кавычки и сработало, Добавлено через 3 минуты Сценарий: C:\UsersW7D~l\AppData\Local\Temp\RarSFX0 \Setup.vbs Строка: 14 Символ: 59 Ошибка: Незавершенная строковая константа Код: 800А0409 Источник: Ошибка компиляции Microsoft VBScript 0

@BKPB 0 / 0 / 0 Регистрация: 08.05.2015 Сообщений: 269
	05.02.2018, 17:46 [ТС]
	Там вообще TSO.SpecialFolders нет, а только FSO.SpecialFolders 0

FlasherX 7001 / 2885 / 1110 Регистрация: 06.06.2017 Сообщений: 9,812
	05.02.2018, 17:48
	Я сам понятия не имею, зачем вы F исправили на Т. 0

FlasherX 7001 / 2885 / 1110 Регистрация: 06.06.2017 Сообщений: 9,812
	05.02.2018, 18:15
	BKPB Зачем же делать такую глупость, когда есть Ctrl+C? Про результат лучше напишите. 0

@BKPB 0 / 0 / 0 Регистрация: 08.05.2015 Сообщений: 269
	05.02.2018, 18:22 [ТС]
	Ну вроде всё отлично, но вот только видать из за распаковки файлов Default.zip установка стала по дольше, но это не беда, просто в процессе установки не понятно установилась она уже или нет так как по времени дольше. Нельзя например, папку заменять не упаковывая её в .zip. Или я не пойму почему стало дольше, наверное что файла заменяются по одному или что я Default.zip сжал по максимуму. 0

FlasherX 7001 / 2885 / 1110 Регистрация: 06.06.2017 Сообщений: 9,812
	05.02.2018, 18:26
	Вы там про применение на другой машине писали. Папку носить лучше, чем архив? 0