Как узнать средствами WSH или Script принтер по умолчанию

Option Explicit
Dim oSrv, oPrn
On Error Resume Next
Set oSrv = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\CIMV2")
If Err.Number <> 0 Then
    WScript.Echo Err.Number & ": " & Err.Description
    WScript.Quit
End If
For Each oPrn In oSrv.ExecQuery("SELECT * FROM Win32_Printer")
    If oPrn.Default Then
        WScript.Echo oPrn.Name
        Exit For
    End If
Next

Option Explicit
Dim oSh, sPrn
Set oSh = CreateObject("WScript.Shell")
sPrn = oSh.RegRead("HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows\Device")
WScript.Echo(sPrn)

Set WshNetwork = WScript.CreateObject("WScript.Network")
Set oPrinters = WshNetwork.EnumPrinterConnections
WScript.Echo "Network printer mappings:"
For i = 0 to oPrinters.Count - 1 Step 2
    WScript.Echo "Port " & oPrinters.Item(i) & " = " & oPrinters.Item(i+1)
Next

Dim objFolder, strTemp, intTemp
Set objFolder = CreateObject("Shell.Application").NameSpace(&H4)
Select Case objFolder.Items.Count
    Case 1: strTemp = "Подключений не найдено."
    Case 2
        strTemp = objFolder.Items.Item(1).Name
        intTemp = objFolder.Items.Item(1).Verbs.Count
    Case Else
        strTemp = objFolder.Items.Item(1).Name
        intTemp = objFolder.Items.Item(1).Verbs.Count
        For i = 2 To objFolder.Items.Count - 1
            If objFolder.Items.Item(i).Verbs.Count < intTemp Then
                strTemp = objFolder.Items.Item(i).Name
                intTemp = objFolder.Items.Item(i).Verbs.Count
            End If
        Next
End Select
WScript.Echo "Принтер по умолчанию: " & strTemp
WScript.Quit 0

Dim objFolder, objPrinters
Dim arrPrinters, strVerbs, strName
Dim strTemp, intTemp, i, j, k
 
arrPrinters = Array(): j = -1
Set objPrinters = CreateObject("WScript.Network").EnumPrinterConnections
For i = 1 To objPrinters.Count - 1 Step 2
    strTemp = objPrinters.Item(i)
    If Left(strTemp, 2) = "\\" Then strTemp = StrReverse(Split(StrReverse(strTemp), "\")(0))
    j = j + 1
    ReDim Preserve arrPrinters(j)
    arrPrinters(j) = strTemp
Next
Set objPrinters = Nothing
If UBound(arrPrinters) >= 0 Then
    Set objFolder = CreateObject("Shell.Application").NameSpace(&H4)
    For i = 0 To objFolder.Items.Count - 1
        strTemp = objFolder.Items.Item(i).Name: strVerbs = vbNullString
        For j = 0 To UBound(arrPrinters)
            If StrComp(arrPrinters(j), Left(strTemp, Len(arrPrinters(j))), vbTextCompare) = 0 Then
                intTemp = objFolder.Items.Item(i).Verbs.Count
                For k = 0 To intTemp - 1
                    strVerbs = strVerbs & objFolder.Items.Item(i).Verbs.Item(k).Name & vbNewLine
                Next
                If InStr(1, strVerbs, "Использовать по умолчанию", vbTextCompare) = 0 Then
                    strName = arrPrinters(j)
                    Exit For
                End If
            End If
        Next
        If Len(strName) > 0 Then Exit For
    Next
    Set objFolder = Nothing
    If Len(strName) > 0 Then
        WScript.Echo "Принтер по умолчанию: " & strName
    Else
        WScript.Echo "Принтер по умолчанию не найден."
    End If
Else
    WScript.Echo "Подключений не найдено."
End If
WScript.Quit 0