Реализовать бегущую строку по диагонали

.model small
.stack 1000h
.data 
x1  equ 10              ;начальная координата выводимой строки
x2  equ 40              ;конечная координата выводимой строки
llen    equ x2-x1+1         ;длина строки
 
txt db llen dup(' ')        ;текст "бегущей" строки
    db 'ABC123'
    db llen-1 dup(' ')
txtl    equ $-txt           ;длина "бегущей" строки
 
movnm   equ txtl-llen+1     ;количество сдвигов "бегущей" строки
 
deltime equ 30              ;задержка (в сотых долях сек.) между сдвигами "бегущей" строки
  
.code
    mov ax,@data            ;загружаем адрес сегмента данных
    mov ds,ax
 
    mov ah,0            ;очищаем экран установкой стандартного текстового видеорежима
    mov al,3
    int 10h
 
m1: mov si,offset txt       ;загружаем адрес начала текста
    mov cx,movnm            ;загружаем количество сдвигов строки
 
m2: push cx
    
    mov dh,12           ;устанавливаем курсор в позицию начала строки
    mov dl,10
   
    call locat
 
    call tprint         ;отображаем строку
 
    call delay          ;формируем временную задержку
 
 
    inc si              ;переходим к следующей позиции в строке
    pop cx              ;и выполняем отображение остальной части строки в цикле
    loop m2
 
    jmp m1              ;переходим к отображению строки с начала
 
exit:   mov ah,4ch          ;завершаем программу
        int 21h
 
 
delay   proc near
    mov ah,2ch          ;получаем текущее время
    int 21h
    mov bl,dl           ;сохраняем сотые доли секунды
 
del1:   mov ah,2ch          ;получаем текущее время
    int 21h
 
    sub dl,bl           ;корректируем время (при переходе через секунду)
    jge del2
    add dl,100
 
del2:   cmp dl,deltime          ;если время не прошло, то ожидаем
    jb del1
 
    ret
delay   endp
 
                    ;при входе:
                    ;DH - Y-координата
                    ;DL - X-координата
locat   proc near
    mov ah,2            ;устанавливаем позицию курсора
    mov bh,0
    int 10h
 
    ret
locat   endp
 
                    ;при входе:
                    ;SI - начальный адрес текста
tprint  proc near
    mov ah,40h          ;выводим строку
    mov bx,1
    mov cx,llen
    mov dx,si
    int 21h
 
    ret             ;выход из подпрограммы
tprint  endp
 
end

; masm dos exe #
.286 
.MODEL small
.data
Hello byte "A  ",10,"B  ",10,"C  ",10,"1  ",10,"2  ",10,"3  ",10," $"
coord dw 123Ch
.code
start:  mov ax,@data
    mov ds,ax
    mov ax,3
    int 10h
    mov cx,21
a0: push cx
    mov dx,coord ;Y-координата и X-координата
        mov ah,2            ;устанавливаем позицию курсора
        int 10h
    mov ah,9
    mov dx,offset Hello
    int 21h
        mov ah,2Ch          ;получаем текущее время
        int 21h
        mov bl,dl           ;сохраняем сотые доли секунды 
del1:   int 21h          ;получаем текущее время 
        sub dl,bl           ;корректируем время (при переходе через секунду)
        jge del2
        add dl,100 
del2:   cmp dl,30          ;если время не прошло, то ожидаем
        jb del1
        sub coord,103h
    pop cx
    loop a0
    mov ah,0
    int 16h
    mov ah,4Ch
    int 21h
End start

;tasm dos com
.model tiny
.code
.386
org 100h    ; СОМ-программа
start:
    mov ah,9
    lea dx,stringtxt
    int 21h
 
    mov ah,10       ;ввод строки
    lea dx,string
    int 21h
 
;si на конец строки
    mov si,dx
    mov cx,[si]
    shr cx,8
    add si,cx
    inc si
 
    mov ax,3        ;очистка экрана
    int 10h
 
    push 0B800h ;видеопамять
    pop es
 
;вывод введенной строки
    mov di,50*2 ;79*2 правый верхний угол 
        ;80 символов в строке по 2 байта (символ и атрибут)на символ 
    std     ;читать строку с конца к началу
m1:
    lodsb   ;читать
    stosb   ;писать в видеопамять
    add di,159  ;следующая строка
    loop m1
 
    cld     ;изменить направление для строк
    push es
    pop ds  ;видеопамять
 
    mov si,(158*24)+(50*2) ;на последний символ в последней строке
    mov bp,si   ;сохранить
m3:
    mov si,bp
    mov di,si
    lodsw   ;прочитать в последней строки символ и
    mov bx,ax   ;сохранить его
 
    mov cx,24   ;остальных строк на экране (25-1)
    sub si,160  ;предпоследняя строка
 
;читать/писать символы со смещением на символ влево и на строку выше 
m2:
    lodsw   ;читать символ с атрибутом
    stosw   ;писать на 1 строку ниже
    mov di,si
    sub di,2
    sub si,160
    loop m2
 
    mov ax,bx   ;писать сохраненный символ из 25 строки 
    stosw   ;в верхнюю 1 строку
 
    call wait   ;задерка
 
    in al,60h   ; прочитать скан-код последнего символа,
    cmp al,81h  ; если это 81h (отпускание клавиши Esc),
    jz short exit ; выйти из программы
    jmp short m3
exit:
    ret     ;выход из программы
;------------------------------------------------------------
wait    proc
    mov ah,0
    int 1Ah
    add dx,18  ;18*3 задержка примерно на 3 секунды
    adc cx,0
    mov di,dx
    mov si,cx
DELAY:
    int 1Ah
    cmp cx,si
    ja short EndDELAY
    cmp dx,di
    jb short DELAY
EndDELAY:
    ret
wait    endp
;------------------------------------------
stringtxt db 13,10,'Esc - exit',13,10
          db       'Enter string: $'
string db 26    ;25 строк + enter, 1 символ в строке
;------------------------------------------
    end start