Определить, есть ли во введённой с клавиатуры последовательности чисел три одинаковых последовательных числа?

;Определить, есть ли в введённой с клавиатуры последовательности
;чисел, три одинаковых последовательных числа
;
;DOS, TASM, COM-файл
;
;Создание СОМ-файла
;tasm.exe /m filename.asm
;tlink.exe /t /x filename.obj
;Получается filename.com
;
.model tiny
.code
.386
org 100h
start:
    mov ah,9
    lea dx,str
    int 21h
 
    xor bx,bx   ;для двух цифр
    xor cx,cx   ;флаг цифра/пробел
m1:
    xor ax,ax   ;получить символ
    int 16h
    cmp al,1Bh  ;Esc
    jz short exit
    cmp al,' '  ;пробел
    jz short probel
 
    sub al,30h
    cmp al,09h
    ja short m1 ;не цифра
 
    test cx,cx  ;флаг цифра/пробел
    jnz short m1
    add al,30h  ;вывод символа цифоы на экран
    mov ah,2
    mov dl,al
    int 21h
    inc cx      ;установить флаг цифра/пробел
 
;проверка и запись символов в BX
    cmp bh,al
    jz short m2
    shl bx,8
m2:
    cmp bl,al
    jz short m3
    mov bl,al
    jmp short m1
m3:
    mov ah,9
    lea dx,str_OK
    int 21h
    mov bh,bl
    xor cx,cx   ;сброс флага цифра/пробел
    jmp short m1
probel:
    test cx,cx  ;проверка флага цифра/пробел
    jz short m1
    mov ah,2
    mov dl,al
    int 21h
    xor cx,cx   ;сброс флага цифра/пробел
    jmp short m1
exit:
    ret     ;выход из программы
 
str     db 'Esc - exit',13,10
        db "Enter your number:$"
str_OK  db 13,10,'Yes',13,10,'$'
 
    end start

.model tiny
.code
.386
org 100h
start:
    mov ah,9
    lea dx,str
    int 21h
 
    xor cx,cx   ;флаг цифра/пробел
    xor bx,bx   ;счетчик цифр и пробелов
    lea di,buffer   ;буфер для строки
m1:
    xor ax,ax   ;получить символ
    int 16h
    cmp al,13   ;Enter
    jz short ent
    cmp al,' '  ;пробел
    jz short probel
 
    sub al,30h
    cmp al,09h
    ja short m1 ;не цифра
 
    test cx,cx  ;был пробел?
    jnz short m1
    inc cx      ;установить флаг цифры
    add al,30h
    jmp short m2    ;на вывод цифры на экран
 
probel:
    test cx,cx  ;уже был пробел?
    jz short m1
    dec cx
m2:
    mov ah,2    ;вывод на экран
    mov dl,al
    int 21h
    inc bx      ;увеличить счетчик
    stosb
    jmp short m1
ent:
;перевод строки
    mov ah,2
    mov dl,13
    int 21h
    mov dl,10
    int 21h
 
    lea si,buffer   ;на адрес строки
    add bx,si   ;вычислить адрес конца строки
m3:
    cmp bx,si   ;конец строки?
    jbe short exit
    lodsw       ;читать символ
    cmp [si],al ;сравнить со вторым и
    jnz short m3
    cmp [si+2],al   ;с третьим
    jnz short m3
 
    mov ah,2    ;вывод на экран
    mov dl,al
    int 21h
    mov dl,' '
    int 21h
    jmp short m3    ;на следующий символ
exit:
    xor ax,ax
    int 16h
 
    ret     ;выход из программы
 
str db "Enter string: $"
buffer:
 
    end start

exit:
    xor ax,ax
    int 16h
;********************
    cmp al,27   ;Esc?
    jnz short exit
;********************
 
    ret     ;выход из программы