Как создать объектный файл

.model tiny 
.code
org 100h
start:  mov ah,9
    mov dx,offset Hello
    int 21h
    mov ah,0
    int 16h
    ret
Hello byte "Hello, world!$"
end start

.model small
.stack 200
.data
Hello byte "Hello, world!$"
.code
start:  mov ax,@data
    mov ds,ax
    mov ah,9
    mov dx,offset Hello
    int 21h
    mov ah,0
    int 16h
    mov ah,4Ch
    int 21h
end start

.386
.model flat, stdcall
option casemap:none
include \masm32\include\windows.inc
include \masm32\include\kernel32.inc
include \masm32\include\user32.inc
includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib
 
.data
MsgCaption      db "Iczelion's tutorial no.2",0
MsgBoxText      db "Win32 Assembly is Great!",0
 
.code
start:
    invoke MessageBox, NULL,addr MsgBoxText, addr MsgCaption, MB_OK
    invoke ExitProcess,NULL
end start

.386
.model flat,stdcall
option casemap:none
WinMain proto :DWORD,:DWORD,:DWORD,:DWORD
include \masm32\include\windows.inc
include \masm32\include\user32.inc
include \masm32\include\kernel32.inc
includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib
 
.data
ClassName db "SimpleWinClass",0
AppName  db "Our First Window",0
MenuName db "FirstMenu",0
Test_string db "You selected Test menu item",0
Hello_string db "Hello, my friend",0
Goodbye_string db "See you again, bye",0
 
.data?
hInstance HINSTANCE ?
CommandLine LPSTR ?
hMenu HMENU ?
 
.const
IDM_TEST equ 1
IDM_HELLO equ 2
IDM_GOODBYE equ 3
IDM_EXIT equ 4
 
.code
start:
    invoke GetModuleHandle, NULL
    mov    hInstance,eax
    invoke GetCommandLine
        mov CommandLine,eax
    invoke WinMain, hInstance,NULL,CommandLine, SW_SHOWDEFAULT
    invoke ExitProcess,eax
WinMain proc hInst:HINSTANCE,hPrevInst:HINSTANCE,CmdLine:LPSTR,CmdShow:DWORD
    LOCAL wc:WNDCLASSEX
    LOCAL msg:MSG
    LOCAL hwnd:HWND
    mov   wc.cbSize,SIZEOF WNDCLASSEX
    mov   wc.style, CS_HREDRAW or CS_VREDRAW
    mov   wc.lpfnWndProc, OFFSET WndProc
    mov   wc.cbClsExtra,NULL
    mov   wc.cbWndExtra,NULL
    push  hInst
    pop   wc.hInstance
    mov   wc.hbrBackground,COLOR_WINDOW+1
    mov   wc.lpszMenuName,NULL
    mov   wc.lpszClassName,OFFSET ClassName
    invoke LoadIcon,NULL,IDI_APPLICATION
    mov   wc.hIcon,eax
    mov   wc.hIconSm,0
    invoke LoadCursor,NULL,IDC_ARROW
    mov   wc.hCursor,eax
    invoke RegisterClassEx, addr wc
    invoke LoadMenu, hInst, OFFSET MenuName
    mov    hMenu,eax
    INVOKE CreateWindowEx,NULL,ADDR ClassName,ADDR AppName,\
           WS_OVERLAPPEDWINDOW,CW_USEDEFAULT,\
           CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,NULL,hMenu,\
           hInst,NULL
    mov   hwnd,eax
    INVOKE ShowWindow, hwnd,SW_SHOWNORMAL
    INVOKE UpdateWindow, hwnd
    .WHILE TRUE
                INVOKE GetMessage, ADDR msg,NULL,0,0
                .BREAK .IF (!eax)
                INVOKE DispatchMessage, ADDR msg
    .ENDW
    mov     eax,msg.wParam
    ret
WinMain endp
WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
    .IF uMsg==WM_DESTROY
        invoke PostQuitMessage,NULL
    .ELSEIF uMsg==WM_COMMAND
        mov eax,wParam
        .IF ax==IDM_TEST
            invoke MessageBox,NULL,ADDR Test_string,OFFSET AppName,MB_OK
        .ELSEIF ax==IDM_HELLO
            invoke MessageBox, NULL,ADDR Hello_string, OFFSET AppName,MB_OK
        .ELSEIF ax==IDM_GOODBYE
            invoke MessageBox,NULL,ADDR Goodbye_string, OFFSET AppName, MB_OK
        .ELSE
            invoke DestroyWindow,hWnd
        .ENDIF
    .ELSE
        invoke DefWindowProc,hWnd,uMsg,wParam,lParam
        ret
    .ENDIF
    xor    eax,eax
    ret
WndProc endp
end start

#define IDM_TEST 1
#define IDM_HELLO 2
#define IDM_GOODBYE 3
#define IDM_EXIT 4
 
FirstMenu MENU
{
 POPUP "&PopUp"
        {
         MENUITEM "&Say Hello",IDM_HELLO
         MENUITEM "Say &GoodBye", IDM_GOODBYE
         MENUITEM SEPARATOR
         MENUITEM "E&xit",IDM_EXIT
        }
 MENUITEM "&Test", IDM_TEST
}

.686
.model flat,stdcall
option casemap:none
include \masm32\include\user32.inc
include \masm32\include\kernel32.inc
includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib
include \masm32\include\windows.inc;содержит описание типов данных Windows 
COL1 = 2+8;цвет выводимого текста
COL2 = 1+2+8;цвет выводимого текста 2
.data
HANDL  dd ?
HANDL1 dd ?
STR1 db 'Введите строку:',13,10,0
LEN1 = $ - STR1 - 1
STR2 db 'Простой пример консоли',0
LEN2 = $ - STR2 - 1
BUF db 200 dup (?)
LENS db '25',0;количество выведенных символов
CRD COORD <?>
.code
start:   invoke CharToOemA,offset STR1,offset STR1;перекодируем строку из Win в DOS
         invoke FreeConsole;освободим существующую консоль
         invoke AllocConsole;образуем свою консоль
         invoke GetStdHandle,STD_INPUT_HANDLE;получаем HANDL1 для ввода
         mov HANDL1,eax
         invoke GetStdHandle,STD_OUTPUT_HANDLE;получаем HANDL для вывода
         mov HANDL,eax
         mov CRD.X,100
         mov CRD.Y,25
         invoke SetConsoleScreenBufferSize,eax,dword ptr CRD;устанавливаем новый размер окна консоли
         invoke SetConsoleTitleA,offset STR2;определение заголовка окна
         mov CRD.X,0
         mov CRD.Y,10
         invoke SetConsoleCursorPosition,HANDL,dword ptr CRD;устанавливаем позицию курсора
         invoke SetConsoleTextAttribute,HANDL,COL1;задаем цветовые атрибуты выводимого текста
         invoke WriteConsoleA,HANDL,offset STR1,dword ptr LEN1,offset LENS,offset STR1;выводим строку символов
         invoke ReadConsoleA,HANDL1,offset BUF,200,offset LENS,0;ждем ввод строки символов
         invoke SetConsoleTextAttribute,HANDL,COL2;задаем цветовые атрибуты выводимого текста
         invoke WriteConsoleA,HANDL,offset BUF,dword ptr LENS,offset LENS,0
         invoke Sleep,1500;небольшая задержка
         invoke FreeConsole;закрываем консоль
         invoke ExitProcess,0
end start