Резидентная программа: по комбинации Ctrl+alt+e показывает на экране фамилию с интервалом в 4 секунды

text segment 'code' 
org 256 ;для СOM
assume cs:text,ds:text  
main proc
jmp init  
;Поля данных резидентной секции
empty db   '            $' 
msg_fio db 'FAMILIYA $'
flag1 dw 0
count dw 0
old_2fh dd 0    ; Ячейка для сохранения системного вектора 2Fh
old_09h dd 0    ; Ячейка для сохранения системного вектора 09h
old_1Ch dd 0     ; Ячейка для сохранения системного вектора 1Сh
new_09h proc
; Сохраним используемые регистры
    push es
    push ax
    push bx
    push cx
    push dx
    push ds
    push cs ; Настроим DS на наш сегмент для простоты программирования
    pop ds   
    IN ax,60h   ;Чтение портов клавиатуры в AX
    cmp al,18   ; проверка нажатия буквы E
    JNZ exit    ; не нажата - выходим
    MOV AX,0    
    MOV ES,AX          ; Чтение флагов состояния  
    MOV AL,ES:[417h]   ; клавиатуры в регистр AL и 
    AND AL,00001100b   ; определение нажаты ли клавиши 
    CMP AL,00001100b   ; Ctrl-Alt, если нет, то 
    JNZ exit        ; возврат управления
    NOT flag1     
    
; Восстановим использовавшиеся регистры 
exit: 
    pop ds 
    pop dx 
    pop cx 
    pop bx 
    pop ax 
    pop es
    jmp cs:old_09h         ; Передадим управление системному обработчику "int09h"
new_09h endp              ; Конец процедуры
 
new_1Ch proc
    push ax
    push es
    push dx
    push ds    
    push cs ; Настроим DS на наш сегмент для простоты программирования
    pop ds  
    
    mov ax,0b800h        ;Загружаем в сегментный регистр адресса 0 видеостраницы
    mov es,ax 
 
cmp flag1,0
je exit1
inc count
 
cmp count,72 ; 4 сек прошло?
jne p1 ;Нет -> Ждем еще секунду и чистим экран. Если 4 сек прошло, то выводим фамилию
    mov si,3410     ; где выводить 
    mov di, offset msg_fio  ;что выводить 
    mov cx, 11      ; сколько выводить
c1: mov ah, [di]
    inc di
    mov es:[si],ah
    add si,2
    loop c1
p1: cmp count,90 ; прошло 5 секунд?
jne exit1 ;нет -> выходим. Если прошло - чистим экран
    mov si,3410 ;где выводим
    mov di, offset empty ;что выводим  (пробелы)
    mov cx, 11  ; сколько выводим
c2: mov ah, [di]
    inc di
    mov es:[si],ah
    add si,2
    loop c2
    mov count,0
exit1:
pop ds
pop dx
pop es
pop ax
iret 
new_1Ch endp 
 
; Обработчик мультиплексорного прерывания 
new_2fh proc
    cmp ah,0f1h ; Проверим номер функции мультиплексорного прерывания
    jne out_2fh ; Не наша - на выход
    cmp al,00h  ; Подфункция проверки на повторную установку?
    je inst               ; Да, сообщим о невозможности повторной установки
    cmp al,01h  ;Подфункция выгрузки? 
    je off                     ; Да - на выгрузку
    jmp short out_2fh   ; Неизвестная подфункция, на выход
inst: 
    mov al,0ffh            ; Программа уже установлена
    iret                 ; Выход из прерывания
out_2fh:
    jmp cs:old_2fh ; Переход в следующий по цепочке обработчик прерывания 2Fh
; Выгрузим программу из памяти, предварительно восстановив все перехваченные ею векторы
; Сохраним используемые регистры 
off: 
    push ds 
    push es 
    push dx 
    push bx
;------------------------------------------------------------------------   
    ; проверка на связность!
    mov ax,351Ch    ; если нашли 3 прерывания  
    int 21h
    push es
    pop ax
    push cs
    pop dx
    cmp ax,dx
    je msg1c 
    mov ax,0FFFFh
    jmp error_exit
    
msg1c:     
    mov ax,3509h  
    int 21h
    push es
    pop ax
    cmp ax,dx
    je msg09
 
    mov ax,0EFFFh  
    jmp error_exit
    
msg09:     
    mov ax,352fh
    int 21h
    push es
    pop ax
    cmp ax,dx
    je msg2f
 
    mov ax,0DFFFh
    jmp error_exit     
msg2f:     
;------------------------------------------------------------------
; Восстановим вектор 09h  ; 
    mov ax,2509h          ;Функция установки вектора
    lds dx,cs:old_09h    ; Заполним DS:DX
    int 21h 
; Восстановим вектор 2fh 
    mov ax,252fh          ;Функция установки вектора
    lds dx,cs:old_2fh     ;Заполним DS:DX
    int 21h
; Восстановим вектор 1Ch 
    mov ax,251Ch          ;Функция установки вектора
    lds dx,cs:old_1Ch     ;Заполним DS:DX
    int 21h
; Получим из PSP адрес собственного окружения и выгрузим его 
    mov es,cs:2ch   ; ES окружение
    mov ah,49h  ; Функция освобождения блока памяти
    int 21h
; Выгрузим теперь саму программу
    push cs              ; Загрузим в ES содержимое CS, т.е. сегментный адрес PSP
    pop es
    mov ah,49h  ; Функция освобождения блока памяти
    int 21h
; Восстановим использовавшиеся регистры      
error_exit:
    pop bx
    pop dx 
    pop es 
    pop ds
    iret                  ;Возврат в вызвавшую программу
new_2fh endp        ; Конец процедуры обработки прерывания 2Fh
end_res=$   ; Смещение конца резидентной части программы
main endp 
tail db 'off'              ; Ожидаемый хвост команды
flag db 0                ;Флаг требования выгрузки
 
; Процедура инициализации 
init proc
    mov cl,es:80h         ;Получим длину хвоста PSP
    cmp cl,0                ;Длина хвоста = 0 ?
    je live                     ;Да программа запущена без параметров
    xor ch,ch               ; Теперь СХ=СL=длина хвоста
    mov di,81h             ; DS:SI хвост в PSP
    lea si,tail               ; DS:SI поле tail
    mov al,' '                ;Уберём пробелы из начала хвоста
repe  scasb           ;Сканируем хвост, пока пробелы
    dec di                   ;DI первый символ после пробелов
    mov cx,3               ;Ожидаемая длина параметра
repe  cmpsb          ;Сравниваем введённый хвост с ожидаемым 
    jne live                  ;Введена неизвестная команда
    inc flag                  ;Введено "off", установим флаг запроса на выгрузку
 
; Проверим, не установлена ли уже данная программа 
live:
    mov ah,0f1h ; Установим нашу функцию
    mov al,0                  ; и подфункцию на наличие нашей программы в оперативной памяти
    int 2fh 
    cmp al,0ffh            ; Программа установлена?
    je installed           ; Да, при наличии запроса на выгрузку её можно выгрузить
 
; Сохраним вектор 2fh
    mov ax,352fh                      ; Функция получения вектора 2fh
    int 21h
    mov word ptr cs:old_2fh,bx        ; Сохраним смещение системного обработчика 
    mov word ptr cs:old_2fh+2,es    ; Сохраним сегмент системного обработчика
; Заполним вектор 2fh
    mov ax,252fh                     ; Функция установления вектора прерывания 2fh
    mov dx,offset new_2fh              ; Смещение нашего обработчика 
    int 21h 
 
; Сохраним вектор 09h
    mov ax,3509h                       ; Функция получения вектора 09h
    int 21h
    mov word ptr cs:old_09h,bx        ; Сохраним смещение системного обработчика 
    mov word ptr cs:old_09h+2,es    ; Сохраним сегмент системного обработчика ; Заполним вектор 09h
    mov ax,2509h                       ; Функция установления вектора прерывания 09h
    mov dx,offset new_09h              ; Смещение нашего обработчика 
    int 21h
 
; Сохраним вектор 1Ch
    mov ax,351Ch                       ; Функция получения вектора 09h
    int 21h
    mov word ptr cs:old_1Ch,bx        ; Сохраним смещение системного обработчика 
    mov word ptr cs:old_1Ch+2,es    ; Сохраним сегмент системного обработчика ; Заполним вектор 09h
    mov ax,251Ch                       ; Функция установления вектора прерывания 09h
    mov dx,offset new_1Ch              ; Смещение нашего обработчика 
    int 21h
 
; Выведем на экран информационное сообщение 
by: 
    mov ax,0900h    ; Показываем сообщение фио
    mov dx,offset mes
    int 21h
    mov ax,3100h        ; Функция "завершиться и остаться резидентным"
    mov dx,(end_res-main+10fh)/16   ;Размер в параграфах
    int 21h
installed:
    cmp flag, 1 ; Запрос на выгрузку установлен?
    je unins                  ; Да, на выгрузку
; Выведем на экран информационное сообщение
    mov ah, 09h ; Функция вывода на экран
    lea dx,mes1 ; DS:DX адрес строки
    int 21h
    mov ax,4c01h    ; Функция завершения с кодом возврата
    int 21h
unins:
; Перешлём в первую (резидентную) копию программы запрос на выгрузку 
    mov ax,0f101h   ; Наша функция с подфункцией выгрузки
    int 2fh     ; Мультиплексное прерывание
    cmp ax,0FFFFh
    jne p1c
    mov ah, 09h
    lea dx,error1c
    int 21h
    jmp quit
p1c:    cmp ax,0EFFFh
    jne p09
    mov ah, 09h
    lea dx,error09
    int 21h
    jmp quit
p09:    cmp ax,0DFFFh
    jne p2f
    mov ah, 09h
    lea dx,error2f
    int 21h
    jmp quit
p2f:    
; Выведем на экран информационное сообщение
    mov ah,09h  ; Функция вывода на экран
    lea dx,mes2 ; DS:DX адрес строки
    int 21h
quit: mov ax,4c00h    ; Функция завершения программы
    int 21h
 
mes db 'Program installed$' , 0
mes1 db 'Program already installed$' ,0
mes2 db 'Program is uninstalled$' ,0
error1c db 'Error 1ch Program can not be uninstalled$' ,0
error09 db 'Error 09h Program can not be uninstalled$' ,0
error2f db 'Error 2fh Program can not be uninstalled$' ,0
 
init endp
text ends
end main