Жесткий диск

use16
org 100h
jmp start
 
mess0    db  13,10,'(c) HDD-TEST v1.00 ================ 2015 ===='
         db  13,10,'*********************************************'
         db  13,10,' READY DEVICE: $'
mess1    db  13,10,'    SAVE DATA: $'
mess2    db  13,10,10,'  DEVICE NAME: $'
mess3    db  13,10,'SERIAL NUMBER: $'
mess4    db  13,10,' TOTAL SECTOR: $'
mess5    db  13,10,'     REVISION: $'
mess6    db  13,10,'============================================='
         db  13,10,'CREATE DAT-FILE: ОК! $'
mess7    db  'OK!$'
 
buff     db  512 dup(0)
fName    db  'ATAID.DAT',0
handle   dw  ?
 
start:
   mov   dx,mess0            ; шапка программы
   call  message
 
   call  waitATA             ; DX = 1F7h. ждём готовности диска (BSY=0)
   dec   dx                  ; DX = 1F6h. выбираем девайс
   mov   al,0E0h             ; для Device(0), LBA-адресация
   out   dx,al               ; пишем в порт!
 
   call  waitATA             ; ждём BSY=0
   test  al,40h              ; а так-же DRDY=1
   jz    waitATA             ; если DRDY=Зеро, то циклимся
 
   mov   dx,mess7            ; винт готов! мессага ОК!
   call  message
   mov   dx,mess1     ;------- подготовка к приёму данных в буфер --------------------|
   call  message
 
   mov   dx,01F7h            ; заносим в регистр команд 
   mov   al,0ECh             ;         код команды 'DEVICE_ID'
   out   dx,al
 
   call  waitATA             ; ждём BSY=0
   test  al,08h              ; а так-же DRQ=1
   jz    waitATA             ; если DRQ=0, ждём готовности
 
   cld                       ; винт готов! читать будем слева-направо
   mov   di,buff             ; адрес приёмного буфера
   mov   dx,01F0h            ; от куда будем читать (регистр данных)
   mov   cx,256              ; сколько читать (512 байт, или 256 слов)
   rep   insw                ; читаем с регистра словами!
 
   mov   dx,mess7            ; данные считаны! мессага ОК!
   call  message
 
   mov   dx,mess2   ;--------- выводим DEVICE-NAME -----------------------------------| 
   call  message
   mov   si,buff             ; адрес буфера в DS:SI
   add   si,27*2             ; перемещаемся в буфере на нужный адрес
   mov   cx,20               ; считать 20 слов
   call  print               ; читаем и выводим инфу на экран
 
   mov   dx,mess3   ;--------- выводим SERIAL-NUMBER ---------------------------------|
   call  message
   mov   si,buff 
   add   si,10*2             ; адрес инфы в буфере
   mov   cx,10               ; считать 10 слов
   call  print               ; выводим инфу на экран
 
   mov   dx,mess4   ;--------- выводим TOTAL SECTOR ----------------------------------|
   call  message
   mov   eax,dword[buff+60*2]     ; читаем двойное слово в 32-битный EAX
   call  convert                  ; переводим его в DEC и выводим на экран
 
   mov   dx,mess5   ;--------- выводим REVISION --------------------------------------|
   call  message
   mov   si,buff
   add   si,23*2             ; смещение инфы в буфере
   mov   cx,4                ; считать 4 слова
   call  print               ; выводим инфу на экран
 
   mov   ah,3ch     ;--------- создаём из буфера DAT-файл ----------------------------|
   mov   cx,20h              ; атрибут - архивный
   mov   dx,fName            ; адрес строки с именем файла
   int   21h                 ; создать файл!
 
   mov   dx,fName   ;--------- открываем созданный файл ------------------------------|
   mov   ax,3d02h            ;    в режиме чтения/записи
   int   21h
   mov   [handle],ax         ; сохраняем его дескриптор
 
   mov   ah,40h     ;--------- записываем данные в файл ------------------------------|
   mov   cx,512              ; сколько байт писАть
   mov   bx,[handle]         ; куда писАть (в открытый файл через его хэндл)
   mov   dx,buff             ; от куда брать данные (с буфера)
   int   21h                 ; есть запись!
 
   mov   ah,3eh     ;--------- закрываем файл ----------------------------------------|
   mov   bx,[handle]         ; какой файл закрыть (открытый)
   int   21h                 ; Save & Close!
 
   mov   dx,mess6            ; мессага об успешном завершении
   call  message
exit:               ;--------- на выход! ----------------------------------------------|
   ret
 
;//====================================================================================|
message:
   mov   ah,9
   int   21h
ret
 
waitATA:            ;--------- функция проверки готовности диска ----------------------|
   mov   dx,1F7h             ; регистр состояния на первом канале
back:
   in    al,dx               ; читаем байт состояния..
   test  al,80h              ; проверяем в нём бит(7) BSY. он должен быть 0
   jnz   back                ; если не нуль, то циклимся
ret
 
print:              ;--------- функция чтения ASCII-строк из буфера -------------------|
   lodsw                     ; читаем слово в регистр AX
   push  ax                  ; байты лежат наоборот и нужно их поменять местами
   xchg  ah,al               ; кидаем AH в AL,
   int   29h                 ;     и выводим AL на экран
   pop   ax                  ; снимаем со-стека оригинальный AL,
   int   29h                 ;     и тоже на экран его
   loop  print               ; мотаем цикл CX раз
ret
 
convert:            ;--------- функция для вывода чисел с регистра EAX
   pusha
   mov   ebx,10              ; выводить будем в десятичной системе счисления
   xor   ecx,ecx
isDiv:
   xor   edx,edx
   div   ebx
   push  edx
   inc   ecx
   or    eax,eax
   jnz   isDiv
isOut:
   pop   eax
   cmp   al,9
   jle   noHex
   add   al,7
noHex:
   add   al,30h
   int   29h
   loop  isOut
   popa
ret