Проблема с удалением файла и ветки реестра

@Mikston · Регистрация: 08.12.2021

Author24 — интернет-сервис помощи студентам

Всем привет.

Нужно удалить файл по пути "%appdata%\lsvclic.dat" и ветку реестра "HKEY_CURRENT_USER\Software\7-Zip"

Получился такой код:

Visual Basic

WScript.CreateObject("WScript.Shell").RegDelete "HKEY_CURRENT_USER\Software\7-Zip\"
Set objShell = CreateObject("WScript.Shell")
objShell.ExpandEnvironmentStrings("%APPDATA%")
WScript.CreateObject("Scripting.FileSystemObject").DeleteFile "%appdata%\lsvclic.dat"

Ошибки:
"Не удаётся удалить раздел реестра"
"Файл не найден"

В реестре если подразделов нет, то раздел удаляется, но т.к. в "7-Zip" они есть - появляется ошибка.

FlasherX · 25.07.2022, 18:10

Visual Basic

Option Explicit: Dim File, oReg, oCol, Key, sKeys, sKey
File = CreateObject("WScript.Shell").SpecialFolders(5) & "\lsvclic.dat"
Set oReg = GetObject("winmgmts:\\.\root\default:StdRegProv")
Set oCol = CreateObject("System.Collections.ArrayList")
Recursion "Software\7-Zip"
oCol.Sort: oCol.Reverse
For Each Key in oCol: oReg.DeleteKey &H80000001, Key: Next
With CreateObject("Scripting.FileSystemObject")
   If .FileExists(File) Then .DeleteFile File, 1
End With
Set oReg = Nothing: Set oCol = Nothing
 
Sub Recursion(Key)
   oReg.EnumKey &H80000001, Key, sKeys
   If VarType(sKeys) <> 1 Then
      oCol.Add Key
      For Each sKey In sKeys
         Recursion Key & "\" & sKey
      Next
   Else oReg.DeleteKey &H80000001, Key
   End If
End Sub

@Mikston · 26.07.2022, 08:07 **[ТС]**

Скрипт работает, спасибо.
Хотелось бы прояснить - почему vbs не может удалить раздел реестра, если имеются подразделы? Батник легко всё делает, и работает с тем же путём %appdata%.

FlasherX · 26.07.2022, 10:05

Пожал'ста.

VBS и батник тут ни при чём. Методы RegDelete и DeleteKey соотв. объектов в своих библиотеках COM не реализованы для вызова рекурсивных API-функции RegDeleteTreeW или SHDeleteKeyW, а базируются на RegDeleteKeyExW, как, впрочем, и утилита reg.exe, но в ней предусмотрена самостоятельная рекурсия вроде той, что я написал.
P. S.: За счёт чего реализуется Remove-Item <Key> -Recurse в powershell затрудняюсь ответить.

Переменные среды вроде %appdata% могут раскрываться за счёт функций CreateProcessW/WinExec, реализованных в методах Run/Exec объекта WshShell, как, собственно, и в командном интерпретаторе cmd.exe. В функциях вроде удаления файла (DeleteFile) этого нет.

@Mikston · 26.07.2022, 10:34 **[ТС]**

Понял, спасибо

@Mikston 0 / 0 / 0 Регистрация: 08.12.2021 Сообщений: 70
	26.07.2022, 08:07 [ТС]	3
	Скрипт работает, спасибо. Хотелось бы прояснить - почему vbs не может удалить раздел реестра, если имеются подразделы? Батник легко всё делает, и работает с тем же путём %appdata%. 0

FlasherX 6228 / 2670 / 1051 Регистрация: 06.06.2017 Сообщений: 9,127
	26.07.2022, 10:05	4
	Пожал'ста. VBS и батник тут ни при чём. Методы RegDelete и DeleteKey соотв. объектов в своих библиотеках COM не реализованы для вызова рекурсивных API-функции RegDeleteTreeW или SHDeleteKeyW, а базируются на RegDeleteKeyExW, как, впрочем, и утилита reg.exe, но в ней предусмотрена самостоятельная рекурсия вроде той, что я написал. P. S.: За счёт чего реализуется `Remove-Item <Key> -Recurse` в powershell затрудняюсь ответить. Переменные среды вроде %appdata% могут раскрываться за счёт функций CreateProcessW/WinExec, реализованных в методах Run/Exec объекта WshShell, как, собственно, и в командном интерпретаторе cmd.exe. В функциях вроде удаления файла (DeleteFile) этого нет. 0

@Mikston 0 / 0 / 0 Регистрация: 08.12.2021 Сообщений: 70
	26.07.2022, 10:34 [ТС]	5
	Понял, спасибо 0

Проблема с удалением файла и ветки реестра

Решение