Переход с флешки на загрузку с HDD

#make_boot#
org 7c00h
 
xor cx,cx     ; инициализация
mov es,cx
mov ds,cx
mov ss,cx
mov si,7c00h  ; начальный адрес
mov di,0600h  ; конечный адрес
mov sp,di
inc ch        ; 512 байт
repnz movsw   ; самоперемещение
jmp Start
 
org 0600h+$-07c00h     ; все адреса относительно нового места
Start:
mov ax,0003h  ; установка режима экрана
int 10h
add ah,10h
mov bx,color  ; включение мигания
rol bx,1
and bl,1
int 10h
 
mov bp,0800h  ; перегрузка символа (буфер символа по 0000:0800)
mov di,bp     ; инициализация указателя
xor al,al     ; первая строка знакоместа - нули
stosb
not al
mov cl,14     ; следующие 14 строк знакоместа - единицы
repnz stosb
not al        ; последняя строка знакоместа - нули
stosb
inc cl        ; заменить 1 символ в таблице
mov dx,0080h  ; с кодом 0x80
mov bx,1000h  ; размер знакоместа 8х16
mov ax,1100h
int 10h
 
lea si,map    ; инициализация таблицы данных
mov ax,0b800h ; указатель на видеопамять
mov es,ax
xor di,di
mov bh,250    ; 250 байт в карте
bytes:
lodsb         ; загрузка байта из карты
mov bl,al
mov cl,8      ; по 8 бит в байте
bits:
shl bl,1
mov ax,space
jnc skip
mov ax,color
skip:         ; пробел
stosw
loop bits
dec bh
jnz bytes 
 
mov dh,19h    ; гашение курсора
mov ah,2
int 10h
 
waitspace:    ; ожидание пробела
xor ah,ah
int 16h
cmp al,20h
jne waitspace
 
mov ax,0003h  ; очистка экрана
int 10h
add ah,10h    ; отключение мигания
int 10h
xor dx,dx     ; восстановление курсора
mov ah,2
int 10h
 
mov ah,42h    ; чтение бутсектора HDD
mov dl,81h    ; номер диска = 1
lea si,DAP    ; указатель на параметры чтения
int 13h
jc err        ; если чтение успешно
jmp 7c00h     ; то загрузиться с HDD
err:          ; при ошибке чтения
lea si,ErrMsr ; выдать сообщение
mov ah,0eh
mov cx,11
MsgOut:
lodsb
int 10h
loop MsgOut
hlt
 
DAP db 10h,0,1,0,0,7Ch,0,0,8 dup (0) ; параметры загрузочного диска
ErrMsr db 'Boot error!'              ; сообщение об ошибке
space dw 0720h    ; видеокод пустого знакоместа
color dw 8b80h    ; видеокод заполненного знакоместа
map 250 dup(0ffh) ; карта рисунка