Вызываем функции из clib (библиотека Си) в DOS

format ms coff
; сохранять в 866 кодовой. 
include 'private\proc.inc'
extrn   __CMain ;обязательно для инициализации Си-библиотеки, отсюда будет вызван main
; объявляем все ф-ции, которые будем вызывать, внешними
extrn system
extrn printf
extrn scanf
extrn _getch
extrn exit
public  main    ; обязательно
section '_TEXT' code    ; тоже обязательно
; #include <stdio.h>
; #include <stdlib.h>
; void main (void)
main:
 
; system ("cls");
    ccall   system, @cls        ; это вместо invoke
; printf("Введите a:");
    mov ebx, 61h
    ccall   printf, entr, ebx
; scanf("%d",&a);
    ccall   scanf, tpi, a
; printf("Введите b:");
    inc ebx
    ccall   printf, entr, ebx
; scanf("%d",&b);
    ccall   scanf, tpi, b
; printf("Введите n:");
    mov eax, 6Eh
    ccall   printf, entr, eax
; scanf("%d",&n);
    ccall   scanf, tpi, n
; {d=(a*b)*n;}
    mov eax,[a] 
        imul    eax,[b] 
        imul    eax,[n] 
    mov [d], eax
 
; printf("(a+b)*n)=%d",d);
    ccall   printf, rslt, eax
; getchar();getchar();
    ccall   _getch
    ccall   exit,0
; }
section '_DATA' data    ; тоже обязательно, секции в Си зовутся именно так
@cls    db  'cls',0
entr    db  'Введите %c:',0
tpi db  '%d',0
rslt    db  '(a+b)*n)=%d',0
; int a,b,n,d;
; d=0;
d   dd  0
a   dd  ?
b   dd  ?
n   dd  ?

;FASM bahama.asm bahama.obj
;wlink sys dos4g fi bahama.obj,D:\WC11\lib386\dos\CMAIN386.OBJ lib clib3s.lib,graph.lib
format ms coff
include 'private\proc.inc'
include 'gr.inc'
extrn   __CMain
extrn   _setvideomode
extrn   _setcolor
extrn   _rectangle
extrn   _polygon
extrn   _getch
extrn   exit
public  main
section '_TEXT' code
main:
    ccall   _setvideomode, _MRES256COLOR    ;mode X, 13h
; заливаем экран синеньким, точно подбирать цвета лень
    ccall   _setcolor, 7fh
    ccall   _rectangle,_GFILLINTERIOR, 0, 0, 320, 200
; выводим жёлтую полосу посерёдке
    ccall   _setcolor, 2a2a2ah;_YELLOW
    ccall   _rectangle, _GFILLINTERIOR, 0, 66, 320, 132
; и чёрный треугольник слева
    ccall   _setcolor, 0
    ccall   _polygon, _GFILLINTERIOR, 3, trio
 
gtfo:   ccall   _getch
    ccall   _setvideomode, _TEXTC80
    ccall   exit,0
section '_DATA' data
trio    dw  0,0, 100,100, 0,200