XSLT. Удалить пространства имен из XML

<?xml version="1.0" encoding="utf-8"?>
<root>
  <Elements Name="" ItemPath="folder1" ItemName="signal1" IsItem="true" HasChildren="false">
    <Properties Name="limitHiHi" Description="" ItemPath="" ItemName="">
      <Value type="double">0</Value>
    </Properties>
    <Properties Name="dataType" Description="" ItemPath="" ItemName="">
      <Value type="QName">ArrayOfInt</Value>
    </Properties>
  </Elements>
  <Elements Name="" ItemPath="folder2" ItemName="signal2" IsItem="true" HasChildren="false">
    <Properties Name="limitHiHi" Description="" ItemPath="" ItemName="">
      <Value type="double">0</Value>
    </Properties>
    <Properties Name="dataType" Description="" ItemPath="" ItemName="">
      <Value type="QName">boolean</Value>
    </Properties>
  </Elements>
  <Elements Name="" ItemPath="folder3" ItemName="signal3" IsItem="true" HasChildren="false">
    <Properties Name="limitHiHi" Description="" ItemPath="" ItemName="">
      <Value type="double">0</Value>
    </Properties>
    <Properties Name="dataType" Description="" ItemPath="" ItemName="">
      <Value type="QName">double</Value>
    </Properties>
  </Elements>
  ...
  <Elements Name="" ItemPath="folder4" ItemName="signal4" IsItem="true" HasChildren="false">
    <Properties Name="limitHiHi" Description="" ItemPath="" ItemName="">
      <Value type="double">0</Value>
    </Properties>
    <Properties Name="dataType" Description="" ItemPath="" ItemName="">
      <Value type="QName">int</Value>
    </Properties>
  </Elements>
</root>

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
    <xsl:output indent="yes" method="xml" encoding="utf-8" omit-xml-declaration="yes"/>
 
    <!-- Stylesheet to remove all namespaces from a document -->
    <!-- NOTE: this will lead to attribute name clash, if an element contains
        two attributes with same local name but different namespace prefix -->
    <!-- Nodes that cannot have a namespace are copied as such -->
 
    <!-- template to copy elements -->
    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@* | node()"/>
        </xsl:element>
    </xsl:template>
 
    <!-- template to copy attributes -->
    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
            <xsl:value-of select="."/>
        </xsl:attribute>
    </xsl:template>
 
    <!-- template to copy the rest of the nodes -->
    <xsl:template match="comment() | text() | processing-instruction()">
        <xsl:copy/>
    </xsl:template>
 
</xsl:stylesheet>

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet
    version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
    exclude-result-prefixes="msxsl xsi xsd"
>
     <!--
      Help
          https://wiki.tei-c.org/index.php/Remove-Namespaces.xsl
          http://clardeur.blogspot.ru/2012/11/remove-all-namespaces-from-xml-using.html
          https://xsltdev.ru/xpath/substring-after/
      -->
  
  <xsl:output method="xml" indent="yes" encoding="UTF-8" omit-xml-declaration="no"/>
  
  <!--The first templating rule to apply remove namespaces prefixing elements-->
  <xsl:template match="*">
    <xsl:element name="{local-name()}">
      <xsl:apply-templates select="@*|node()"/>
    </xsl:element>
  </xsl:template>
  
  <!--The second templating rule is needed to copy attributes-->
  <xsl:template match="@*">
    <!-- перебор всех атрибутов -->
    <xsl:attribute name="{local-name()}">
      <xsl:choose>
        <!-- если текущее имя атрибута = 'Name' и его содержимое содержит символ двоеточия(префикс) -->
        <xsl:when test="name()='Name' and contains(.,':')">
          <!--вытащить подстроку после двоеточия из содержимого текущего атрибута -->
          <xsl:value-of select="substring-after(.,':')"/>
        </xsl:when>
        <xsl:when test="name()='xsi:type' and contains(.,':')">
          <!--вытащить подстроку после двоеточия из содержимого текущего атрибута -->
          <xsl:value-of select="substring-after(.,':')"/>
        </xsl:when>
        <xsl:otherwise>
          <!--оставить текущий атрибут без изменений -->
          <xsl:value-of select="."/>  
        </xsl:otherwise>
      </xsl:choose>
    </xsl:attribute>
  </xsl:template>
  
  <!--The third rule just copy all the rest of the node processed.-->
  <xsl:template match="comment() | text() | processing-instruction()">
    <xsl:copy>
      <xsl:apply-templates/>
    </xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>